投稿プログラム : リーチゲームVer2

パンくずリスト

概要
スクリーンショット・動画
QR コード
プログラムリスト
CHECKER FLAG (ひとことコメント)

2011年12月01日投稿 / 投稿者 : shiro / タグ : 投稿プログラムゲームテーブルゲーム QRコード初代対応

概要

CPUと対戦するビンゴゲームです。
起動するとデモ画面が表示され、ゲームのルールが説明されます。下画面にタッチすると、ゲームを開始できます。
上画面にCPUのマス目、下画面に自分のマス目が表示されます。（CPUのマス目は、ゲーム対戦中は隠されていて見えません）
自分のマス目の数字を、1手ずつタッチして「×」にして消していきます。
逆にCPUが選んだ数字は、自分のマス目では「○」になります。
「○」が縦・横・斜めのどこか1列で5個揃えば勝ちです。
どこの列を捨てて「×」で消していくかの戦略が難しく、後述のリーチ宣言ルールによる一発大逆転もあり、頭を使いますが楽しいゲームです。
CPUは結構強いです。どうしても勝てない人は、15行目の「DM=FALSE」を「DM=TRUE」に変えてデバッグモードにして、CPUの打ち方を見ながら研究してください。
リストがかなり長くて打つのが大変なので、デモ画面が必要ない人は92～195行を削ってください。

ゲームのルール

5×5のマス目に1～25の数字をランダムに並べてスタート。
自分が言った数字は「×」となり消える。
相手が言った数字は「○」となる。
「○」が縦・横・斜めのどこか1列で5個揃えば勝ち。
相手が言った数字で「○」が4個並んだ時は「リーチ」と宣言し、相手にもう一度数字を言わせることができる。

グラフィック文字

プログラムリスト中では、グラフィック文字を「Ｘ」「○」「★」などの全角文字に適宜置き換えています。
実際にプチコンで入力する時は、グラフィック文字で入力してください。

おまけ

私が通った中学校で当時流行していた紙と鉛筆のゲームを、BASICで再現しました。
今、ネットで「リーチゲーム」などと検索しても、このゲームの情報が出てきません。
私の中学だけのローカルブームだったのでしょうか？
過去に遊んだ経験がある人がいたら、ぜひコメントをください。

スクリーンショット・動画

QR コード

プチコンmkII 向けの QR コードです。

1	2	3

4	5	6

プログラムリスト

’＊＊＊＊＊＊＊＊＊＊＊＊＊＊
’＊　　　　　　　　　　　　＊
’＊　ＲＥＡＣＨ　ＧＡＭＥ　＊
’＊　　　　Ｖｅｒ２　　　　＊
’＊　２０１１．１１．２７　＊
’＊　　ｂｙ　ｓｈｉｒｏ　　＊
’＊　　　　　　　　　　　　＊
’＊＊＊＊＊＊＊＊＊＊＊＊＊＊

’＊＊＊　ショキセッテイ　＊＊＊

ＣＬＥＡＲ

’テ゛ハ゛ック゛モート゛
ＤＭ＝ＦＡＬＳＥ

ＶＩＳＩＢＬＥ　１，１，０，０，０，１
ＰＮＬＴＹＰＥ　”ＯＦＦ”
ＣＬＳ
ＧＰＡＧＥ　０：ＧＣＬＳ　０
ＧＰＡＧＥ　１：ＧＣＬＳ　１
ＢＧＭＳＴＯＰ

’マスメ　カンレン
ＤＩＭ　ＹＯＵＮ（５，５），ＣＰＵＮ（５，５）
ＤＩＭ　ＴＨＫＮ（５，５），ＴＨＫＩ（５，５）
ＤＩＭ　ＬＩＮＥＮ（５，５）

’ナラヘ゛ラレル　レツホウコウ
’ｂｉｔ０：─　ｂｉｔ１：│
’ｂｉｔ２：＼　ｂｉｔ３：／
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＲＥＡＤ　ＬＩＮＥＮ（Ｘ，Ｙ）
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ
ＤＡＴＡ　　７，　３，　３，　３，１１
ＤＡＴＡ　　３，　７，　３，１１，　３
ＤＡＴＡ　　３，　３，１５，　３，　３
ＤＡＴＡ　　３，１１，　３，　７，　３
ＤＡＴＡ　１１，　３，　３，　３，　７

’マーク　Ｘ，○
ＭＡＲＫＥＲ＝０
ＭＡＲＫＳＥＬ＝－１

’ケ゛ーム　シンコウ　カンリ
ＧＭＤＥＭＯ＝０
ＧＭＰＬＡＹ＝１
ＧＭＹＯＵＷＩＮ＝２
ＧＭＣＰＵＷＩＮ＝３
ＧＭＤＲＡＷ＝４

ＲＥＡＣＨＮＯ＝０
ＲＥＡＣＨＹＯＵ＝１
ＲＥＡＣＨＣＰＵ＝２

ＴＵＲＮＣＰＵ＝０
ＴＵＲＮＹＯＵ＝ＮＯＴ　ＴＵＲＮＣＰＵ
ＴＵＲＮ０＝ＴＵＲＮＣＰＵ
ＷＩＮＹＯＵ＝０：ＷＩＮＣＰＵ＝０

’ヒョウシ゛　サ゛ヒョウ
ＹＯＵＸ＝４：ＹＯＵＹ＝３
ＣＰＵＸ＝４：ＣＰＵＹ＝５
ＳＥＬＷＸ＝３８：ＳＥＬＷＹ＝２１
ＭＥＳＸ＝１：ＭＥＳＹ＝１９

’メッセーシ゛
ＤＩＭ　ＭＥＳ＄（４）
ＭＥＳＤＬＧ＝ＦＡＬＳＥ

’カラー
ＣＯＬＴＩＴＬＥ＝１５：ＣＯＬＴＩＴＢＧ＝２
ＣＯＬＤＥＭＯ＝１５

ＣＯＬＴＢＬＴＩ＝０
ＣＯＬＴＢＬＬＮ＝６：ＣＯＬＴＢＬＢＧ＝１５
ＣＯＬＴＢＬＮ＝１１：ＣＯＬＴＢＬＥＲ＝９
ＣＯＬＴＢＬＳＬ＝１３：ＣＯＬＴＢＬＳＣ＝１１

ＣＯＬＭＥＳ＝０：ＣＯＬＭＥＳＦＬ＝０
ＣＯＬＭＥＳＢＧ＝＆ＨＥＥ

’サウント゛
ＢＰＹＯＵＳＥＬ＝３：ＢＰＣＰＵＳＥＬ＝２
ＢＰＲＥＡＣＨ＝５

ＢＧＭＧＡＭＥ＝８
ＢＧＭＷＩＮ＝４：ＢＧＭＬＯＳＥ＝６：ＢＧＭＤＲＡＷ＝６

’＊＊＊　ルール　セツメイ　テ゛モ　＊＊＊
＠ＤＥＭＯ

ＧＭ＝ＧＭＤＥＭＯ
ＭＥＳＴＩＭＥ＝４００
ＭＥＳＷＡＩＴ＝０

ＧＯＳＵＢ　＠ＰＲＴＴＩＴＬＥ
ＧＯＳＵＢ　＠ＰＲＴＤＥＭＯ

ＧＯＳＵＢ　＠ＹＯＵＩＮＩ
ＧＯＳＵＢ　＠ＹＯＵＴＡＢＬＥ
ＧＯＳＵＢ　＠ＰＲＴＹＯＵＮ
ＧＯＳＵＢ　＠ＣＰＵＩＮＩ
ＧＯＳＵＢ　＠ＣＰＵＴＡＢＬＥ
ＧＯＳＵＢ　＠ＰＲＴＣＰＵＮ

ＭＥＳＴＣＨ＝ＴＲＵＥ
ＭＥＳＴＩＴ＄＝”ルール　セツメイ”

ＭＳ＄＝”ＣＰＵト　タイセンスル　ヒ゛ンコ゛ケ゛ーム　テ゛ス。”
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＩＦ　ＭＥＳＲＥＴ＝＝ＴＲＵＥ　ＧＯＴＯ　＠ＤＥＭＯＥＮＤ

ＭＳ＄＝”５ｘ５ノ　マスメニ、１－２５ノ　スウシ゛ヲ　ナラヘ゛テ　スタート。”
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＩＦ　ＭＥＳＲＥＴ＝＝ＴＲＵＥ　ＧＯＴＯ　＠ＤＥＭＯＥＮＤ

ＴＵＲＮ＝ＴＵＲＮＹＯＵ
ＧＯＳＵＢ　＠ＹＯＵＴＵＲＮ
ＭＳ＄＝”シ゛フ゛ンカ゛　イッタ　スウシ゛ハ、「Ｘ」ニナリ　キエル。”
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＩＦ　ＭＥＳＲＥＴ＝＝ＴＲＵＥ　ＧＯＴＯ　＠ＤＥＭＯＥＮＤ

ＴＵＲＮ＝ＴＵＲＮＣＰＵ
ＧＯＳＵＢ　＠ＣＰＵＴＵＲＮ
ＭＳ＄＝”アイテカ゛　イッタ　スウシ゛ハ、「○」ニナル。”
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＩＦ　ＭＥＳＲＥＴ＝＝ＴＲＵＥ　ＧＯＴＯ　＠ＤＥＭＯＥＮＤ

ＭＥＳＴＣＨ＝ＦＡＬＳＥ
ＭＳ＄＝””
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ

ＧＲ＝ＲＥＡＣＨＮＯ
＠ＤＥＭＯ１ＬＰ
ＴＵＲＮ＝ＮＯＴ　ＴＵＲＮ
ＩＦ　ＴＵＲＮ＝＝ＴＵＲＮＹＯＵ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＹＯＵＴＵＲＮ：ＧＯＳＵＢ　＠ＣＨＫＣＰＵ
ＩＦ　ＧＲ＝＝ＲＥＡＣＨＣＰＵ　ＧＯＴＯ　＠ＤＥＭＯ１ＬＰＥ
ＩＦ　ＴＵＲＮ＝＝ＴＵＲＮＣＰＵ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＣＰＵＴＵＲＮ：ＧＯＳＵＢ　＠ＣＨＫＹＯＵ
ＩＦ　ＧＲ＝＝ＲＥＡＣＨＹＯＵ　ＧＯＴＯ　＠ＤＥＭＯ１ＬＰＥ
ＧＯＴＯ　＠ＤＥＭＯ１ＬＰ
＠ＤＥＭＯ１ＬＰＥ

ＭＥＳＴＣＨ＝ＴＲＵＥ
ＭＳ＄＝”アイテカ゛　イッタ　スウシ゛テ゛、「○」カ゛４コ　ソロッタラ、「リーチ」ト　センケ゛ン。アイテニ　モウイチト゛　スウシ゛ヲ　イワセラレル。”
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＩＦ　ＭＥＳＲＥＴ＝＝ＴＲＵＥ　ＧＯＴＯ　＠ＤＥＭＯＥＮＤ

ＭＥＳＴＣＨ＝ＦＡＬＳＥ
ＭＳ＄＝””
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ

ＴＵＲＮ＝ＮＯＴ　ＴＵＲＮ

ＧＲ＝ＲＥＡＣＨＮＯ
＠ＤＥＭＯ２ＬＰ
ＴＵＲＮ＝ＮＯＴ　ＴＵＲＮ
＠ＤＥＭＯ２ＬＰ１
ＩＦ　ＴＵＲＮ＝＝ＴＵＲＮＹＯＵ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＹＯＵＴＵＲＮ：ＧＯＳＵＢ　＠ＣＨＫＣＰＵ
ＩＦ　ＧＭ＝＝ＧＭＣＰＵＷＩＮ　ＧＯＴＯ　＠ＤＥＭＯ２ＬＰＥ
ＩＦ　ＧＲ＝＝ＲＥＡＣＨＣＰＵ　ＧＯＴＯ　＠ＤＥＭＯ２ＬＰ１
＠ＤＥＭＯ２ＬＰ２
ＩＦ　ＴＵＲＮ＝＝ＴＵＲＮＣＰＵ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＣＰＵＴＵＲＮ：ＧＯＳＵＢ　＠ＣＨＫＹＯＵ
ＩＦ　ＧＭ＝＝ＧＭＹＯＵＷＩＮ　ＧＯＴＯ　＠ＤＥＭＯ２ＬＰＥ
ＩＦ　ＧＲ＝＝ＲＥＡＣＨＹＯＵ　ＧＯＴＯ　＠ＤＥＭＯ２ＬＰ２
ＧＯＴＯ　＠ＤＥＭＯ２ＬＰ
＠ＤＥＭＯ２ＬＰＥ

ＧＭ＝ＧＭＤＥＭＯ
ＭＥＳＴＣＨ＝ＴＲＵＥ
ＭＳ＄＝”「○」カ゛、タテ・ヨコ・ナナメノ　ト゛コカノレツテ゛　５コ　ソロエハ゛　カチ！”
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＩＦ　ＭＥＳＲＥＴ＝＝ＴＲＵＥ　ＧＯＴＯ　＠ＤＥＭＯＥＮＤ

ＧＭ＝ＧＭＰＬＡＹ
ＧＯＳＵＢ　＠ＹＯＵＩＮＩ
ＧＯＳＵＢ　＠ＰＲＴＹＯＵＮ
ＧＯＳＵＢ　＠ＣＰＵＩＮＩ
ＧＯＳＵＢ　＠ＰＲＴＣＰＵＮ
ＭＳ＄＝”シ゛ッサイノ　ケ゛ームテ゛ハ、ＣＰＵノ　マスメハ　カクサレマス。”
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＧＭ＝ＧＭＤＥＭＯ

ＧＯＴＯ　＠ＤＥＭＯ

＠ＤＥＭＯＥＮＤ
ＧＯＳＵＢ　＠ＥＲＤＥＭＯ
ＭＥＳＴＣＨ＝ＦＡＬＳＥ
ＭＥＳＤＬＧ＝ＴＲＵＥ
ＭＥＳＴＩＴ＄＝””
ＭＳ＄＝”ケ゛ームヲ　ヤル？”
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＩＦ　ＭＥＳＲＥＴ＝＝ＦＡＬＳＥ　ＧＯＴＯ　＠ＥＮＤＩＮＩＴ

’＊＊＊　ケ゛ーム　リスタート　＊＊＊
＠ＲＥＳＴＡＲＴ

ＭＥＳＤＬＧ＝ＦＡＬＳＥ
ＭＥＳＴＣＨ＝ＦＡＬＳＥ
ＣＬＳ
ＧＰＡＧＥ　０：ＧＣＬＳ　０
ＧＰＡＧＥ　１：ＧＣＬＳ　０
ＧＯＳＵＢ　＠ＰＲＴＴＩＴＬＥ
ＧＯＳＵＢ　＠ＣＰＵＴＡＢＬＥ
ＧＯＳＵＢ　＠ＹＯＵＴＡＢＬＥ

’＊＊＊　ケ゛ーム　カイシ　＊＊＊

ＢＧＭＰＬＡＹ　ＢＧＭＧＡＭＥ
ＧＭ＝ＧＭＰＬＡＹ
ＧＯＳＵＢ　＠ＣＰＵＩＮＩ
ＧＯＳＵＢ　＠ＰＲＴＣＰＵＮ
ＧＯＳＵＢ　＠ＹＯＵＩＮＩ
ＧＯＳＵＢ　＠ＰＲＴＹＯＵＮ

ＭＥＳＷＡＩＴ＝１００
ＭＳ＄＝”○○○　ケ゛ーム　カイシ！　○○○”
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ

ＴＵＲＮ＝ＴＵＲＮ０
ＭＳ＄＝”ＣＰＵカ゛　センテ。”
ＩＦ　ＴＵＲＮ＝＝ＴＵＲＮＹＯＵ　ＴＨＥＮ　ＭＳ＄＝”アナタカ゛　センテ。”
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ

’＊＊＊　メイン　ルーフ゜　＊＊＊

ＩＦ　ＴＵＲＮ＝＝ＴＵＲＮＹＯＵ　ＧＯＴＯ　＠ＭＡＩＮＹＯＵ

＠ＭＡＩＮＬＯＯＰ

’ＣＰＵノ　ハ゛ン
＠ＭＡＩＮＣＰＵ
ＴＵＲＮ＝ＴＵＲＮＣＰＵ
ＧＲ＝ＲＥＡＣＨＮＯ
ＧＯＳＵＢ　＠ＣＰＵＴＵＲＮ

ＭＥＳＷＡＩＴ＝１００
ＭＳ＄＝”ＣＰＵハ　”＋ＳＴＲ＄（ＳＥＬＮ）＋”ヲ　ケシマシタ。”
ＢＥＥＰ　ＢＰＣＰＵＳＥＬ
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ

ＧＯＳＵＢ　＠ＣＨＫＹＯＵ
ＩＦ　ＧＭ＞ＧＭＰＬＡＹ　ＧＯＴＯ　＠ＧＡＭＥＥＮＤ
ＩＦ　ＧＲ！＝ＲＥＡＣＨＹＯＵ　ＧＯＴＯ　＠ＭＡＩＮＹＯＵ
ＭＳ＄＝”○○　アナタカ゛　リーチ！　○○”
ＢＥＥＰ　ＢＰＲＥＡＣＨ
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＧＯＴＯ　＠ＭＡＩＮＣＰＵ

’ＰＬＡＹＥＲノ　ハ゛ン
＠ＭＡＩＮＹＯＵ
ＴＵＲＮ＝ＴＵＲＮＹＯＵ
ＧＲ＝ＲＥＡＣＨＮＯ
ＧＯＳＵＢ　＠ＹＯＵＴＵＲＮ

ＭＥＳＷＡＩＴ＝１００
ＭＳ＄＝”アナタハ　”＋ＳＴＲ＄（ＳＥＬＮ）＋”ヲ　ケシマシタ。”
ＢＥＥＰ　ＢＰＹＯＵＳＥＬ
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ

ＧＯＳＵＢ　＠ＣＨＫＣＰＵ
ＩＦ　ＧＭ＞ＧＭＰＬＡＹ　ＧＯＴＯ　＠ＧＡＭＥＥＮＤ
ＩＦ　ＧＲ！＝ＲＥＡＣＨＣＰＵ　ＧＯＴＯ　＠ＭＡＩＮＬＯＯＰ
ＭＳ＄＝”○○　ＣＰＵカ゛　リーチ！　○○”
ＢＥＥＰ　ＢＰＲＥＡＣＨ
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＧＯＴＯ　＠ＭＡＩＮＣＰＵ

’＊＊＊　ケ゛ーム　シュウリョウ　＊＊＊
＠ＧＡＭＥＥＮＤ

’ケッカ　ヒョウシ゛
ＢＧＭＳＴＯＰ
ＧＯＳＵＢ　＠ＰＲＴＣＰＵＮ
ＩＦ　ＧＭ＝＝ＧＭＹＯＵＷＩＮ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＥＮＤＷＩＮ
ＩＦ　ＧＭ＝＝ＧＭＣＰＵＷＩＮ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＥＮＤＬＯＳＥ
ＩＦ　ＧＭ＝＝ＧＭＤＲＡＷ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＥＮＤＤＲＡＷ

’リフ゜レイ？
ＭＥＳＤＬＧ＝ＴＲＵＥ
ＭＳ＄＝”モウ１カイ　ヤル？”
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＩＦ　ＭＥＳＲＥＴ＝＝ＴＲＵＥ　ＧＯＴＯ　＠ＲＥＳＴＡＲＴ

’シュウリョウ　ショリ
＠ＥＮＤＩＮＩＴ
ＢＧＭＳＴＯＰ
ＣＬＳ
ＧＰＡＧＥ　０：ＧＣＬＳ　０
ＧＰＡＧＥ　１：ＧＣＬＳ　０
ＥＮＤ

’ＰＬＡＹＥＲノ　カチ
＠ＥＮＤＷＩＮ
ＢＧＭＰＬＡＹ　ＢＧＭＷＩＮ
ＷＩＮＹＯＵ＝ＷＩＮＹＯＵ＋１
ＧＯＳＵＢ　＠ＹＯＵＴＡＢＬＥ
ＧＯＳＵＢ　＠ＰＲＴＹＯＵＮ
ＭＳ＄＝”★★★　アナタノ　カチ！　★★★”
ＭＥＳＷＡＩＴ＝３００
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＴＵＲＮ０＝ＴＵＲＮＹＯＵ
ＲＥＴＵＲＮ

’ＣＰＵノ　カチ
＠ＥＮＤＬＯＳＥ
ＢＧＭＰＬＡＹ　ＢＧＭＬＯＳＥ
ＷＩＮＣＰＵ＝ＷＩＮＣＰＵ＋１
ＧＯＳＵＢ　＠ＣＰＵＴＡＢＬＥ
ＧＯＳＵＢ　＠ＰＲＴＣＰＵＮ
ＭＳ＄＝”★★★　ＣＰＵノ　カチ！　★★★”
ＭＥＳＷＡＩＴ＝３００
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＴＵＲＮ０＝ＴＵＲＮＣＰＵ
ＲＥＴＵＲＮ

’ヒキワケ
＠ＥＮＤＤＲＡＷ
ＢＧＭＰＬＡＹ　ＢＧＭＤＲＡＷ
ＭＳ＄＝”○○○　ヒキワケ　○○○”
ＭＥＳＷＡＩＴ＝３００
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ
ＲＥＴＵＲＮ

’＝＝＝＝＝　サフ゛ルーチン　＝＝＝＝＝

’＊＊＊　タイトル　ヒョウシ゛　＊＊＊
＠ＰＲＴＴＩＴＬＥ

ＧＰＡＧＥ　０
ＧＦＩＬＬ　０，０，２５５，２０，ＣＯＬＴＩＴＢＧ
ＧＣＯＬＯＲ　ＣＯＬＴＩＴＬＥ
Ｔ＄＝”○Ｘ　ＲＥＡＣＨ　ＧＡＭＥ　Ｘ○”
ＴＹ＝４
ＧＯＳＵＢ　＠ＰＲＴＣＨＲ２Ｘ
ＲＥＴＵＲＮ

’＊＊＊　テ゛モ　ヒョウシ゛　＊＊＊
＠ＰＲＴＤＥＭＯ

ＧＣＯＬＯＲ　ＣＯＬＤＥＭＯ
Ｔ＄＝”○セツメイ　テ゛モ　チュウ○”
ＴＹ＝１６０
ＧＯＳＵＢ　＠ＰＲＴＣＨＲ２Ｘ
Ｔ＄＝”タッチテ゛　スキッフ゜”
ＴＹ＝１７８
ＧＯＳＵＢ　＠ＰＲＴＣＨＲ２Ｘ
ＲＥＴＵＲＮ

’＊＊＊　テ゛モ　ショウキョ　＊＊＊
＠ＥＲＤＥＭＯ

ＧＰＡＧＥ　０
ＧＦＩＬＬ　０，１６０，２５５，１９４，０
ＲＥＴＵＲＮ

’２ハ゛イモシ゛　ヒョウシ゛　サフ゛
＠ＰＲＴＣＨＲ２Ｘ
ＧＰＡＧＥ　０
ＸＯ＝１２８－ＬＥＮ（Ｔ＄）＊８
ＦＯＲ　Ｉ＝０　ＴＯ　ＬＥＮ（Ｔ＄）－１
ＧＰＵＴＣＨＲ　ＸＯ＋Ｉ＊１６＋１，ＴＹ，”ＢＧＦ０”，ＡＳＣ（ＭＩＤ＄（Ｔ＄，Ｉ，１）），０，２
ＮＥＸＴ　Ｉ
ＲＥＴＵＲＮ

’＊＊＊　ＰＬＡＹＥＲマス　ショキセッテイ　＊＊＊
＠ＹＯＵＩＮＩ

Ｎ＝１
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＹＯＵＮ（Ｘ，Ｙ）＝Ｎ
Ｎ＝Ｎ＋１
ＮＥＸＴ　Ｙ
ＮＥＸＴ　Ｘ

ＦＯＲ　Ｎ＝１　ＴＯ　１００
Ｘ＝ＲＮＤ（５）：Ｙ＝ＲＮＤ（５）
Ｉ＝ＲＮＤ（５）：Ｊ＝ＲＮＤ（５）
Ｚ＝ＹＯＵＮ（Ｘ，Ｙ）
ＹＯＵＮ（Ｘ，Ｙ）＝ＹＯＵＮ（Ｉ，Ｊ）
ＹＯＵＮ（Ｉ，Ｊ）＝Ｚ
ＮＥＸＴ　Ｎ

ＲＥＴＵＲＮ

’＊＊＊　ＣＰＵマス　ショキセッテイ　＊＊＊
＠ＣＰＵＩＮＩ

Ｎ＝１
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＣＰＵＮ（Ｘ，Ｙ）＝Ｎ
Ｎ＝Ｎ＋１
ＮＥＸＴ　Ｙ
ＮＥＸＴ　Ｘ

ＦＯＲ　Ｎ＝１　ＴＯ　１００
Ｘ＝ＲＮＤ（５）：Ｙ＝ＲＮＤ（５）
Ｉ＝ＲＮＤ（５）：Ｊ＝ＲＮＤ（５）
Ｚ＝ＣＰＵＮ（Ｘ，Ｙ）
ＣＰＵＮ（Ｘ，Ｙ）＝ＣＰＵＮ（Ｉ，Ｊ）
ＣＰＵＮ（Ｉ，Ｊ）＝Ｚ
ＮＥＸＴ　Ｎ

ＲＥＴＵＲＮ

’＊＊＊　ＰＬＡＹＥＲノ　ハ゛ン　＊＊＊
＠ＹＯＵＴＵＲＮ

ＦＯＲ　Ｘ＝０　ＴＯ　４
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＴＨＫＮ（Ｘ，Ｙ）＝ＹＯＵＮ（Ｘ，Ｙ）
ＮＥＸＴ　Ｙ
ＮＥＸＴ　Ｘ

ＯＮ　ＧＭ＝＝ＧＭＤＥＭＯ　ＧＯＳＵＢ　＠ＹＯＵＴＨＫ，＠ＡＵＴＯＴＨＫ

ＹＯＵＮ（ＥＸ，ＥＹ）＝ＭＡＲＫＥＲ
ＧＯＳＵＢ　＠ＰＲＴＹＯＵＮ

ＦＯＲ　Ｙ＝０　ＴＯ　４
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＩＦ　ＣＰＵＮ（Ｘ，Ｙ）＝＝ＳＥＬＮ　ＴＨＥＮ　ＳＸ＝Ｘ：ＳＹ＝Ｙ：Ｘ＝４：Ｙ＝４
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ
ＣＰＵＮ（ＳＸ，ＳＹ）＝ＭＡＲＫＳＥＬ
ＩＦ　（ＧＭ＝＝ＧＭＤＥＭＯ　ＯＲ　ＤＭ＝＝ＴＲＵＥ）　ＴＨＥＮ　ＧＯＳＵＢ　＠ＰＲＴＣＰＵＮ

ＲＥＴＵＲＮ

’＊＊＊　ＰＬＡＹＥＲ　スウシ゛　センタク　＊＊＊
＠ＹＯＵＴＨＫ

ＭＥＳＷＡＩＴ＝０
ＭＳ＄＝”★ケシタイ　スウシ゛ヲ　タッチシテ　クタ゛サイ。”
ＧＯＳＵＢ　＠ＭＥＳＳＡＧＥ

＠ＴＣＨＬＯＯＰ
ＩＦ　ＴＣＨＳＴ＝＝ＦＡＬＳＥ　ＧＯＴＯ　＠ＴＣＨＬＯＯＰ
ＥＸ＝ＦＬＯＯＲ（（ＴＣＨＸ－ＹＯＵＸ＊８）／ＳＥＬＷＸ）
ＥＹ＝ＦＬＯＯＲ（（ＴＣＨＹ－ＹＯＵＹ＊８）／ＳＥＬＷＹ）
ＩＦ　（ＥＸ＜０　ＯＲ　ＥＸ＞４）　ＧＯＴＯ　＠ＴＣＨＬＯＯＰ
ＩＦ　（ＥＹ＜０　ＯＲ　ＥＹ＞４）　ＧＯＴＯ　＠ＴＣＨＬＯＯＰ
ＳＥＬＮ＝ＴＨＫＮ（ＥＸ，ＥＹ）
ＩＦ　（ＳＥＬＮ＝＝ＭＡＲＫＥＲ　ＯＲ　ＳＥＬＮ＝＝ＭＡＲＫＳＥＬ）　ＧＯＴＯ　＠ＴＣＨＬＯＯＰ

ＲＥＴＵＲＮ

’＊＊＊　ＣＰＵノ　ハ゛ン　＊＊＊
＠ＣＰＵＴＵＲＮ

ＦＯＲ　Ｘ＝０　ＴＯ　４
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＴＨＫＮ（Ｘ，Ｙ）＝ＣＰＵＮ（Ｘ，Ｙ）
ＮＥＸＴ　Ｙ
ＮＥＸＴ　Ｘ

ＧＯＳＵＢ　＠ＡＵＴＯＴＨＫ

ＣＰＵＮ（ＥＸ，ＥＹ）＝ＭＡＲＫＥＲ
ＩＦ　（ＧＭ＝＝ＧＭＤＥＭＯ　ＯＲ　ＤＭ＝＝ＴＲＵＥ）　ＴＨＥＮ　ＧＯＳＵＢ　＠ＰＲＴＣＰＵＮ

ＦＯＲ　Ｙ＝０　ＴＯ　４
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＩＦ　ＹＯＵＮ（Ｘ，Ｙ）＝＝ＳＥＬＮ　ＴＨＥＮ　ＳＸ＝Ｘ：ＳＹ＝Ｙ：Ｘ＝４：Ｙ＝４
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ
ＹＯＵＮ（ＳＸ，ＳＹ）＝ＭＡＲＫＳＥＬ
ＧＯＳＵＢ　＠ＰＲＴＹＯＵＮ

ＲＥＴＵＲＮ

’＊＊＊　シコウ　ルーチン　＊＊＊
＠ＡＵＴＯＴＨＫ

’オモミ　リセット
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＴＨＫＩ（Ｘ，Ｙ）＝０
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ

’オモミ　ケイサン　ヨコ
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＬＩＮＥＣ＝０
ＩＦ　Ｙ！＝２　ＴＨＥＮ　ＬＩＮＥＣ＝１
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＩＦ　ＴＨＫＮ（Ｘ，Ｙ）＝＝ＭＡＲＫＳＥＬ　ＴＨＥＮ　ＬＩＮＥＣ＝ＬＩＮＥＣ＋３
ＩＦ　ＴＨＫＮ（Ｘ，Ｙ）＝＝ＭＡＲＫＥＲ　ＴＨＥＮ　ＬＩＮＥＣ＝－１：Ｘ＝４
ＮＥＸＴ　Ｘ
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＴＨＫＩ（Ｘ，Ｙ）＝ＴＨＫＩ（Ｘ，Ｙ）＋ＬＩＮＥＣ
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ

’オモミ　ケイサン　タテ
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＬＩＮＥＣ＝０
ＩＦ　Ｘ！＝２　ＴＨＥＮ　ＬＩＮＥＣ＝１
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＩＦ　ＴＨＫＮ（Ｘ，Ｙ）＝＝ＭＡＲＫＳＥＬ　ＴＨＥＮ　ＬＩＮＥＣ＝ＬＩＮＥＣ＋３
ＩＦ　ＴＨＫＮ（Ｘ，Ｙ）＝＝ＭＡＲＫＥＲ　ＴＨＥＮ　ＬＩＮＥＣ＝－１：Ｙ＝４
ＮＥＸＴ　Ｙ
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＴＨＫＩ（Ｘ，Ｙ）＝ＴＨＫＩ（Ｘ，Ｙ）＋ＬＩＮＥＣ
ＮＥＸＴ　Ｙ
ＮＥＸＴ　Ｘ

’オモミ　ケイサン　ナナメ１
ＬＩＮＥＣ＝４
ＦＯＲ　ＸＹ＝０　ＴＯ　４
ＩＦ　ＴＨＫＮ（ＸＹ，ＸＹ）＝＝ＭＡＲＫＳＥＬ　ＴＨＥＮ　ＬＩＮＥＣ＝ＬＩＮＥＣ＋３
ＩＦ　ＴＨＫＮ（ＸＹ，ＸＹ）＝＝ＭＡＲＫＥＲ　ＴＨＥＮ　ＬＩＮＥＣ＝－１：ＸＹ＝４
ＮＥＸＴ　ＸＹ
ＦＯＲ　ＸＹ＝０　ＴＯ　４
ＴＨＫＩ（ＸＹ，ＸＹ）＝ＴＨＫＩ（ＸＹ，ＸＹ）＋ＬＩＮＥＣ
ＮＥＸＴ　ＸＹ

’オモミ　ケイサン　ナナメ２
ＬＩＮＥＣ＝４
ＦＯＲ　ＸＹ＝０　ＴＯ　４
ＩＦ　ＴＨＫＮ（４－ＸＹ，ＸＹ）＝＝ＭＡＲＫＳＥＬ　ＴＨＥＮ　ＬＩＮＥＣ＝ＬＩＮＥＣ＋３
ＩＦ　ＴＨＫＮ（４－ＸＹ，ＸＹ）＝＝ＭＡＲＫＥＲ　ＴＨＥＮ　ＬＩＮＥＣ＝－１：ＸＹ＝４
ＮＥＸＴ　ＸＹ
ＦＯＲ　ＸＹ＝０　ＴＯ　４
ＴＨＫＩ（４－ＸＹ，ＸＹ）＝ＴＨＫＩ（４－ＸＹ，ＸＹ）＋ＬＩＮＥＣ
ＮＥＸＴ　ＸＹ

’オモミ　サイショウ　マス
ＩＭ＝１００
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＩＦ　（ＴＨＫＩ（Ｘ，Ｙ）＜ＩＭ　ＡＮＤ　ＴＨＫＮ（Ｘ，Ｙ）＞０）　ＴＨＥＮ　ＩＭ＝ＴＨＫＩ（Ｘ，Ｙ）：ＥＸ＝Ｘ：ＥＹ＝Ｙ
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ

’ケス　スウシ゛　ケッテイ
ＳＥＬＮ＝ＴＨＫＮ（ＥＸ，ＥＹ）

ＲＥＴＵＲＮ

’＊＊＊　ＣＰＵマス　ヒョウシ゛　＊＊＊
＠ＣＰＵＴＡＢＬＥ

ＣＯＬＯＲ　ＣＯＬＴＢＬＴＩ
ＬＯＣＡＴＥ　ＣＰＵＸ，ＣＰＵＹ－１
ＰＲＩＮＴ　”ＣＰＵ　（”；ＷＩＮＣＰＵ；”ショウ）”

ＧＰＡＧＥ　０
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＧＸ＝ＣＰＵＸ＊８＋Ｘ＊ＳＥＬＷＸ：ＧＹ＝ＣＰＵＹ＊８＋Ｙ＊ＳＥＬＷＹ
ＧＢＯＸ　ＧＸ，ＧＹ，ＧＸ＋ＳＥＬＷＸ，ＧＹ＋ＳＥＬＷＹ，ＣＯＬＴＢＬＬＮ
ＧＦＩＬＬ　ＧＸ＋１，ＧＹ＋１，ＧＸ＋ＳＥＬＷＸ－１，ＧＹ＋ＳＥＬＷＹ－１，ＣＯＬＴＢＬＢＧ
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ

ＲＥＴＵＲＮ

’＊＊＊　ＰＬＡＹＥＲマス　ヒョウシ゛　＊＊＊
＠ＹＯＵＴＡＢＬＥ

ＣＯＬＯＲ　ＣＯＬＴＢＬＴＩ
ＰＮＬＳＴＲ　ＹＯＵＸ，ＹＯＵＹ－１，”アナタ　（”＋ＳＴＲ＄（ＷＩＮＹＯＵ）＋”ショウ）”

ＧＰＡＧＥ　１
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＧＸ＝ＹＯＵＸ＊８＋Ｘ＊ＳＥＬＷＸ：ＧＹ＝ＹＯＵＹ＊８＋Ｙ＊ＳＥＬＷＹ
ＧＢＯＸ　ＧＸ，ＧＹ，ＧＸ＋ＳＥＬＷＸ，ＧＹ＋ＳＥＬＷＹ，ＣＯＬＴＢＬＬＮ
ＧＦＩＬＬ　ＧＸ＋１，ＧＹ＋１，ＧＸ＋ＳＥＬＷＸ－１，ＧＹ＋ＳＥＬＷＹ－１，ＣＯＬＴＢＬＢＧ
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ

ＲＥＴＵＲＮ

’＊＊＊　ＣＰＵスウシ゛　ヒョウシ゛　＊＊＊
＠ＰＲＴＣＰＵＮ

ＧＰＡＧＥ　０
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＧＸ＝ＣＰＵＸ＊８＋Ｘ＊ＳＥＬＷＸ：ＧＹ＝ＣＰＵＹ＊８＋Ｙ＊ＳＥＬＷＹ
ＧＦＩＬＬ　ＧＸ＋１，ＧＹ＋１，ＧＸ＋ＳＥＬＷＸ－１，ＧＹ＋ＳＥＬＷＹ－１，ＣＯＬＴＢＬＢＧ
ＮＵＭ＝ＣＰＵＮ（Ｘ，Ｙ）
ＩＦ　ＧＭ＝＝ＧＭＰＬＡＹ　ＡＮＤ　ＤＭ＝＝ＦＡＬＳＥ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＰＲＴＳＥＣ
ＩＦ　（ＧＭ！＝ＧＭＰＬＡＹ　ＯＲ　ＤＭ＝＝ＴＲＵＥ）　ＡＮＤ　ＮＵＭ＞０　ＴＨＥＮ　ＧＯＳＵＢ　＠ＰＲＴＮ
ＩＦ　（ＧＭ！＝ＧＭＰＬＡＹ　ＯＲ　ＤＭ＝＝ＴＲＵＥ）　ＡＮＤ　ＮＵＭ＝＝ＭＡＲＫＥＲ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＰＲＴＥＲ
ＩＦ　（ＧＭ！＝ＧＭＰＬＡＹ　ＯＲ　ＤＭ＝＝ＴＲＵＥ）　ＡＮＤ　ＮＵＭ＝＝ＭＡＲＫＳＥＬ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＰＲＴＳＥＬ
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ
ＲＥＴＵＲＮ

’＊＊＊　ＰＬＡＹＥＲスウシ゛　ヒョウシ゛　＊＊＊
＠ＰＲＴＹＯＵＮ

ＧＰＡＧＥ　１
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＧＸ＝ＹＯＵＸ＊８＋Ｘ＊ＳＥＬＷＸ：ＧＹ＝ＹＯＵＹ＊８＋Ｙ＊ＳＥＬＷＹ
ＧＦＩＬＬ　ＧＸ＋１，ＧＹ＋１，ＧＸ＋ＳＥＬＷＸ－１，ＧＹ＋ＳＥＬＷＹ－１，ＣＯＬＴＢＬＢＧ
ＮＵＭ＝ＹＯＵＮ（Ｘ，Ｙ）
ＩＦ　ＮＵＭ＞０　ＴＨＥＮ　ＧＯＳＵＢ　＠ＰＲＴＮ
ＩＦ　ＮＵＭ＝＝ＭＡＲＫＥＲ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＰＲＴＥＲ
ＩＦ　ＮＵＭ＝＝ＭＡＲＫＳＥＬ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＰＲＴＳＥＬ
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ
ＲＥＴＵＲＮ

’＊＊＊　スウシ゛ヒョウシ゛　サフ゛　＊＊＊
＠ＰＲＴＮ
ＮＵＭ＄＝ＳＴＲ＄（ＮＵＭ）
ＯＮ　ＬＥＮ（ＮＵＭ＄）－１　ＧＯＳＵＢ　＠ＰＲＴＮ１，＠ＰＲＴＮ２
ＲＥＴＵＲＮ

＠ＰＲＴＮ１
Ｎ１＄＝ＭＩＤ＄（ＮＵＭ＄，０，１）
ＧＰＵＴＣＨＲ　ＧＸ＋４＋８，ＧＹ＋４，”ＢＧＦ０”，ＡＳＣ（Ｎ１＄），ＣＯＬＴＢＬＮ，２
ＲＥＴＵＲＮ

＠ＰＲＴＮ２
Ｎ１＄＝ＭＩＤ＄（ＮＵＭ＄，０，１）
Ｎ２＄＝ＭＩＤ＄（ＮＵＭ＄，１，１）
ＧＰＵＴＣＨＲ　ＧＸ＋４，ＧＹ＋４，”ＢＧＦ０”，ＡＳＣ（Ｎ１＄），ＣＯＬＴＢＬＮ，２
ＧＰＵＴＣＨＲ　ＧＸ＋４＋１６，ＧＹ＋４，”ＢＧＦ０”，ＡＳＣ（Ｎ２＄），ＣＯＬＴＢＬＮ，２
ＲＥＴＵＲＮ

＠ＰＲＴＥＲ
ＧＰＵＴＣＨＲ　ＧＸ＋４＋８，ＧＹ＋３，”ＢＧＦ０”，ＡＳＣ（”Ｘ”），ＣＯＬＴＢＬＥＲ，２
ＲＥＴＵＲＮ

＠ＰＲＴＳＥＬ
ＧＰＵＴＣＨＲ　ＧＸ＋４＋８，ＧＹ＋４，”ＢＧＦ０”，ＡＳＣ（”○”），ＣＯＬＴＢＬＳＬ，２
ＲＥＴＵＲＮ

＠ＰＲＴＳＥＣ
ＧＰＵＴＣＨＲ　ＧＸ＋４＋８，ＧＹ＋４，”ＢＧＦ０”，ＡＳＣ（”？”），ＣＯＬＴＢＬＳＣ，２
ＲＥＴＵＲＮ

’＊＊＊　ＣＰＵマス　ハンテイ　＊＊＊
＠ＣＨＫＣＰＵ

ＦＯＲ　Ｙ＝０　ＴＯ　４
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＴＨＫＮ（Ｘ，Ｙ）＝ＣＰＵＮ（Ｘ，Ｙ）
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ

ＧＯＳＵＢ　＠ＣＨＫＴＡＢＬＥ

ＩＦ　ＲＣ＝＝ＴＲＵＥ　ＴＨＥＮ　ＧＲ＝ＲＥＡＣＨＣＰＵ
ＩＦ　（ＤＣ＝＝ＴＲＵＥ　ＡＮＤ　ＷＣ＝＝ＦＡＬＳＥ）　ＴＨＥＮ　ＧＭ＝ＧＭＤＲＡＷ
ＩＦ　ＷＣ＝＝ＴＲＵＥ　ＴＨＥＮ　ＧＭ＝ＧＭＣＰＵＷＩＮ

ＲＥＴＵＲＮ

’＊＊＊　ＰＬＡＹＥＲマス　ハンテイ　＊＊＊
＠ＣＨＫＹＯＵ

ＦＯＲ　Ｙ＝０　ＴＯ　４
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＴＨＫＮ（Ｘ，Ｙ）＝ＹＯＵＮ（Ｘ，Ｙ）
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ

ＧＯＳＵＢ　＠ＣＨＫＴＡＢＬＥ

ＩＦ　ＲＣ＝＝ＴＲＵＥ　ＴＨＥＮ　ＧＲ＝ＲＥＡＣＨＹＯＵ
ＩＦ　（ＤＣ＝＝ＴＲＵＥ　ＡＮＤ　ＷＣ＝＝ＦＡＬＳＥ）　ＴＨＥＮ　ＧＭ＝ＧＭＤＲＡＷ
ＩＦ　ＷＣ＝＝ＴＲＵＥ　ＴＨＥＮ　ＧＭ＝ＧＭＹＯＵＷＩＮ

ＲＥＴＵＲＮ

’＊＊＊　マス　ハンテイ　サフ゛　＊＊＊
＠ＣＨＫＴＡＢＬＥ

ＧＲ＝ＲＥＡＣＨＮＯ
ＲＣ＝ＦＡＬＳＥ：ＷＣ＝ＦＡＬＳＥ：ＤＣ＝ＦＡＬＳＥ
ＬＮ＝ＬＩＮＥＮ（ＳＸ，ＳＹ）

’ヨコ　ハンテイ
＠ＣＨＫＸ
ＩＦ　（ＬＮ　ＡＮＤ　１）＝＝０　ＧＯＴＯ　＠ＣＨＫＹ
ＣＣ＝０
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＩＦ　ＴＨＫＮ（Ｘ，ＳＹ）＝＝ＭＡＲＫＳＥＬ　ＴＨＥＮ　ＣＣ＝ＣＣ＋１
ＩＦ　ＴＨＫＮ（Ｘ，ＳＹ）＝＝ＭＡＲＫＥＲ　ＴＨＥＮ　ＣＣ＝０：Ｘ＝４
ＮＥＸＴ　Ｘ
ＩＦ　ＣＣ＝＝５　ＴＨＥＮ　ＷＣ＝ＴＲＵＥ
ＩＦ　ＣＣ＝＝４　ＴＨＥＮ　ＲＣ＝ＴＲＵＥ

’タテ　ハンテイ
＠ＣＨＫＹ
ＩＦ　（ＬＮ　ＡＮＤ　２）＝＝０　ＧＯＴＯ　＠ＣＨＫＸＹ
ＣＣ＝０
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＩＦ　ＴＨＫＮ（ＳＸ，Ｙ）＝＝ＭＡＲＫＳＥＬ　ＴＨＥＮ　ＣＣ＝ＣＣ＋１
ＩＦ　ＴＨＫＮ（ＳＸ，Ｙ）＝＝ＭＡＲＫＥＲ　ＴＨＥＮ　ＣＣ＝０：Ｙ＝４
ＮＥＸＴ　Ｙ
ＩＦ　ＣＣ＝＝５　ＴＨＥＮ　ＷＣ＝ＴＲＵＥ
ＩＦ　ＣＣ＝＝４　ＴＨＥＮ　ＲＣ＝ＴＲＵＥ

’ナナメ　ハンテイ１
＠ＣＨＫＸＹ
ＩＦ　（ＬＮ　ＡＮＤ　４）＝＝０　ＧＯＴＯ　＠ＣＨＫＹＸ
ＣＣ＝０
ＦＯＲ　ＸＹ＝０　ＴＯ　４
ＩＦ　ＴＨＫＮ（ＸＹ，ＸＹ）＝＝ＭＡＲＫＳＥＬ　ＴＨＥＮ　ＣＣ＝ＣＣ＋１
ＩＦ　ＴＨＫＮ（ＸＹ，ＸＹ）＝＝ＭＡＲＫＥＲ　ＴＨＥＮ　ＣＣ＝０：ＸＹ＝４
ＮＥＸＴ　ＸＹ
ＩＦ　ＣＣ＝＝５　ＴＨＥＮ　ＷＣ＝ＴＲＵＥ
ＩＦ　ＣＣ＝＝４　ＴＨＥＮ　ＲＣ＝ＴＲＵＥ

’ナナメ　ハンテイ２
＠ＣＨＫＹＸ
ＩＦ　（ＬＮ　ＡＮＤ　８）＝＝０　ＧＯＴＯ　＠ＣＨＫＥＮＤ
ＣＣ＝０
ＦＯＲ　ＸＹ＝０　ＴＯ　４
ＩＦ　ＴＨＫＮ（４－ＸＹ，ＸＹ）＝＝ＭＡＲＫＳＥＬ　ＴＨＥＮ　ＣＣ＝ＣＣ＋１
ＩＦ　ＴＨＫＮ（４－ＸＹ，ＸＹ）＝＝ＭＡＲＫＥＲ　ＴＨＥＮ　ＣＣ＝０：ＸＹ＝４
ＮＥＸＴ　ＸＹ
ＩＦ　ＣＣ＝＝５　ＴＨＥＮ　ＷＣ＝ＴＲＵＥ
ＩＦ　ＣＣ＝＝４　ＴＨＥＮ　ＲＣ＝ＴＲＵＥ

＠ＣＨＫＥＮＤ

’ト゛ロー？
ＣＮ＝ＦＡＬＳＥ
ＦＯＲ　Ｙ＝０　ＴＯ　４
ＦＯＲ　Ｘ＝０　ＴＯ　４
ＩＦ　ＴＨＫＮ（Ｘ，Ｙ）＞０　ＴＨＥＮ　ＣＮ＝ＴＲＵＥ
ＮＥＸＴ　Ｘ
ＮＥＸＴ　Ｙ
ＩＦ　ＣＮ＝＝ＦＡＬＳＥ　ＴＨＥＮ　ＤＣ＝ＴＲＵＥ

ＲＥＴＵＲＮ

’＊＊＊　メッセーシ゛　ウイント゛ウ　＊＊＊
＠ＭＥＳＳＡＧＥ

’ウイント゛ウ
ＧＰＡＧＥ　１
ＧＦＩＬＬ　ＭＥＳＸ＊８－８，ＭＥＳＹ＊８－８，（ＭＥＳＸ＋３０）＊８＋８，（ＭＥＳＹ＋４）＊８＋８，ＣＯＬＭＥＳＢＧ
ＣＯＬＯＲ　ＣＯＬＭＥＳＦＬ
ＰＮＬＳＴＲ　ＭＥＳＸ－１，ＭＥＳＹ－１，”┌──────────────────────────────┐”
ＦＯＲ　Ｙ＝０　ＴＯ　３
ＰＮＬＳＴＲ　ＭＥＳＸ－１，ＭＥＳＹ＋Ｙ，”│　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　│”
ＮＥＸＴ　Ｙ
ＰＮＬＳＴＲ　ＭＥＳＸ－１，ＭＥＳＹ＋４，”└──────────────────────────────┘”

’ウイント゛ウ　タイトル
ＩＦ　ＭＥＳＴＩＴ＄＝＝””　ＧＯＴＯ　＠ＭＥＳＴＩＴＥＮ
ＸＯ＝ＦＬＯＯＲ（１４－ＬＥＮ（ＭＥＳＴＩＴ＄）／２）
ＰＮＬＳＴＲ　ＭＥＳＸ＋ＸＯ，ＭＥＳＹ－１，”［”＋ＭＥＳＴＩＴ＄＋”］”
＠ＭＥＳＴＩＴＥＮ

’メッセーシ゛　キ゛ョウフ゛ンカイ
ＦＯＲ　Ｉ＝０　ＴＯ　３
ＭＥＳ＄（Ｉ）＝””
ＮＥＸＴ　Ｉ
ＦＯＲ　Ｃ＝０　ＴＯ　ＬＥＮ（ＭＳ＄）－１
ＭＮ＝ＦＬＯＯＲ（Ｃ／３０）
ＭＥＳ＄（ＭＮ）＝ＭＥＳ＄（ＭＮ）＋ＭＩＤ＄（ＭＳ＄，Ｃ，１）
ＮＥＸＴ　Ｃ

’メッセーシ゛　ヒョウシ゛
ＸＯ＝０
ＩＦ　ＭＥＳＤＬＧ＝＝ＴＲＵＥ　ＴＨＥＮ　ＸＯ＝ＦＬＯＯＲ（１５－ＬＥＮ（ＭＥＳ＄（０））／２）
ＣＯＬＯＲ　ＣＯＬＭＥＳ
ＦＯＲ　Ｙ＝０　ＴＯ　３
ＰＮＬＳＴＲ　ＭＥＳＸ＋ＸＯ，ＭＥＳＹ＋Ｙ，ＭＥＳ＄（Ｙ）
ＮＥＸＴ　Ｙ

’タ゛イアロク゛／ワンタッチ／ウェイト
ＩＦ　ＭＥＳＤＬＧ＝＝ＴＲＵＥ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＭＥＳＤＬＧ：ＧＯＴＯ　＠ＭＥＳＥＮＤ
ＩＦ　ＭＥＳＴＣＨ＝＝ＴＲＵＥ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＭＥＳＴＣＨ：ＧＯＴＯ　＠ＭＥＳＥＮＤ
ＶＳＹＮＣ　ＭＥＳＷＡＩＴ

＠ＭＥＳＥＮＤ
ＲＥＴＵＲＮ

’＊＊＊　メッセーシ゛　タ゛イアロク゛　＊＊＊
＠ＭＥＳＤＬＧ

Ｂ１＄＝”ハイ”：ＢＷ１＝ＬＥＮ（Ｂ１＄）＋２
ＢＸ１＝ＭＥＳＸ＋８：ＢＹ１＝ＭＥＳＹ＋１
Ｂ２＄＝”イイエ”：ＢＷ２＝ＬＥＮ（Ｂ１＄）＋２
ＢＸ２＝ＭＥＳＸ＋１７：ＢＹ２＝ＭＥＳＹ＋１

ＰＮＬＳＴＲ　ＢＸ１，ＢＹ１，”┌──┐”
ＰＮＬＳＴＲ　ＢＸ１，ＢＹ１＋１，”│”＋Ｂ１＄＋”│”
ＰＮＬＳＴＲ　ＢＸ１，ＢＹ１＋２，”└──┘”
ＰＮＬＳＴＲ　ＢＸ２，ＢＹ２，”┌───┐”
ＰＮＬＳＴＲ　ＢＸ２，ＢＹ２＋１，”│”＋Ｂ２＄＋”│”
ＰＮＬＳＴＲ　ＢＸ２，ＢＹ２＋２，”└───┘”

’ホ゛タン　タッチ　マチ
＠ＭＥＳＤＬＧＬＰ
ＩＦ　ＴＣＨＳＴ＝＝ＦＡＬＳＥ　ＧＯＴＯ　＠ＭＥＳＤＬＧＬＰ
ＴＸ＝ＦＬＯＯＲ（ＴＣＨＸ／８）：ＴＹ＝ＦＬＯＯＲ（ＴＣＨＹ／８）
ＭＥＳＢＴＮ＝ＦＡＬＳＥ
ＩＦ　ＢＸ１＜＝ＴＸ　ＡＮＤ　ＴＸ＜＝ＢＸ１＋ＢＷ１　ＴＨＥＮ　ＭＥＳＢＴＮ＝ＴＲＵＥ：ＭＥＳＲＥＴ＝ＴＲＵＥ
ＩＦ　ＢＸ２＜＝ＴＸ　ＡＮＤ　ＴＸ＜＝ＢＸ２＋ＢＷ２　ＴＨＥＮ　ＭＥＳＢＴＮ＝ＴＲＵＥ：ＭＥＳＲＥＴ＝ＦＡＬＳＥ
ＩＦ　ＭＥＳＢＴＮ＝＝ＦＡＬＳＥ　ＧＯＴＯ　＠ＭＥＳＤＬＧＬＰ
ＢＥＥＰ　ＢＰＹＯＵＳＥＬ

ＲＥＴＵＲＮ

’＊＊＊　メッセーシ゛　ワンタッチ　マチ　＊＊＊
＠ＭＥＳＴＣＨ

ＭＥＳＲＥＴ＝ＦＡＬＳＥ
ＴＩＭＥ０＝ＭＡＩＮＣＮＴＬ

＠ＭＥＳＴＣＨＬＰ
ＴＩＭＥ１＝ＭＡＩＮＣＮＴＬ－ＴＩＭＥ０
ＩＦ　（ＴＣＨＳＴ＝＝ＦＡＬＳＥ　ＡＮＤ　ＴＩＭＥ１＜ＭＥＳＴＩＭＥ）　ＧＯＴＯ　＠ＭＥＳＴＣＨＬＰ

ＩＦ　ＴＣＨＳＴ＝＝ＴＲＵＥ　ＴＨＥＮ　ＭＥＳＲＥＴ＝ＴＲＵＥ

ＲＥＴＵＲＮ

CHECKER FLAG (ひとことコメント)

この作品に対するコメントがあれば一言どうぞ。(作品に直接関係ない質問や雑談は掲示板へ)

名無しさん : 面白いですね (2011/12/02 (金) 02:16:57)
shiro : YouTubeにプレイ動画を投稿したので、こちらも追加しました。 (2011/12/07 (水) 19:00:19)
shiro : プログラムリストにいくつか打ち間違いがあったので修正しました。すみませんでした。 (2011/12/13 (火) 01:15:39)
初心者 : たまにCPUが”－１”を選択するときがあるんですが、これは仕様ですか？ (2012/01/30 (月) 14:49:36)
shiro : 「-1」を選択してしまうのはおかしいですね。確認してみます。 (2012/01/31 (火) 11:02:12)
shiro : 533行目の重み計算の初期値を増やしてみました。これで試してみてください。>初心者さん (2012/02/01 (水) 11:24:24)
shiro : 533行目の重み計算の初期値を増やしてみました。これで試してみてください。>初心者さん (2012/02/01 (水) 13:14:33)
初心者 : ありがとうございました。これからやってみます。（状況を思い出してみると勝敗が”ＤＲＡＷ”だったような…あれから何回かチャレンジしても”－１”がでないのは”ＤＲＡＷ”にもっていけないからかな…） (2012/02/02 (木) 16:37:46)
初心者 : おもしろいので、3人 (2012/02/02 (木) 16:40:20)
初心者 : ↑の続き…で机上でやってみたら、終盤にリーチの嵐で集中砲火にあいました。もしかして2人専用かな？ (2012/02/02 (木) 16:42:57)
shiro : 基本的に2人でやるゲームです。中学時代によく友達と対戦したものでした。 (2012/02/03 (金) 00:22:35)
shiro : ニコニコ動画をプレーヤー表示にしました。 (2012/02/16 (木) 22:26:07)
shiro : mkII用のQRコードを載せました。 (2012/03/14 (水) 17:18:20)
ウイング : ８２４・・・　mk (2012/03/15 (木) 16:12:48)
名無しさん : ↑↑ｑｒコード出てない･･･ (2012/03/15 (木) 19:55:03)
ウイング : これはＱＲないと・・・長い・・・ (2012/03/15 (木) 19:57:28)
shiro : 私が試した限りではQRコードはちゃんと見えているのですが、名無しさん、ウイングさんはどんな環境でこのページを見ていますか？ (2012/03/16 (金) 03:23:21)
orirakkusu : 3DSでもちゃんと見えてますよー。 (2012/03/16 (金) 09:04:02)
ウイング : ＰＣです。ちなみにｍｋⅡ持ってないのでＱＲはよくわかりません (2012/03/16 (金) 15:28:01)
名無しさん : ↑↑↑Windows XPです。 (2012/03/16 (金) 18:25:37)
shiro : QRコードを表で並べると、IE8で見えないようなので、1枚の合成画像にしました。 (2012/03/17 (土) 00:08:28)
名無しさん : shiroさん、お疲れ様です (2012/03/17 (土) 00:14:20)
プチコンまとめWiki管理人 : IE8以前での画像表示不具合を修正しました。ご迷惑をおかけしました。詳しくは簡素ブロックくずしのページにコメントを残しました。 (2012/03/17 (土) 00:54:26)
shiro : プチコンmkII Ver2.1を使って再保存して、QRコードの枚数を減らしました。 (2012/05/02 (水) 13:03:44)
名無しさん : 世界一イラつきゲー (2012/08/27 (月) 09:35:39)

メニュー【mkII】

プチコン3号まとめWiki

ヘルプ

リンク

Petit Computer Wiki

プチコンリンク集

オンライン情報

現在同時に 1 人がこのサイトを見ています

ページの先頭に戻る

プチコンまとめWiki (初代/mkII)