プチコンまとめWiki (初代/mkII)

投稿プログラム : 簡素ブロックくずし

パンくずリスト

2011年12月07日投稿 / 投稿者 : shiro / タグ : 投稿プログラム ゲーム アクションゲーム QRコード 初代対応

概要

昔のアーケードゲームを思い出しながら作りました。
公式のプログラムリストにもブロックくずしがありますが、あえて１から自分で作ってみました。

遊び方

起動するとデモ画面が出ます。Aボタンでゲームがスタートします。
パドルは下画面をタッチして動かしてください。十字キーには対応していません。
アイテムなどは何も出ません。ひたすらボールを打ち返してブロックを消してください。
向こう側の壁にボールが当たると、パドルの長さが半分になります。
ボールは3個です。400点でボールが1個追加されます。
2面クリアしても終わりません。ずっと続きます。

おまけ

DSiLLで開発しています。3DSだとボールが速過ぎると思いますので、49行目のウェイトの値を増やしてください。
かつて8ビットマシンの時代にブロックくずしを作りましたが、BASICでは速度が足りず、マシン語ルーチンを組み込んで何とか遊べる代物になりました。
今はオールBASICでこれだけ高速なブロックくずしが作れるんですね。楽しいです。
ゲームタイトルは最初「元祖ブロックくずし」にしようと思ったのですが、既に使っている人がいたので、「簡素」にしてみました。

スクリーンショット・動画

demo2.jpg
game2.jpg

QR コード

プチコンmkII 向けの QR コードです。

12
qr2-1.pngqr2-2.png
34
qr2-3.pngqr2-4.png

プログラムリスト

  1. ’＊＊＊＊＊＊＊＊＊＊＊＊＊＊
  2. ’＊　　　　　　　　　　　　＊
  3. ’＊　　　　カンソ　　　　　＊
  4. ’＊　フ゛ロック　クス゛シ　＊
  5. ’＊　　　　　　　　　　　　＊
  6. ’＊　２０１２．１．１９　　＊
  7. ’＊　　ｂｙ　ｓｈｉｒｏ　　＊
  8. ’＊　　　　　　　　　　　　＊
  9. ’＊＊＊＊＊＊＊＊＊＊＊＊＊＊
  11. ’＊＊＊　ショキ　セッテイ　＊＊＊
  13. ＣＬＥＡＲ
  14. ＶＩＳＩＢＬＥ　１，０，０，０，１，１
  15. ＰＮＬＴＹＰＥ　”ＯＦＦ”
  16. ＣＬＳ
  17. ＧＰＡＧＥ　０：ＧＣＬＳ　０
  18. ＧＰＡＧＥ　１：ＧＣＬＳ　０
  19. ＢＧＭＳＴＯＰ
  20. ＧＰＡＧＥ　０
  21. ＳＰＰＡＧＥ　０
  23. ＤＩＭ　ＢＬＯＣＫ（１４，８），ＣＯＬＢＬＫ（８）
  25. ’ケ゛ーム　モート゛
  26. ＧＭＤＥＭＯ＝０
  27. ＧＭＰＬＡＹ＝１
  28. ＧＭＭＩＳＳ＝２
  30. ’フ゛ロック
  31. ＢＬＯＣＫＭＡＸ＝１４＊８
  32. ＢＬＫＯＸ＝５６：ＢＬＫＯＹ＝１６
  33. ＢＬＫＷＸ＝１４：ＢＬＫＷＹ＝６
  35. ’スクリーン　サイス゛
  36. ＳＣＲＭＩＮＸ＝５５：ＳＣＲＭＡＸＸ＝ＳＣＲＭＩＮＸ＋ＢＬＫＷＸ＊１４＋２
  37. ＳＣＲＭＩＮＹ＝０：ＳＣＲＭＡＸＹ＝１９１
  39. ’ハ゜ト゛ル
  40. ＰＡＤＩＸ＝１５０：ＰＡＤＹ＝１８９
  41. ＰＡＤＷＬ＝２８：ＰＡＤＷＳ＝１４
  42. ＰＡＤＷＹ＝２
  44. ’ホ゛ール
  45. ＳＰＳＥＴ　０，２５４，１，０，０，０
  46. ＳＰＳＣＡＬＥ　０，１５０
  47. ＢＡＬＬＭＡＸ＝３
  48. ＢＡＬＬＩＸ＝１１０：ＢＡＬＬＩＹ＝８２
  49. ＢＡＬＬＷＴ０＝１２：ＢＡＬＬＷＴ１＝１０
  51. ’スコア
  52. ＳＣＯＲＥＸ＝０：ＳＣＯＲＥＹ＝０
  53. ＳＣＯＲＥＢ＝４００
  55. ’ホ゛ール　ノコリ
  56. ＢＡＬＬＣＸ＝０：ＢＡＬＬＣＹ＝３
  58. ’メッセーシ゛
  59. ＭＥＳＸ＝１２：ＭＥＳＹ＝１３
  61. ’カラー
  62. ＣＯＬＰＡＤ＝１５
  63. ＣＯＬＷＡＬＬ＝１５
  64. ＣＯＬＭＥＳ＝０
  65. ＣＯＬＳＣＯＲＥ＝０：ＣＯＬＢＡＬＬＣ＝０
  67. ＦＯＲ　Ｙ＝０　ＴＯ　７
  68. ＲＥＡＤ　ＣＯＬＢＬＫ（Ｙ）
  69. ＮＥＸＴ　Ｙ
  70. ＤＡＴＡ　３，３，１２，１２，１１，１１，１５，１５
  72. ’サウント゛
  73. ＢＰＰＡＤ＝４０９６：ＢＰＷＡＬＬ＝２０４８：ＢＰＢＬＯＣＫ＝０
  74. ＢＰＢＯＮＵＳ＝３
  76. ＧＯＳＵＢ　＠ＩＮＩＢＬＯＣＫ
  77. ＧＯＳＵＢ　＠ＰＲＴＳＣＯＲＥ
  78. ＧＯＳＵＢ　＠ＰＲＴＢＡＬＬＣ
  80. ’＊＊＊　テ゛モ　＊＊＊
  81. ＠ＤＥＭＯ
  83. ＧＭ＝ＧＭＤＥＭＯ
  84. ＧＯＳＵＢ　＠ＰＲＴＢＬＯＣＫ
  85. ＢＡＬＬＳＰ＝３
  86. ＢＡＬＬＸ＝ＢＡＬＬＩＸ：ＢＡＬＬＹ＝ＢＡＬＬＩＹ
  87. ＢＡＬＬＤＸ＝１：ＢＡＬＬＤＹ＝１
  88. ＧＯＳＵＢ　＠ＰＲＴＰＡＤＬＮ
  90. ＣＯＬＯＲ　ＣＯＬＭＥＳ
  91. ＬＯＣＡＴＥ　ＭＥＳＸ，ＭＥＳＹ
  92. ＰＲＩＮＴ　”ＰＵＳＨ　Ａ　ＴＯ　ＳＴＡＲＴ”
  93. ＬＯＣＡＴＥ　ＭＥＳＸ，ＭＥＳＹ＋２
  94. ＰＲＩＮＴ　”　ＰＵＳＨ　Ｂ　ＴＯ　ＥＮＤ”
  96. ＠ＤＥＭＯＬＯＯＰ
  97. ＧＯＳＵＢ　＠ＭＯＶＥＢＡＬＬ
  98. ＦＯＲ　Ｉ＝０　ＴＯ　ＢＡＬＬＷＴ０＋ＢＡＬＬＷＴ１＊ＢＡＬＬＳＰ：ＧＯＳＵＢ　＠ＰＲＴＷＡＬＬ：ＮＥＸＴ　Ｉ
  99. ＩＦ　（ＢＵＴＴＯＮ（）　ＡＮＤ　１６）！＝０　ＧＯＴＯ　＠ＧＡＭＥＩＮＩＴ
  100. ＩＦ　（ＢＵＴＴＯＮ（）　ＡＮＤ　３２）！＝０　ＧＯＴＯ　＠ＥＮＤＩＮＩＴ
  101. ＧＯＴＯ　＠ＤＥＭＯＬＯＯＰ
  103. ’＊＊＊　ケ゛ーム　ショキカ　＊＊＊
  104. ＠ＧＡＭＥＩＮＩＴ
  106. ＳＣＯＲＥ＝０
  107. ＢＡＬＬＣ＝ＢＡＬＬＭＡＸ
  108. ＣＬＢＬＯＣＫ＝ＦＡＬＳＥ
  110. ＣＬＳ：ＧＣＬＳ　０
  111. ＧＯＳＵＢ　＠ＰＲＴＷＡＬＬ
  112. ＧＯＳＵＢ　＠ＩＮＩＢＬＯＣＫ
  113. ＧＯＳＵＢ　＠ＰＲＴＢＬＯＣＫ
  114. ＧＯＳＵＢ　＠ＰＲＴＳＣＯＲＥ
  116. ’＊＊＊　ケ゛ーム　リスタート　＊＊＊
  117. ＠ＲＥＳＴＡＲＴ
  119. ＧＭ＝ＧＭＰＬＡＹ
  120. ＢＡＬＬＳＰ＝３
  121. ＢＡＬＬＤＸ＝１：ＢＡＬＬＤＹ＝１
  122. ＰＡＤＸ＝ＰＡＤＩＸ：ＰＡＤＷＸ＝ＰＡＤＷＬ
  123. ＰＡＤＲＦＣ＝０
  124. ＲＦＰＡＤ＝ＦＡＬＳＥ：ＲＦＢＬＯＣＫ＝ＦＡＬＳＥ
  126. ＧＯＳＵＢ　＠ＰＲＴＰＡＤ
  127. ＧＯＳＵＢ　＠ＰＲＴＢＡＬＬＣ
  128. ＢＡＬＬＸ＝ＢＡＬＬＩＸ：ＢＡＬＬＹ＝ＢＡＬＬＩＹ
  129. ＧＯＳＵＢ　＠ＰＲＴＢＡＬＬ
  130. ＶＳＹＮＣ　１５０
  132. ’＊＊＊　メイン　ルーフ゜　＊＊＊
  133. ＠ＭＡＩＮＬＯＯＰ
  135. ＧＯＳＵＢ　＠ＭＯＶＥＰＡＤ
  136. ＧＯＳＵＢ　＠ＭＯＶＥＢＡＬＬ
  137. ＦＯＲ　Ｉ＝０　ＴＯ　ＢＡＬＬＷＴ０＋ＢＡＬＬＷＴ１＊ＢＡＬＬＳＰ：ＧＯＳＵＢ　＠ＰＲＴＷＡＬＬ：ＮＥＸＴ　Ｉ
  138. ＩＦ　ＧＭ＝＝ＧＭＰＬＡＹ　ＧＯＴＯ　＠ＭＡＩＮＬＯＯＰ
  140. ’＊＊＊　ミス　＊＊＊
  142. ＶＳＹＮＣ　１５０
  143. ＢＡＬＬＣ＝ＢＡＬＬＣ−１
  144. ＧＯＳＵＢ　＠ＰＲＴＢＡＬＬＣ
  145. ＩＦ　ＢＡＬＬＣ＝＝０　ＧＯＴＯ　＠ＤＥＭＯ
  147. ＧＯＳＵＢ　＠ＥＲＣＰＡＤ
  148. ＧＯＴＯ　＠ＲＥＳＴＡＲＴ
  150. ’＊＊＊　ケ゛ーム　シュウリョウ　＊＊＊
  151. ＠ＥＮＤＩＮＩＴ
  153. ＶＩＳＩＢＬＥ　１，１，１，１，１，１
  154. ＣＬＳ
  155. ＧＰＡＧＥ　０：ＧＣＬＳ　０
  156. ＳＰＣＬＲ
  157. ＥＮＤ
  159. ’＝＝＝＝＝　サフ゛ルーチン　＝＝＝＝＝
  161. ’＊＊＊　カヘ゛　ヒョウシ゛　＊＊＊
  162. ＠ＰＲＴＷＡＬＬ
  163. ＧＬＩＮＥ　ＳＣＲＭＩＮＸ，ＳＣＲＭＩＮＹ，ＳＣＲＭＩＮＸ，ＳＣＲＭＡＸＹ，ＣＯＬＷＡＬＬ
  164. ＧＬＩＮＥ　ＳＣＲＭＡＸＸ，ＳＣＲＭＩＮＹ，ＳＣＲＭＡＸＸ，ＳＣＲＭＡＸＹ，ＣＯＬＷＡＬＬ
  165. ＲＥＴＵＲＮ
  167. ’＊＊＊　テ゛モ　ハ゜ト゛ルライン　ヒョウシ゛　＊＊＊
  168. ＠ＰＲＴＰＡＤＬＮ
  169. ＧＦＩＬＬ　ＳＣＲＭＩＮＸ＋１，ＰＡＤＹ，ＳＣＲＭＡＸＸ−１，ＰＡＤＹ＋ＰＡＤＷＹ，ＣＯＬＰＡＤ
  170. ＲＥＴＵＲＮ
  172. ’＊＊＊　フ゛ロック　ショキカ　＊＊＊
  173. ＠ＩＮＩＢＬＯＣＫ
  175. ＢＬＯＣＫＣ＝ＢＬＯＣＫＭＡＸ
  176. ＦＯＲ　Ｘ＝０　ＴＯ　１３
  177. ＢＬＯＣＫ（Ｘ，０）＝７：ＢＬＯＣＫ（Ｘ，１）＝７
  178. ＢＬＯＣＫ（Ｘ，２）＝５：ＢＬＯＣＫ（Ｘ，３）＝５
  179. ＢＬＯＣＫ（Ｘ，４）＝３：ＢＬＯＣＫ（Ｘ，５）＝３
  180. ＢＬＯＣＫ（Ｘ，６）＝１：ＢＬＯＣＫ（Ｘ，７）＝１
  181. ＮＥＸＴ　Ｘ
  182. ＲＥＴＵＲＮ
  184. ’＊＊＊　フ゛ロック　ヒョウシ゛　＊＊＊
  185. ＠ＰＲＴＢＬＯＣＫ
  187. ＦＯＲ　Ｘ＝０　ＴＯ　１３
  188. ＦＯＲ　Ｙ＝０　ＴＯ　７
  189. ＩＦ　ＢＬＯＣＫ（Ｘ，Ｙ）＝＝０　ＴＨＥＮ　＠ＰＲＴＢＬＫ２
  190. ＧＸ＝ＢＬＫＯＸ＋Ｘ＊ＢＬＫＷＸ
  191. ＧＹ＝ＢＬＫＯＹ＋Ｙ＊ＢＬＫＷＹ
  192. ＧＣＯＬＯＲ　ＣＯＬＢＬＫ（Ｙ）
  193. ＧＦＩＬＬ　ＧＸ＋１，ＧＹ＋１，ＧＸ＋ＢＬＫＷＸ−１，ＧＹ＋ＢＬＫＷＹ−１
  194. ＠ＰＲＴＢＬＫ２
  195. ＮＥＸＴ　Ｙ
  196. ＮＥＸＴ　Ｘ
  198. ＲＥＴＵＲＮ
  200. ’＊＊＊　ハ゜ト゛ルヲ　ウコ゛カス　＊＊＊
  201. ＠ＭＯＶＥＰＡＤ
  203. ＧＯＳＵＢ　＠ＥＲＣＰＡＤ
  204. ＩＦ　ＴＣＨＳＴ＝＝ＴＲＵＥ　ＴＨＥＮ　ＰＡＤＸ＝ＴＣＨＸ
  205. ＩＦ　ＰＡＤＸ−ＰＡＤＷＸ／２＜＝ＳＣＲＭＩＮＸ　ＴＨＥＮ　ＰＡＤＸ＝ＳＣＲＭＩＮＸ＋ＰＡＤＷＸ／２
  206. ＩＦ　ＰＡＤＸ＋ＰＡＤＷＸ／２＞＝ＳＣＲＭＡＸＸ−１　ＴＨＥＮ　ＰＡＤＸ＝ＳＣＲＭＡＸＸ−ＰＡＤＷＸ／２−１
  207. ＧＯＳＵＢ　＠ＰＲＴＰＡＤ
  209. ＲＥＴＵＲＮ
  211. ’ハ゜ト゛ル　ヒョウシ゛
  212. ＠ＰＲＴＰＡＤ
  213. ＧＦＩＬＬ　ＰＡＤＸ−ＰＡＤＷＸ／２＋１，ＰＡＤＹ，ＰＡＤＹ＋ＰＡＤＷＹ，ＣＯＬＰＡＤ
  214. ＲＥＴＵＲＮ
  216. ’ハ゜ト゛ル　ショウキョ
  217. ＠ＥＲＣＰＡＤ
  218. ＧＦＩＬＬ　ＰＡＤＸ−ＰＡＤＷＸ／２＋１，ＰＡＤＹ，ＰＡＤＹ＋ＰＡＤＷＹ，０
  219. ＲＥＴＵＲＮ
  221. ’＊＊＊　ホ゛ールヲ　ウコ゛カス　＊＊＊
  222. ＠ＭＯＶＥＢＡＬＬ
  224. ＩＦ　ＢＡＬＬＸ＜＝ＳＣＲＭＩＮＸ＋２　ＴＨＥＮ　ＧＯＳＵＢ　＠ＲＦＷＡＬＬＬ
  225. ＩＦ　ＢＡＬＬＸ＞＝ＳＣＲＭＡＸＸ−２　ＴＨＥＮ　ＧＯＳＵＢ　＠ＲＦＷＡＬＬＲ
  226. ＩＦ　ＢＡＬＬＹ＜ＳＣＲＭＩＮＹ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＲＦＷＡＬＬＵ
  227. ＩＦ　ＢＡＬＬＹ＞ＳＣＲＭＡＸＹ＋１　ＴＨＥＮ　ＧＯＳＵＢ　＠ＲＦＭＩＳＳ：ＲＥＴＵＲＮ
  229. ＩＦ　ＢＡＬＬＹ＜ＰＡＤＹ−２　ＯＲ　ＢＡＬＬＹ＞ＰＡＤＹ　ＴＨＥＮ　ＲＦＰＡＤ＝ＦＡＬＳＥ：ＧＯＴＯ　＠ＮＯＰＡＤ
  230. ＩＦ　ＧＭ＝＝ＧＭＤＥＭＯ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＲＦＰＡＤＬＮ：ＧＯＴＯ　＠ＮＯＰＡＤ
  231. ＩＦ　０＜＝ＰＡＤＸ−ＢＡＬＬＸ　ＡＮＤ　ＰＡＤＸ−ＢＡＬＬＸ＜＝ＰＡＤＷＸ／２　ＡＮＤ　ＲＦＰＡＤ＝＝ＦＡＬＳＥ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＲＦＰＡＤＬ
  232. ＩＦ　０＜ＢＡＬＬＸ−ＰＡＤＸ　ＡＮＤ　ＢＡＬＬＸ−ＰＡＤＸ＜＝ＰＡＤＷＸ／２＋１　ＡＮＤ　ＲＦＰＡＤ＝＝ＦＡＬＳＥ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＲＦＰＡＤＲ
  233. ＠ＮＯＰＡＤ
  235. ＠ＣＨＫＢＬＯＣＫ
  236. ＩＦ　ＲＦＢＬＯＣＫ＝＝ＴＲＵＥ　ＧＯＴＯ　＠ＮＯＢＬＯＣＫ
  237. ＢＸ＝ＦＬＯＯＲ（（ＢＡＬＬＸ−ＢＬＫＯＸ）／ＢＬＫＷＸ）
  238. ＢＹ＝ＦＬＯＯＲ（（ＢＡＬＬＹ−ＢＬＫＯＹ）／ＢＬＫＷＹ）
  239. ＩＦ　ＢＹ＜０　ＯＲ　ＢＹ＞７　ＧＯＴＯ　＠ＮＯＢＬＯＣＫ
  240. ＩＦ　ＢＬＯＣＫ（ＢＸ，ＢＹ）＞０　ＴＨＥＮ　ＧＯＳＵＢ　＠ＲＦＢＬＯＣＫ
  241. ＠ＮＯＢＬＯＣＫ
  243. ＢＡＬＬＸ＝ＢＡＬＬＸ＋ＢＡＬＬＤＸ
  244. ＢＡＬＬＹ＝ＢＡＬＬＹ＋ＢＡＬＬＤＹ
  245. ＧＯＳＵＢ　＠ＰＲＴＢＡＬＬ
  247. ＲＥＴＵＲＮ
  249. ’ホ゛ール　ヒョウシ゛
  250. ＠ＰＲＴＢＡＬＬ
  251. ＳＰＯＦＳ　０，ＢＡＬＬＸ−１２，ＢＡＬＬＹ−１２
  252. ＲＥＴＵＲＮ
  254. ’ハンシャ　ハ゜ト゛ル　ヒタ゛リ
  255. ＠ＲＦＰＡＤＬ
  256. ＢＥＥＰ　０，ＢＰＰＡＤ
  257. ＢＡＬＬＤＸ＝−１：ＢＡＬＬＤＹ＝−ＢＡＬＬＤＹ
  258. ＧＯＳＵＢ　＠ＢＡＬＬＰＴＲＮ
  259. ＲＦＰＡＤ＝ＴＲＵＥ：ＲＦＢＬＯＣＫ＝ＦＡＬＳＥ
  260. ＩＦ　ＣＬＢＬＯＣＫ＝＝ＴＲＵＥ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＰＲＴＢＬＯＣＫ：ＣＬＢＬＯＣＫ＝ＦＡＬＳＥ
  261. ＲＥＴＵＲＮ
  263. ’ハンシャ　ハ゜ト゛ル　ミキ゛
  264. ＠ＲＦＰＡＤＲ
  265. ＢＥＥＰ　０，ＢＰＰＡＤ
  266. ＢＡＬＬＤＸ＝１：ＢＡＬＬＤＹ＝−ＢＡＬＬＤＹ
  267. ＧＯＳＵＢ　＠ＢＡＬＬＰＴＲＮ
  268. ＲＦＰＡＤ＝ＴＲＵＥ：ＲＦＢＬＯＣＫ＝ＦＡＬＳＥ
  269. ＩＦ　ＣＬＢＬＯＣＫ＝＝ＴＲＵＥ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＰＲＴＢＬＯＣＫ：ＣＬＢＬＯＣＫ＝ＦＡＬＳＥ
  270. ＲＥＴＵＲＮ
  272. ’ハンシャ　ハ゜ト゛ルライン
  273. ＠ＲＦＰＡＤＬＮ
  274. ＢＡＬＬＤＹ＝−ＢＡＬＬＤＹ
  275. ＧＯＳＵＢ　＠ＢＡＬＬＰＴＲＮ
  276. ＲＦＢＬＯＣＫ＝ＦＡＬＳＥ
  277. ＲＥＴＵＲＮ
  279. ’ホ゛ール　ハ゜ターン
  280. ＠ＢＡＬＬＰＴＲＮ
  281. ＰＡＤＲＦＣ＝ＰＡＤＲＦＣ＋１
  282. ＩＦ　ＰＡＤＲＦＣ＝＝５　ＡＮＤ　ＢＡＬＬＳＰ！＝０　ＴＨＥＮ　ＢＡＬＬＳＰ＝２
  283. ＩＦ　ＰＡＤＲＦＣ＝＝１１　ＡＮＤ　ＢＡＬＬＳＰ！＝０　ＴＨＥＮ　ＢＡＬＬＤＹ＝−０．５
  284. ＩＦ　ＰＡＤＲＦＣ＝＝１５　ＡＮＤ　ＢＡＬＬＳＰ！＝０　ＴＨＥＮ　ＢＡＬＬＳＰ＝１：ＢＡＬＬＤＹ＝−１
  285. ＲＥＴＵＲＮ
  287. ’ハンシャ　カヘ゛　ヒタ゛リ
  288. ＠ＲＦＷＡＬＬＬ
  289. ＩＦ　ＧＭ＝＝ＧＭＰＬＡＹ　ＴＨＥＮ　ＢＥＥＰ　０，ＢＰＷＡＬＬ
  290. ＢＡＬＬＤＸ＝１
  291. ＲＥＴＵＲＮ
  293. ’ハンシャ　カヘ゛　ミキ゛
  294. ＠ＲＦＷＡＬＬＲ
  295. ＩＦ　ＧＭ＝＝ＧＭＰＬＡＹ　ＴＨＥＮ　ＢＥＥＰ　０，ＢＰＷＡＬＬ
  296. ＢＡＬＬＤＸ＝−１
  297. ＲＥＴＵＲＮ
  299. ’ハンシャ　カヘ゛　ウエ
  300. ＠ＲＦＷＡＬＬＵ
  301. ＢＡＬＬＤＹ＝−ＢＡＬＬＤＹ
  302. ＲＦＢＬＯＣＫ＝ＦＡＬＳＥ
  303. ＩＦ　ＧＭ＝＝ＧＭＤＥＭＯ　ＴＨＥＮ　ＲＥＴＵＲＮ
  304. ＩＦ　ＰＡＤＷＸ＝＝ＰＡＤＷＬ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＥＲＣＰＡＤ：ＰＡＤＷＸ＝ＰＡＤＷＳ：ＧＯＳＵＢ　＠ＰＲＴＰＡＤ
  305. ＲＥＴＵＲＮ
  307. ’ハンシャ　フ゛ロック
  308. ＠ＲＦＢＬＯＣＫ
  310. ＢＡＬＬＤＹ＝−ＢＡＬＬＤＹ
  311. ＲＦＢＬＯＣＫ＝ＴＲＵＥ
  313. ＩＦ　ＢＹ＜＝３　ＴＨＥＮ　ＢＡＬＬＳＰ＝０：ＢＡＬＬＤＹ＝ＳＧＮ（ＢＡＬＬＤＹ）
  314. ＩＦ　ＧＭ＝＝ＧＭＤＥＭＯ　ＴＨＥＮ　ＲＥＴＵＲＮ
  316. ＢＥＥＰ　０，ＢＰＢＬＯＣＫ
  317. ＳＣＯＲＥ０＝ＳＣＯＲＥ
  318. ＳＣＯＲＥ＝ＳＣＯＲＥ＋ＢＬＯＣＫ（ＢＸ，ＢＹ）
  319. ＧＯＳＵＢ　＠ＰＲＴＳＣＯＲＥ
  321. ＢＬＯＣＫ（ＢＸ，ＢＹ）＝０
  322. ＢＬＯＣＫＣ＝ＢＬＯＣＫＣ−１
  323. ＧＸ＝ＢＬＫＯＸ＋ＢＸ＊ＢＬＫＷＸ
  324. ＧＹ＝ＢＬＫＯＹ＋ＢＹ＊ＢＬＫＷＹ
  325. ＧＦＩＬＬ　ＧＸ＋１，ＧＹ＋１，ＧＸ＋ＢＬＫＷＸ−１，ＧＹ＋ＢＬＫＷＹ−１，０
  327. ＩＦ　ＳＣＯＲＥ０＜ＳＣＯＲＥＢ　ＡＮＤ　ＳＣＯＲＥ＞＝ＳＣＯＲＥＢ　ＴＨＥＮ　ＢＡＬＬＣ＝ＢＡＬＬＣ＋１：ＧＯＳＵＢ　＠ＰＲＴＢＡＬＬＣ：ＢＥＥＰ　ＢＰＢＯＮＵＳ
  328. ＩＦ　ＢＬＯＣＫＣ＝＝０　ＴＨＥＮ　ＣＬＢＬＯＣＫ＝ＴＲＵＥ
  330. ＲＥＴＵＲＮ
  332. ’ミス
  333. ＠ＲＦＭＩＳＳ
  334. ＧＭ＝ＧＭＭＩＳＳ
  335. ＲＥＴＵＲＮ
  337. ’＊＊＊　スコア　ヒョウシ゛　＊＊＊
  338. ＠ＰＲＴＳＣＯＲＥ
  340. ＣＯＬＯＲ　ＣＯＬＳＣＯＲＥ
  341. ＬＯＣＡＴＥ　ＳＣＯＲＥＸ，ＳＣＯＲＥＹ
  342. ＰＲＩＮＴ　”ＳＣＯＲＥ”
  343. ＬＯＣＡＴＥ　ＳＣＯＲＥＸ，ＳＣＯＲＥＹ＋１
  344. ＰＲＩＮＴ　ＳＣＯＲＥ
  345. ＲＥＴＵＲＮ
  347. ’＊＊＊　ノコリ　ホ゛ール　ヒョウシ゛　＊＊＊
  348. ＠ＰＲＴＢＡＬＬＣ
  350. ＣＯＬＯＲ　ＣＯＬＢＡＬＬＣ
  351. ＬＯＣＡＴＥ　ＢＡＬＬＣＸ，ＢＡＬＬＣＹ
  352. ＰＲＩＮＴ　”ＢＡＬＬ”
  353. ＬＯＣＡＴＥ　ＢＡＬＬＣＸ，ＢＡＬＬＣＹ＋１
  354. ＰＲＩＮＴ　”　　　　”
  355. ＬＯＣＡＴＥ　ＢＡＬＬＣＸ，ＢＡＬＬＣＹ＋１
  356. ＦＯＲ　Ｉ＝１　ＴＯ　ＢＡＬＬＣ
  357. ＰＲＩＮＴ　”○”；
  358. ＮＥＸＴ　Ｉ
  359. ＲＥＴＵＲＮ

CHECKER FLAG (ひとことコメント)

この作品に対するコメントがあれば一言どうぞ。(作品に直接関係ない質問や雑談は掲示板へ)

  • shiro : YouTubeにプレイ動画を上げたので、こちらにも追加しました。 (2011/12/09 (金) 00:18:48)
  • shiro : プログラムリスト内に数カ所間違いがあったので直しました。すみませんでした。 (2011/12/13 (火) 01:04:53)
  • shiro : ゲーム初期化部分を修正して、コードを短くしました。 (2012/01/19 (木) 12:42:07)
  • shiro : ニコニコ動画をプレーヤー表示にしました。 (2012/02/16 (木) 22:26:32)
  • 名無しさん : 一人しかコメント出してない。 (2012/02/23 (木) 19:25:01)
  • うおおおおおお : これをうつせというのかぁ (2012/03/11 (日) 09:16:05)
  • shiro : プチコンmkIIが出たら、QRコードを載せようと思います(^^)v (2012/03/11 (日) 13:58:24)
  • ウイング（うおおおおおお） : ワーイ (2012/03/11 (日) 18:23:03)
  • shiro : mkII用のQRコードを載せました。 (2012/03/14 (水) 17:12:01)
  • erukane : ありがとうございます。十字キーに対応させていただけると、うれしいです。あっと、自分でなんとかするのが先ですね。(^^;) (2012/03/15 (木) 08:56:01)
  • ウイング : プチコン (2012/03/15 (木) 16:00:02)
  • ウイング : ↑打ち間違い (2012/03/15 (木) 16:01:03)
  • ウイング : プチコンmkiiga (2012/03/15 (木) 16:01:47)
  • shiro : 十字キー対応にもできるのですが、ペンの方がパドルが操作しやすいと思います。私は既存のブロック崩しゲームが十字キーでしか操作できないのが不満でした… (2012/03/16 (金) 03:25:55)
  • erukane : shiroさん、了解致しました。そういうことだったんですね。リスト、参考になります。(^^) (2012/03/16 (金) 16:43:11)
  • 名無しさん : ｑｒコード見えない・・・（´・ω・｀） (2012/03/16 (金) 18:33:58)
  • shiro : どうもIE8だけQRコードを表示できないようです。chrome、Firefox、Safariなど別のブラウザを使ってみてください。 (2012/03/16 (金) 23:12:19)
  • shiro : IE8の方は、F12キーを押して開発者モードにして、ウインドウ下部に出るメニューで「ブラウザモード」「ドキュメントモード」を「IE7」にしてみてください。 (2012/03/16 (金) 23:13:47)
  • shiro : 投稿ページのタイトルが画像参照URLに入るのですが、タイトルに全角文字があるとエンコードされてURLに入り、その解釈がIE8だとうまくいかないようです。例えば英語タイトルの「TENORI-COM」ではその現象が起きていません。 (2012/03/16 (金) 23:20:21)
  • shiro : 面倒なので、6個のQRコードを1枚の合成画像に置き換えました。どうも表形式で並べると、IE8で見えなくなるようです。 (2012/03/16 (金) 23:46:58)
  • Dy : 359行にもわたるプログラムの開発、お疲れ様です。これからもがんばってください。 (2012/03/17 (土) 00:05:46)
  • プチコンまとめWiki管理人 : IE8での表示不具合の件、こちらで調査・対応してみます。申し訳ありません。 (2012/03/17 (土) 00:06:05)
  • プチコンまとめWiki管理人 : IE8以下の表示バグを回避するようにcssを修正しました。表の中に画像を埋め込む場合、HTMLの仕様とIEバグの都合上「#ref()」を使わず、以下のように記述していただく必要があります。大変お手数をおかけしました。 (2012/03/17 (土) 00:37:33) 
    |&ref(qr1.png);|&ref(qr2.png);|
  • shiro : 管理人さん、対応ありがとうございます。合成画像で載せてしまったので、今回はこのままで行きたいと思います。 (2012/03/17 (土) 12:23:00)
  • カップラーメン : 十字ボタンで今までやっていましたw (2012/03/29 (木) 17:00:18)
  • 人間 : 処理抜け　ブロックにあたったあと、ブロックにもう１度あたっても、壊れない (2012/04/09 (月) 14:33:18)
  • 人間 : ついでに改造法　４７行（BALLLMAX＝の後の数字）変えればボール増える (2012/04/09 (月) 14:47:18)
  • shiro : ブロックに当たった後、次にブロックに当たっても壊れないのは仕様ですw。初期のブロックくずしはそうなっていました。その後のアルカノイドなどは連続で壊れましたが。 (2012/04/29 (日) 17:17:54)
  • shiro : 残りボール数などを含めて、改造は各自で自由にやってみてください(^^) (2012/04/29 (日) 17:19:52)
  • shiro : ちなみに一度ブロックに当たったかどうかは変数RFBLOCKで判定していて、236行目のIF文をコメントアウトすれば連続でブロックに当たります。ただしその後のボールの動きがおかしくなるかもしれません。 (2012/04/29 (日) 17:27:07)
  • shiro : プチコンmkII Ver2.1を使って再保存して、QRコードの枚数を減らしました。 (2012/05/02 (水) 12:59:25)

表示モード : [ スマホ・3DS対応表示 | クラシック表示 ]
PukiWiki 1.4.7 Copyright © 2001-2006 PukiWiki Developers Team. License is GPL. Based on "PukiWiki" 1.3 by yu-ji
ページの処理時間 : 0.167 秒 | このページの最終更新 : 2022/09/20 (火) 12:44:06 (565d) | ログイン
Copyright(C) 2011-2014 プチコンまとめWiki ◆1sxkymI8ji30