投稿プログラム : PetitcoLOID

パンくずリスト

概要
PeticoLOID α3言語仕様
- 正規表現(間違ってるかも…)
変数について
フォントについて
- ひらがなのキーボードマッピングについて
MMLの注意点
スクリーンショット・動画
QR コード
プログラムリスト
CHECKER FLAG (ひとことコメント)

2012年03月20日投稿 / 投稿者 : sou51 / タグ : 投稿プログラム QRコード実用ツール mkII専用

概要

プチコンのTALK命令を使って歌わせるツールです。
勝手に機能拡張・変更・修正して使っていただいて構いません。

このプログラム自体にはデータ編集ツール機能はありません。
プログラムリスト内の@PLL、@MMLのデータを編集して好きな歌を歌わせるためのプログラムです。

PeticoLOID α3言語仕様

PeticoLOID α3の言語仕様は以下のようになっています。

正規表現(間違ってるかも…)

([<>]*[CDEFGABR][+#-]?[1-9][0-9]*\.*['/|_.?!%ヲ-゜\-]+(\[([^]]|\\\])*]\])?)*

先頭から、相対オクターブ移動、音階/休符、音の長さ、発話文字列、出力文字列、となっています。

相対オクターブ移動

これはMMLと同じです。Oコマンドによる絶対指定はできません。
オクターブ移動しない場合は省略可能です。

音階/休符

これもMMLと同じです。CDEFGABで音階、Rで休符となります。
省略不可。

音の長さ

これもMMLと同様ですが、省略不可です。
仕様上1以上の数字の指定ができますし、付点もいくらでもつけられると思いますが、
あまり意味が無いことになると思います。

発話文字列

TALK文で発音する文字列です。カナ文字以外では、'|_.?!%が指定出来ます。
ただしPHF変数が1の場合、末尾に自動的に音の長さに合わせた長音が付加されるため、
発話文字列が記号などで終わっていた場合、TALKでエラーになると思われます。
音階/休符で、休符を指定した場合は、不要です。(記述するとエラーになります。)

出力文字列

PS$に格納される文字列です。[]で囲った文字列がそのまま格納されます。
文字列に[を含めたい場合は、円マークをつけてエスケープしてください。
円マークは常に次の文字をそのまま出力するため、円マークを出力する場合は2個連続して記述してください。

変数について

PL$	入力	PetitcoLOID Languageを格納します
PTMP	入力	テンポ(BPM)を格納します
PHF	入力	1にすると、音の長さに応じて発話文字列の末尾に長音が追加されます。
PE	出力	解析エラーがあると1になります
PLE	出力	PL$末尾に到達すると1になります
PW	出力	待機すべきフレーム数です
PS$	出力	出力文字列が格納されます。出力文字列が無い場合は空文字列となります。

フォントについて

美咲フォントを使用しています。
美咲フォントのライセンス

These fonts are free softwares.
Unlimited permission is granted to use, copy, and distribute it, with or without modification, either commercially and noncommercially.
THESE FONTS ARE PROVIDED "AS IS" WITHOUT WARRANTY.
これらのフォントはフリー（自由な）ソフトウエアです。
あらゆる改変の有無に関わらず、また商業的な利用であっても、自由にご利用、複製、再配布することができますが、全て無保証とさせていただきます。

ということなので、QRコードの方にはBGF0も付けています。
ひらがなもPCGにマッピングしているため、ひらがな、カタカナ、アルファベットの混在が可能です。
サンプルコードでは、出力文字列にひらがなを使用しています。

ひらがなのキーボードマッピングについて

ひらがなは、キーボード上で、カタカナ入力にできるだけ対応するようにマッピングしています。

「お」について

「お」は ★ にマッピングしていましたが、Ver.2.0現在、改行に化けるため、
回避策として В にもマッピングしています。

実際に出力文字列の「あさひににおう」に「お」が使用されていたため、
最初のバージョンではそこが改行に化け、正しく歌えませんでした。

拗音のマッピング

ただし、拗音のみ同じようにマッピングできないため、以下のようにしています。

■	▲	▼	О	Ж	↓	ж	↑	и
ぁ	ぃ	ぅ	ぇ	ぉ	っ	ゃ	ゅ	ょ

MMLの注意点

BGMPLAYの最初にR16程度の休止を入れると、割とぴったり合うと思います。
また進むにつれて微妙に遅れるていくので、適当なタイミングで16分～32分程度短くして調整してやってください。

スクリーンショット・動画

このバージョンの動画は以下です。

以下は、旧バージョンの動画ですが、歌唱能力自体は同程度なので参考にしてください。

QR コード

プチコンmkII 向けの QR コードです。
美咲フォントが設定されたBGF0データも含みます。

1/6	2/6	3/6

4/6	5/6	6/6

プログラムリスト

’－－－－－－－－－－－－－－－－－－－－－－－－－－－
’　ＰｅｔｉｔｃｏＬＯＩＤ　Ｖｅｒ．Ａｌｐｈａ　３
’－－－－－－－－－－－－－－－－－－－－－－－－－－－
’　ＰＬ＄ニ　ＰｅｔｉｃｏＬＯＩＤ　Ｌａｎｇｕａｇｅヲ
’　キシ゛ュツシ　＠ＰＬＴＡＬＫヲ　ヨフ゛ト
’　１ツ　ハツワ　サレル。
’　ＶＳＹＮＣテ゛　ＰＷフ゛ン　マッテカラ
’　フタタヒ゛＠ＰＬＴＡＬＫヲ　ヨフ゛
’－－－－－－－－－－－－－－－－－－－－－－－－－－－
’　ＰＭＴＭＰ＝Ｂｅａｔ　Ｐｅｒ　Ｍｉｎｕｔｅ
’　ＰＥ＝ＥＲＲＯＲノ　ハ゛アイ　１
’　ＰＬＥ＝ＰＬ＄マツヒ゛ニ　トウタツスルト　１
’　ＰＨＦ＝１ニスルト　ハツワ　マツヒ゛ニ”－”ツイカ
’－－－－－－－－－－－－－－－－－－－－－－－－－－－
’ＰＭＴＭＰハ　ＶＳＹＮＣノ　カンケイシ゛ョウ
’　ス゛レカ゛　ショウシ゛ナイ　テンホ゜ト　オンフ゜ハ
’　　イカノ　ヨウニナリマス
’　　　　１２３４６８ＡＢＣフ゛オンフ゜
’　５０　○○○○○○○○○　Ａ＝１２フ゛
’　６０　○○○○○○○○○　Ｂ＝１６フ゛
’　７２　○○м○м○м○м　Ｃ＝２４フ゛
’　８０　○○○○○м○мм　３フ゛＝１フ゛ノ３レンフ゜
’　９０　○○м○м○○○м　６フ゛＝２フ゛ノ３レンフ゜
’　９６　○○○м○мммм　１２フ゛＝４フ゛ノ３レンフ゜
’１００　○○○○○○○○○　２４フ゛＝８フ゛ノ３レンフ゜
’１２０　○○○○○○○м○
’１４４　○○м○ммммм
’１５０　○○○○○○○○○
’１６０　○○○м○мммм
’１８０　○○м○м○м○м
’１９２　○м○м○мммм
’２００　○○○○○○○м○
’２２５　○○м○м○м○м
’２４０　○○○○○м○мм　ＭＭＬサイタ゛イ
’－－－－－－－－－－－－－－－－－－－－－－－－－－－
’　ＰｅｔｉｔｃｏＬＯＩＤ　Ｌａｎｇｕａｇｅ（ＰＬＬ）
’　　　　　　　　　　　　Ｖｅｒ．Ａｌｐｈａ　３　シヨウ
’－－－－－－－－－－－－－－－－－－－－－－－－－－－
’　　オクタ－フ゛イト゛ウ　オンカイ　オンチョウ　ハツワ　モシ゛レツ
’　　　テ゛、１セット。
’　　オクタ－フ゛イト゛ウ：　［＜＞］？
’　　オンカイ：［ＲＣＤＥＦＧＡＢ］［＋＃－］？
’　　オンチョウ：［０－９］＋￥．＊
’　　ハツワ：［￤＿／．？！’ヲ－ン］＋
’　　モシ゛レツ：（￥［．＋￥］）？
’　オクタ－フ゛イト゛ウ　イカ゛イハ　ショウリャク　フカ
’　キュウフノ　ハ゛アイ　ハツワ　フヨウ
’　モシ゛レツ　ショウリャク　カノウ
’－－－－－－－－－－－－－－－－－－－－－－－－－－－
ＧＯＴＯ＠ＭＡＩＮ

＠ＰＬＬ
ＤＡＴＡ”Ａ４サ［─┐л　─┐л］Ａ４クＢ２ラＡ４サＡ４クＢ２ラ
ＤＡＴＡ”Ａ４ノ［▽дУё　─кё］Ｂ４ヤ＜Ｃ４マ＞Ｂ４モＡ４サＢ８トＡ８オＦ２モ
ＤＡＴＡ”Ｅ４ミ［Т┥╂┼　┌┬Цм］Ｃ４ワＥ４タＦ４スＥ４カＥ８キ゛Ｃ８イ＞Ｂ２リ
ＤＡＴＡ”＜Ａ４カ［┌┼Т┌　┐ё┌］Ｂ４ス＜Ｃ４ミ＞Ｂ４カＡ４クＢ８モＡ８オＦ２カ
ＤＡＴＡ”Ｅ４ア［а─Ь◎　◎ВЯ］Ｃ４サＥ４ヒＦ４ニＥ４ニＥ８オＣ８オ＞Ｂ２ウ
ＤＡＴＡ”＜Ａ４サ［─┐л　─┐л］Ａ４クＢ２ラＡ４サＡ４クＢ２ラ
ＤＡＴＡ”Ｅ４ハ［Ю○─Ц┌м］Ｆ４ナＢ８サ゛Ａ８アＦ４カＥ１リ
ＤＡＴＡ””

＠ＭＭＬ
ＤＡＴＡ”Ｔ７２Ｒ１６Ｌ４ＡＡＢ２ＡＡＢ２
ＤＡＴＡ”ＡＢ＜Ｃ＞ＢＡＢ８Ａ８Ｆ２
ＤＡＴＡ”ＥＣＥＦＥＥ８Ｃ８＞Ｂ２
ＤＡＴＡ”＜ＡＢ＜Ｃ＞ＢＡＢ８Ａ８Ｆ２
ＤＡＴＡ”ＥＣＥＦＥＥ８Ｃ８＞Ｂ２
ＤＡＴＡ”＜ＡＡＢ２ＡＡＢ２
ＤＡＴＡ”ＥＦＢ８Ａ８Ｆ４Ｅ１
ＤＡＴＡ　０

＠ＭＡＩＮ
ＣＬＥＡＲ
ＤＩＭ　Ｎ（１４），ＮＭ（７）
ＲＥＳＴＯＲＥ　＠ＮＤＡＴＡ
ＦＯＲ　Ｉ＝０　ＴＯ　１３：ＲＥＡＤ　Ｎ（Ｉ）：ＮＥＸＴ
ＦＯＲ　Ｉ＝０　ＴＯ　６：ＲＥＡＤ　ＮＭ（Ｉ）：ＮＥＸＴ
ＢＧＭＳＥＴＤ　１２８，＠ＭＭＬ

ＧＯＳＵＢ　＠ＰＬＩＮＩＴ
ＲＥＳＴＯＲＥ　＠ＰＬＬ
ＲＥＡＤ　ＰＬ＄
ＶＳＹＮＣ　０
ＢＧＭＰＬＡＹ　１２８
＠ＰＬＰ
ＧＯＳＵＢ　＠ＰＬＴＡＬＫ
ＩＦ　ＰＳ＄！＝””　ＴＨＥＮ　？ＰＳ＄
ＶＳＹＮＣ　ＰＷ
ＩＦ　！ＰＥ　ＡＮＤ　！ＰＬＥ　ＴＨＥＮ　ＧＯＴＯ＠ＰＬＰ
ＲＥＡＤ　ＰＬ＄：Ｐ＝０：ＰＬＥ＝０
ＩＦ　ＬＥＮ（ＰＬ＄）＞０　ＴＨＥＮ　＠ＰＬＰ
ＥＮＤ

＠ＰＬＩＮＩＴ
Ｐ＝０：ＰＬ＄＝””：ＰＭ＝０：ＰＯ＝０：ＰＷ＝０
ＰＥ＝０：ＰＴＭＰ＝７２：ＰＨＦ＝１：ＲＥＴＵＲＮ

＠ＰＬＴＡＬＫ
ＰＬＥ＝（Ｐ＞＝ＬＥＮ（ＰＬ＄））：ＰＥ＝０
ＩＦ　ＰＬＥ　ＡＮＤ　ＰＭ＜３　ＴＨＥＮ　ＰＷ＝０：ＲＥＴＵＲＮ
ＧＯＳＵＢ＠ＰＬＲＩ
ＧＯＴＯ　”＠ＰＭ”＋ＳＴＲ＄（ＰＭ）

’オンカイ
＠ＰＭ０
ＩＦ　Ｃ＝＝６０　ＴＨＥＮ　ＰＯ＝ＰＯ＋（ＰＯ＜２）：ＧＯＴＯ＠ＰＬＴＡＬＫ
ＩＦ　Ｃ＝＝６２　ＴＨＥＮ　ＰＯ＝ＰＯ－（ＰＯ＞－２）：ＧＯＴＯ＠ＰＬＴＡＬＫ
ＩＦ　Ｃ＝＝８２　ＴＨＥＮ　ＰＲ＝１：ＰＭ＝１：ＧＯＴＯ＠ＰＬＴＡＬＫ
ＩＦ　Ｃ＜６５　ＯＲ　Ｃ＞７１　ＴＨＥＮ　？”ＥＲＲＯＲ０＠”；Ｐ；”：”；ＣＨＲ＄（Ｃ）：ＰＥ＝１：ＲＥＴＵＲＮ
ＰＭ＝１：ＰＲ＝０：Ｃ１＝Ｃ－６５：ＧＯＳＵＢ＠ＰＬＲ
ＩＦ　Ｃ！＝４３　ＡＮＤ　Ｃ！＝３５　ＡＮＤ　Ｃ！＝４５　ＴＨＥＮ　ＰＴ＝ＰＯ＊６９０＋Ｎ（ＮＭ（Ｃ１））：ＧＯＴＯ　＠ＰＬＴＡＬＫ
Ｐ＝Ｐ＋１：ＰＴ＝ＰＯ＊６９０＋Ｎ（ＮＭ（Ｃ１）－（Ｃ＝＝４５）＋（Ｃ＝＝４３　ＯＲ　Ｃ＝＝３５））
ＧＯＴＯ　＠ＰＬＴＡＬＫ

’オンチョウ
＠ＰＭ１
ＩＦ　Ｃ＜４９　ＯＲ　Ｃ＞５７　ＴＨＥＮ　？”ＥＲＲＯＲ１＠”；Ｐ；”：”；ＣＨＲ＄（Ｃ）：ＰＥ＝１：ＲＥＴＵＲＮ
ＰＭ＝２＋ＰＲ：Ｃ１＝Ｃ－４８
＠ＰＭ１Ａ
ＧＯＳＵＢ＠ＰＬＲ
ＩＦ　Ｃ！＝４６　ＡＮＤ（Ｃ＜４８　ＯＲ　Ｃ＞５７）ＴＨＥＮ　ＰＷ＝１４４００／ＰＴＭＰ／Ｃ１：ＰＨ＝ＦＬＯＯＲ（１６／Ｃ１）－１：ＧＯＴＯ＠ＰＬＴＡＬＫ
Ｐ＝Ｐ＋１
ＩＦ　Ｃ！＝４６　ＴＨＥＮ　Ｃ１＝Ｃ１＊１０＋Ｃ－４８：ＧＯＴＯ　＠ＰＭ１Ａ
Ｃ２＝１．５：Ｃ３＝４
＠ＰＭ１Ｂ
ＧＯＳＵＢ＠ＰＬＲ
ＩＦ　Ｃ＝＝４６　ＴＨＥＮ　Ｐ＝Ｐ＋１：Ｃ２＝Ｃ２＋１／Ｃ３：Ｃ３＝Ｃ３＋１：ＧＯＴＯ＠ＰＭ１Ｂ
ＰＷ＝１４４００／ＰＴＭＰ／Ｃ１＊Ｃ２：ＰＨ＝ＦＬＯＯＲ（１６／Ｃ１＊Ｃ２）－１：ＧＯＴＯ＠ＰＬＴＡＬＫ

’ハツオンモシ゛レツ
＠ＰＭ２
Ａ＝Ｃ！＝９５　ＡＮＤ　Ｃ！＝３９　ＡＮＤ　Ｃ！＝３７　ＡＮＤ　Ｃ！＝４７　ＡＮＤ　Ｃ！＝１２４　ＡＮＤ　Ｃ！＝４６　ＡＮＤ　Ｃ！＝３３　ＡＮＤ　Ｃ！＝６３　ＡＮＤ（Ｃ＜１６６　ＯＲ　Ｃ＞２２３）
Ａ＝Ａ　ＡＮＤ　Ｃ！＝４５
ＩＦ　Ａ　ＴＨＥＮ　？”ＥＲＲＯＲ２＠”Ｐ”：”ＣＨＲ＄（Ｃ）：ＰＥ＝１：ＲＥＴＵＲＮ
ＰＴ＄＝Ｃ＄
＠ＰＭ２Ａ
ＧＯＳＵＢ＠ＰＬＲ
Ｂ＝（Ｃ＜１６６　ＯＲ　Ｃ＞２２３）
Ａ＝Ｃ！＝９５　ＡＮＤ　Ｃ！＝３９　ＡＮＤ　Ｃ！＝３７　ＡＮＤ　Ｃ！＝４７　ＡＮＤ　Ｃ！＝１２４　ＡＮＤ　Ｃ！＝４６　ＡＮＤ　Ｃ！＝３３　ＡＮＤ　Ｃ！＝６３　ＡＮＤ　Ｂ　ＡＮＤ　Ｃ！＝４５
ＩＦ　！Ａ　ＴＨＥＮ　Ｐ＝Ｐ＋１：ＰＴ＄＝ＰＴ＄＋Ｃ＄：ＧＯＴＯ＠ＰＭ２Ａ
ＰＭ＝３
ＧＯＴＯ＠ＰＬＴＡＬＫ

’シュツリョクモシ゛レツ
＠ＰＭ３
ＰＳ＄＝””
ＩＦ　Ｃ！＝９１　ＴＨＥＮ　Ｐ＝Ｐ－１：ＰＭ＝４＋ＰＲ：ＧＯＴＯ＠ＰＬＴＡＬＫ
＠ＰＭ３Ａ
ＧＯＳＵＢ＠ＰＬＲ
ＩＦ　Ｃ＝＝０　ＴＨＥＮ　ＰＥ＝１：ＲＥＴＵＲＮ
ＩＦ　Ｃ＝＝９２　ＴＨＥＮ　Ｐ＝Ｐ＋１：ＧＯＳＵＢ＠ＰＬＲ：ＰＳ＄＝ＰＳ＄＋Ｃ＄：ＧＯＴＯ＠ＰＭ３Ａ
ＩＦ　Ｃ！＝９３　ＴＨＥＮ　Ｐ＝Ｐ＋１：ＰＳ＄＝ＰＳ＄＋Ｃ＄：ＧＯＴＯ＠ＰＭ３Ａ
Ｐ＝Ｐ＋１：ＰＭ＝４＋ＰＲ：ＧＯＴＯ＠ＰＬＴＡＬＫ

＠ＰＭ４
’ハツオン
Ｔ＄＝”＠Ｅ１６＠Ｎ”＋ＳＴＲ＄（ＰＴ）＋ＰＴ＄＋”－”＊（ＰＨ＋（Ｃ１＝＝０））＊ＰＨＦ
’？Ｔ＄
ＴＡＬＫ　Ｔ＄
＠ＰＭ５
ＰＷＭ＝ＰＷＭ＋ＰＷ％１：ＰＭ２＝（ＰＷＭ＞０）＊（ＦＬＯＯＲ（ＰＷＭ））：ＰＷ＝ＰＷ＋ＰＭ２：ＰＷＭ＝ＰＷＭ－ＰＭ２
Ｐ＝Ｐ－１＋（Ｐ＞＝ＬＥＮ（ＰＬ＄））：ＰＭ＝０
ＲＥＴＵＲＮ

＠ＰＬＲ
ＩＦ　Ｐ＞＝ＬＥＮ（ＰＬ＄）　ＴＨＥＮ　Ｃ＄＝””：Ｃ＝０　ＲＥＴＵＲＮ
Ｃ＄＝ＭＩＤ＄（ＰＬ＄，Ｐ，１）：Ｃ＝ＡＳＣ（Ｃ＄）
’？Ｃ＄；
ＲＥＴＵＲＮ
＠ＰＬＲＩ
ＩＦ　Ｐ＞＝ＬＥＮ（ＰＬ＄）　ＴＨＥＮ　Ｃ＄＝””：Ｃ＝０　ＲＥＴＵＲＮ
Ｃ＄＝ＭＩＤ＄（ＰＬ＄，Ｐ，１）：Ｃ＝ＡＳＣ（Ｃ＄）
’？Ｃ＄”＊”；
Ｐ＝Ｐ＋１：ＲＥＴＵＲＮ

＠ＮＤＡＴＡ
ＤＡＴＡ　１４０３，１４４７，１５１０，１５５９，１６２６
ＤＡＴＡ　１６８６，１７４５，１７９２，１８５８，１９１６
ＤＡＴＡ　１９７１，２０３１，２０９３，２１３７
＠ＮＭＡＰ
ＤＡＴＡ　１０，１２，１，３，５，６，８

CHECKER FLAG (ひとことコメント)

この作品に対するコメントがあれば一言どうぞ。(作品に直接関係ない質問や雑談は掲示板へ)

バイカウントメルビル : うぽつー！ (2012/03/21 (水) 12:39:21)
名無しさん : うぽつ( ^_^)／ (2012/03/21 (水) 14:34:21)
アレクサンドロ・ハーバー（仮） : す～げ～な～ (2012/03/21 (水) 22:28:37)
名無しさん : これMkIIかどうかの判定入れないとだめでないかなぁ… (2012/03/21 (水) 22:38:31)
名無しさん : ↑どうしてそんなことをする必要があるんだ? 配信終了している初代にこのプログラムを入力する人がいるとは思えないし、たとえ入れたとしても、どうせTALKを実行しようとした時点でエラーになるし。 (2012/03/22 (木) 05:37:38)
名無しさん : スゴイ (2012/03/22 (木) 13:50:09)
名無しさん : 混在表示ってhttp://d.hatena.ne.jp/eidaht/20120129/1327802409これと同じようなもの? (2012/03/22 (木) 15:38:06)
sou51 : PCGにひらがなを置いているという点では似ています。リンク先では、カナに対応した位置にシフトさせて配置していますが、PeticoLOID同梱のBGFではPCGキーボードで入力しやすいように配置しているので文字コード順だとバラバラな並びです。処理は全く違います。リンク先では\H、\Kでひらがなモード、カタカナモードを切り替えて、カナ文字をシフトしたりしなかったりしていますが、プチコロイド同梱のフォントは単にPCGを自分で入力するだけです。 (2012/03/22 (木) 22:21:33)
sou51 : んー、解析処理がちょっと重たいかなー。微妙に遅れていくかも。 (2012/03/22 (木) 23:04:58)
名無しさん : プチコロイドって名前どこにも歌う要素が入ってないけどいいですね。 (2012/03/23 (金) 01:38:54)
ななしさん : ↑おそらく某DTMソフトのリスペクトだろうｗ (2012/03/23 (金) 22:20:15)
sou51 : プチカロイドにしちゃうとプチコン色が薄くなっちゃう感じがしたので、"プチコ"まで引っ張った感じ。コでもCが被ってたりするし。 (2012/03/23 (金) 23:15:13)
sou51 : 逐次解析じゃなくて、一括解析した後、再生するような改造をしてみたけど、ズレはほぼ変わらない感じだった。VSYNCだけで同期させるのはこの辺が限界なのかなー (2012/03/23 (金) 23:16:17)
名無しさん : これって、さくらの音楽がきけるプログラムdayona (2012/03/24 (土) 17:43:50)
名無しさん : さくらがきけただけ (2012/03/24 (土) 19:35:14)
sou51 : データ部分(@PLL、@MML)にそれぞれプチコロイド用の記述とMMLを記述すれば、好きなように歌わせることができます。「プログラムを作る」からロードして、該当データ部分を書き換えてお楽しみください。 (2012/03/25 (日) 12:29:21)
ロジウム : このプログラムの題名がS51PTCL3で、PTCLはプチコロイドのことだと思うの (2012/03/25 (日) 08:56:43)
ロジウム : ですがS51はなんですか? (2012/03/25 (日) 08:57:35)
sou51 : S51は単に、自分のハンドルから取ってるだけです。(大量になったときに作者ごとにまとめたりできるので) (2012/03/25 (日) 12:31:21)
ロジウム : なるほど (2012/03/25 (日) 18:32:15)
名無しさん : コロイド溶液? (2012/03/28 (水) 12:04:47)
ロジウム : えっと、QRコードに美咲フォントはどうやって入れたんですか? (2012/03/29 (木) 09:51:33)
sou51 : BGF0をパッケージングしただけですよー。SAVE"S51PTCL3","1000" (2012/03/31 (土) 20:05:22)
sou51 : ボーカルというにはあまりに弱いので、Cだけ重複しとけばいいかという考えです。いずれにしても命令形で文句言われる筋合いは無いと思っています。 (2012/04/06 (金) 23:55:42)
カービィ★KIRBY : うお、スゲー！プチコンが歌った！ (2012/06/03 (日) 13:16:26)
Lv100 : 動画が見れない… (2012/06/03 (日) 15:56:42)
名無しさん : ↑　確かに、ページに埋め込んだ方がいいかもしれません。 (2015/01/10 (土) 22:49:23)

メニュー【mkII】

プチコン3号まとめWiki

ヘルプ

リンク

Petit Computer Wiki

プチコンリンク集

オンライン情報

現在同時に 1 人がこのサイトを見ています

ページの先頭に戻る

プチコンまとめWiki (初代/mkII)