プチコンまとめWiki (初代/mkII)

投稿プログラム : 羅針盤DS

パンくずリスト

2012年5月20日投稿 / 投稿者 : Oskar / タグ : 投稿プログラム 実用ツール QRコード mkII専用

概要

キミの DS（DSi/DSi LL/3DS）がコンパス（方位磁針）になる！ *1

使い方

操作

  1. プログラムを起動します。
  2. 外に出てお日様の光を浴びます。
  3. DS を下画面が水平になるように持ちます。
  4. タッチペンを DS の下画面と垂直になるように持ちます。
  5. タッチペンの影が中央の点の上を通る場所までスライドしてタッチペンを DS から離します。
    • スライド中もタッチペンは傾けないでください。
    • スライド中に表示されるガイドラインに影を合わせても同じことです。
    • 中心から離れたところで離すほうがよいです。
  6. 「コンパス」の赤い「針」の示した方向が「北」です。
  • DS の向きを変えたり場所を移動したりしたら上記を繰り返します。
  • X ボタンで終了します。

設定

起動すると現在地を勝手に東京（新宿）と決め付けますが、A ボタンで変更できます。

  • いい加減な日本地図が表示されるので、だいたいの場所をタッチしてください。
  • いい加減が嫌いなひとや、地図の範囲外にいるときは、Y ボタンで経度・緯度による位置の入力ができます。
  • 現在地を設定したら A ボタンで戻ります。

注意

  • 夜は使えません。
  • 薄日・曇・雨・雪のときは使えません。
  • DS の時刻を日本時間に合わせていないと使えません。
  • ニュージーランドあたりでは使えません。
  • 日本でも沖ノ鳥島では使えません。残念ながら北回帰線より北だけです。
  • これを使って道に迷ったりしても、投稿者は一切責任を負いません。
  • 薄日で影が薄いからといって、肉眼で太陽を直視しないでください。

詳細

計算結果の表示

「針」を北へ向けるために、太陽の見える方角を計算しています。

  • AZ （方位角）として、真北が0度の時計回りの角度で表示

コンパスや地図の表示はアレですが、一応こんなことも考慮しています。

  • 現在地の経度と標準時子午線の経度の差による影響
    • TDM （分単位の時差）として、分単位で表示
    • 例えば、鳥取と東京では経度で約5度差があるので、1日の5/360 = 約20分ぶん太陽の動きにずれがある。

他にもいくつか、Wikipedia（英語版）の この辺 の式をこねくり回す過程で出てくる計算結果を表示しています。興味あればプログラムリストと Web を探してください。

隠し機能

「針」を動かすのには関係ありませんが、ついでなので太陽の高度も出しています。

  • ALT （高度）として、水平が0度の正負の角度で表示

計算に使う日時を固定できます。システム変数 ＭＥＭ＄ に次のような書式で値を代入してプログラムを起動します。

  • 【例】 2012年5月21日7時31分59秒 に固定する場合

    ＭＥＭ＄＝”ＦＩＸＤＡＴＥＴＩＭＥ＝２０１２０５２１０７３１５９”

以上から、ある場所で日食などのイベントが起こる日時を知っていれば、そのとき、その場所での太陽の位置もだいたい分かります。

……ということで、時節柄、投稿を急いだのでした。

スクリーンショット・動画

ええと、誠意検討中です。

QR コード

プチコンmkII 向けの QR コードです。

PRG:OK_RADS1
1/52/53/5
rev2-qr0.pngrev2-qr1.pngrev2-qr2.png
4/55/5全 QR まとめ画像
rev2-qr3.pngrev2-qr4.pngここ

プログラムリスト

  1. ’＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
  2. ’Ｒａｓｈｉｍｂａｎ　ＤＳ
  3. ’ＯＫ＿ＲＡＤＳ１：　２０１２．０５．２０
  4. ’（Ｃ）　Ｏｓｋａｒ
  5. ’＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
  7. ＧＯＳＵＢ　＠ＩＮＩＴＩＡＬＩＺＥ
  8. ＧＯＳＵＢ　＠ＤＲＡＷ＿ＣＯＭＰＡＳＳ
  9. ＧＯＳＵＢ　＠ＰＵＴ＿ＢＧＭＡＰ
  10. ＧＯＳＵＢ　＠ＭＡＩＮ
  11. ＧＯＳＵＢ　＠ＦＩＮＡＬＩＺＥ
  12. ＥＮＤ
  14. ＠ＩＮＩＴＩＡＬＩＺＥ
  15. ＣＬＥＡＲ
  16. ＡＣＬＳ：ＰＮＬＴＹＰＥ　”ＯＦＦ”
  17. ＧＰＡＧＥ　１：ＧＰＲＩＯ　２
  18. ＢＧＰＡＧＥ　１
  19. ＢＣ＝１５：ＢＣ２＝３０：ＯＣ＝５：ＣＣ＝１０
  20. ＮＣ＝２：ＳＣ＝１３
  21. ＬＣ＝４　ＸＯＲ　１５
  22. ＧＣ＝１：ＰＣ＝１２　ＸＯＲ　０
  23. ＯＸ＝１２８：ＯＹ＝９６：ＣＲ＝８０：ＰＲ＝４
  24. ＮＤ＝０：ＳＤ＝１８０
  25. ＢＸ＝１４：ＢＹ＝１０
  26. ＤＸ＝８＊６：ＤＹ＝８＊８
  27. ’Ｄｅｆａｕｌｔ　ｌｏｃａｔｉｏｎ　（Ｓｈｉｎｊｕｋｕ，　Ｔｏｋｙｏ）
  28. ＬＡＴ＝３５．６９　　　’Ｎｏｒｔｈ　ｌａｔｉｔｕｄｅ
  29. ＬＯＮＧ＝１３９．６９　’Ｅａｓｔ　ｌｏｎｇｉｔｕｄｅ
  30. ’ＪＳＴ　ｌｏｃａｔｉｏｎ　（Ａｋａｓｈｉ，　Ｈｙｏｇｏ）
  31. ＪＳＴＬＯＮＧ＝１３５　’Ｅａｓｔ　ｌｏｎｇｉｔｕｄｅ
  32. ＲＥＴＵＲＮ
  34. ＠ＤＲＡＷ＿ＣＯＭＰＡＳＳ
  35. ＧＤＲＡＷＭＤ　０：ＧＣＬＳ　ＢＣ
  36. ＧＣＩＲＣＬＥ　ＯＸ，ＯＹ，ＰＲ，ＣＣ
  37. ＧＣＩＲＣＬＥ　ＯＸ，ＯＹ，ＣＲ，ＣＣ
  38. ＧＰＡＩＮＴ　ＯＸ，ＯＹ，ＯＣ
  39. ＣＬＳ：ＬＯＣＡＴＥ　０，０
  40. ？　”＊　ＩＮＳＴＲＵＣＴＩＯＮＳ　＊”
  41. ？　”１）　ＧＯ　ＯＵＴ　ＩＮ　ＴＨＥ　ＳＵＮ．”
  42. ？　”２）　ＨＯＬＤ　ＹＯＵＲ　ＤＳ　ＨＯＲＩＺＯＮＴＡＬＬＹ．”
  43. ？　”３）　ＨＯＬＤ　ＹＯＵＲ　ＰＥＮ　ＶＥＲＴＩＣＡＬＬＹ．”
  44. ？　”４）　ＳＬＩＤＥ　ＹＯＵＲ　ＰＥＮ　ＡＮＤ　ＲＥＬＥＡＳＥ”
  45. ？　”　　　ＩＴ　ＷＨＥＲＥ　ＴＨＥ　ＳＨＡＤＯＷ　ＯＦ　ＴＨＥ”
  46. ？　”　　　ＰＥＮ　ＩＳ　ＪＵＳＴ　ＴＨＲＯＵＧＨ　ＴＨＥ　”
  47. ？　”　　　ＣＥＮＴＥＲ　ＯＦ　ＴＨＥ　ＣＯＭＰＡＳＳ．”
  48. ？　”５）　ＴＨＥＮ　ＴＨＥ　ＲＥＤ　ＥＤＧＥ　ＯＦ　ＴＨＥ”
  49. ？　”　　　ＮＥＥＤＬＥ　ＳＨＯＷＳ　ＴＨＥ　ＮＯＲＴＨ．”
  50. ？
  51. ？　”−　ＰＲＥＳＳ　А　ＴＯ　ＳＥＴ　ＹＯＵＲ　ＬＯＣＡＴＩＯＮ．”
  52. ？　”−　ＰＲＥＳＳ　Ф　ＴＯ　ＥＸＩＴ．”
  53. ＧＯＳＵＢ　＠ＲＯＴＡＴＥ
  54. ＲＥＴＵＲＮ
  56. ＠ＭＡＩＮ
  57. ＶＳＹＮＣ　１
  58. ＩＦ　ＴＣＨＳＴ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＳＥＮＳＥ
  59. ＢＴＮ＝ＢＴＲＩＧ（）
  60. ＩＦ　ＢＴＮ　ＡＮＤ　６４　ＴＨＥＮ　ＲＥＴＵＲＮ
  61. ＩＦ　ＢＴＮ　ＡＮＤ　１６　ＴＨＥＮ　ＧＯＳＵＢ　＠ＡＤＪＵＳＴ
  62. ＧＯＴＯ　＠ＭＡＩＮ
  64. ＠ＦＩＮＡＬＩＺＥ
  65. ＧＰＡＧＥ　０：ＧＰＲＩＯ　３
  66. ＢＧＰＡＧＥ　０
  67. ＡＣＬＳ
  68. ＲＥＴＵＲＮ
  70. ＠ＳＥＮＳＥ
  71. ＩＦ　ＴＣＨＳＴ　ＴＨＥＮ：ＥＬＳＥ　＠ＥＮＤＩＦ＿ＳＥＮＳＥ
  72. 　Ｘ＝ＴＣＨＸ：Ｙ＝ＴＣＨＹ
  73. 　ＧＤＲＡＷＭＤ　１
  74. 　ＧＬＩＮＥ　ＯＸ，ＯＹ，Ｘ，Ｙ，ＬＣ
  75. 　ＶＳＹＮＣ　１
  76. 　ＧＬＩＮＥ　ＯＸ，ＯＹ，Ｘ，Ｙ，ＬＣ
  77. 　ＧＤＲＡＷＭＤ　０
  78. 　ＧＯＴＯ　＠ＳＥＮＳＥ
  79. ＠ＥＮＤＩＦ＿ＳＥＮＳＥ
  80. ＧＯＳＵＢ　＠ＯＲＩＥＮＴ
  81. ＧＯＳＵＢ　＠ＲＯＴＡＴＥ
  82. ＲＥＴＵＲＮ
  84. ＠ＯＲＩＥＮＴ
  85. ＧＯＳＵＢ　＠ＧＥＴ＿ＪＳＴ　’Ｊａｐａｎ　Ｓｔａｎｄａｒｄ　Ｔｉｍｅ　（Ｍｅａｎ　ｓｏｌａｒ　ｔｉｍｅ　ａｔ　Ａｋａｓｈｉ）
  86. ＧＯＳＵＢ　＠ＧＥＴ＿ＥＯＴ　’Ｅｑｕａｔｉｏｎ　Ｏｆ　Ｔｉｍｅ
  87. ＧＯＳＵＢ　＠ＧＥＴ＿ＴＤＭ　’Ｔｉｍｅ　ｄｉｆｆｅｒｅｎｃｅ　ｆｒｏｍ　ＪＳＴ
  88. ＧＯＳＵＢ　＠ＧＥＴ＿ＨＯＵＲ＿ＡＮＧＬＥ
  89. ＧＯＳＵＢ　＠ＧＥＴ＿ＤＥＣＬＩＮＡＴＩＯＮ
  90. ＧＯＳＵＢ　＠ＧＥＴ＿ＡＺＩＭＵＴＨ
  91. ＧＯＳＵＢ　＠ＧＥＴ＿ＡＬＴＩＴＵＤＥ　’Ｆｏｒ　ｉｎｆｏｒｍａｔｉｏｎ　ｐｕｒｐｏｓｅ　ｏｎｌｙ
  92. ＧＯＳＵＢ　＠ＧＥＴ＿ＡＮＧＬＥ　’Ｎｏｒｔｈ／Ｓｏｕｔｈ
  93. ＬＯＣＡＴＥ　０，１５：？　”　”＊３２＊７；
  94. ＬＯＣＡＴＥ　０，１５
  95. ？　”ＬＡＴ＝”；ＬＡＴ，”ＬＯＮＧ＝”；ＬＯＮＧ
  96. ？　”ＤＡＴＥ＝”；ＹＹ；”／”；ＭＭ；”／”；ＤＤ；”　（”；Ｎ；”）”
  97. ？　”ＴＩＭＥ＝”；Ｈ；”：”；Ｍ；”：”；Ｓ；”　”
  98. ？　”ＥＯＴ＝”；ＥＯＴ，”ＴＤＭ＝”；ＴＤＭ
  99. ？　”ＨＡ＝”；ＨＡ，”ＤＥＣ＝”；ＤＥＣ
  100. ？　”ＡＺ＝”；ＡＺ，”ＡＬＴ＝”；ＡＬＴ
  101. ？　”ＴＣＨＤ＝”；ＴＣＨＤ
  102. ？　”ＮＤ＝”；ＮＤ，”ＳＤ＝”；ＳＤ
  103. ＲＥＴＵＲＮ
  105. ＠ＧＥＴ＿ＪＳＴ
  106. ＩＦ　ＬＥＦＴ＄（ＭＥＭ＄，１２）＝＝”ＦＩＸＤＡＴＥＴＩＭＥ＝”　ＴＨＥＮ：ＥＬＳＥ　＠ＥＮＤＩＦ＿ＧＪ
  107. 　ＹＹ＝ＶＡＬ（ＭＩＤ＄（ＭＥＭ＄，１２＋０，４））
  108. 　ＭＭ＝ＶＡＬ（ＭＩＤ＄（ＭＥＭ＄，１２＋４，２））
  109. 　ＤＤ＝ＶＡＬ（ＭＩＤ＄（ＭＥＭ＄，１２＋６，２））
  110. 　Ｈ＝ＶＡＬ（ＭＩＤ＄（ＭＥＭ＄，１２＋８，２））
  111. 　Ｍ＝ＶＡＬ（ＭＩＤ＄（ＭＥＭ＄，１２＋１０，２））
  112. 　Ｓ＝ＶＡＬ（ＭＩＤ＄（ＭＥＭ＄，１２＋１２，２））
  113. 　ＲＥＴＵＲＮ
  114. ＠ＥＮＤＩＦ＿ＧＪ
  115. ＤＴＲＥＡＤ（ＤＡＴＥ＄），ＹＹ，ＭＭ，ＤＤ
  116. ＴＭＲＥＡＤ（ＴＩＭＥ＄），Ｈ，Ｍ，Ｓ
  117. ＲＥＴＵＲＮ
  119. ＠ＧＥＴ＿ＥＯＴ
  120. ’Ｃｕｒｒｅｎｔ　ｄａｙｓ　ｓｉｎｃｅ　Ｊａｎ　１，　２０００
  121. Ｎ＝ＤＤ
  122. ＲＥＳＴＯＲＥ　＠ＤＡＹＳ＿Ａ＿ＭＯＮＴＨ
  123. ＠ＤＡＹＳ＿Ａ＿ＭＯＮＴＨ
  124. ＤＡＴＡ　３１，２８，３１，３０，３１，３０，３１，３１，３０，３１，３０，３１
  125. ＦＯＲ　Ｉ＝１　ＴＯ　ＭＭ−１
  126. 　ＲＥＡＤ　ＤＭ：Ｎ＝Ｎ＋ＤＭ
  127. ＮＥＸＴ
  128. Ｎ＝Ｎ＋（ＹＹ％４＝＝０　ＡＮＤ　ＹＹ％１００＞０　ＯＲ　ＹＹ％４００＝＝０）
  129. ＦＯＲ　Ｙ２Ｋ＝０　ＴＯ　ＹＹ−１−２０００
  130. 　Ｎ＝Ｎ＋３６５＋（Ｙ２Ｋ％４＝＝０　ＡＮＤ　Ｙ２Ｋ％１００＞０　ＯＲ　Ｙ２Ｋ％４００＝＝０）
  131. ＮＥＸＴ
  132. ’Ｍｅａｎ　ａｎｏｍａｌｙ　ｎｏｒｍａｌｉｚｅｄ
  133. ’ｉｎ　ｄａｙｓ　ｉｎ　ａ　ｔｒｏｐｉｃａｌ　ｙｅａｒ
  134. ’（ｐｅｒｉｈｅｌｉｏｎ：　ａｂｏｕｔ　Ｊａｎ．　４）
  135. ＭＡ＝２＊ＰＩ（）＊（Ｎ−４）／３６５．２４２
  136. ’Ｅｑｕａｔｉｏｎ　ｏｆ　ｔｉｍｅ　ｉｎ　ｍｉｎｕｔｅ
  137. ’（ｆｒｏｍ　Ｗｉｋｉｐｅｄｉａ　［ｅｎ］）
  138. ＥＯＴ＝−７．６５７＊ＳＩＮ（ＭＡ）＋９．８６２＊ＳＩＮ（２＊ＭＡ＋３．５９９）
  139. ＲＥＴＵＲＮ
  141. ＠ＧＥＴ＿ＴＤＭ
  142. ’Ｔｉｍｅ　ｄｉｆｆｅｒｅｎｃｅ　ｉｎ　ｄｅｇｒｅｅ
  143. ＴＤＤ＝ＬＯＮＧ−ＪＳＴＬＯＮＧ
  144. ’Ｔｉｍｅ　ｄｉｆｆｅｒｅｎｃｅ　ｉｎ　ｍｉｎｕｔｅ
  145. ＴＤＭ＝２４＊６０＊ＴＤＤ／３６０
  146. ＲＥＴＵＲＮ
  148. ＠ＧＥＴ＿ＨＯＵＲ＿ＡＮＧＬＥ
  149. ’０　ｄｅｇｒｅｅ　ａｔ　ｎｏｏｎ
  150. ＨＡ＝（Ｈ−１２）＊１５＋（Ｍ＋ＥＯＴ＋ＴＤＭ）／４＋Ｓ／２４０
  151. ＲＥＴＵＲＮ
  153. ＠ＧＥＴ＿ＤＥＣＬＩＮＡＴＩＯＮ
  154. ’（ｖｅｒｎａｌ　ｅｑｕｉｎｏｘ：　ａｂｏｕｔ　Ｍａｒ．　２０／２１）
  155. ＥＣＬＯＮＧ＝２＊ＰＩ（）＊（Ｎ−８０．２４２）／３６５．２４２
  156. ＤＥＣ＝２３．４４＊ＳＩＮ（ＥＣＬＯＮＧ）
  157. ＲＥＴＵＲＮ
  159. ＠ＧＥＴ＿ＡＺＩＭＵＴＨ
  160. ’ｄｅｇ−＞ｒａｄ　ｃｏｎｖｅｒｓｉｏｎ
  161. ’ａｖｏｉｄ　ＲＡＤ（ｘ）　ｆｏｒ　ｎｏｎ−ｉｎｔｅｇｒａｌ　ｘ．
  162. ＨＡＲ＝ＰＩ（）＊ＨＡ／１８０
  163. ＬＡＴＲ＝ＰＩ（）＊ＬＡＴ／１８０
  164. ＤＥＣＲ＝ＰＩ（）＊ＤＥＣ／１８０
  165. ’Ｃｏｏｒｄｉｎａｔｅ　ｃｏｎｖｅｒｓｉｏｎ
  166. ’ｅｑｕａｔｏｒｉａｌ−＞ｈｏｒｉｚｏｎｔａｌ
  167. ’（ｆｒｏｍ　Ｗｉｋｉｐｅｄｉａ　［ｅｎ］）
  168. ＳＩＮＡＺＣＯＳＡＬＴ＝−ＣＯＳ（ＤＥＣＲ）＊ＳＩＮ（ＨＡＲ）
  169. ＣＯＳＡＺＣＯＳＡＬＴ＝ＣＯＳ（ＬＡＴＲ）＊ＳＩＮ（ＤＥＣＲ）−ＳＩＮ（ＬＡＴＲ）＊ＣＯＳ（ＤＥＣＲ）＊ＣＯＳ（ＨＡＲ）
  170. ＡＺＲ＝ＡＴＡＮ（ＳＩＮＡＺＣＯＳＡＬＴ，ＣＯＳＡＺＣＯＳＡＬＴ）
  171. ＡＺ＝（ＤＥＧ（ＡＺＲ）＋３６０）％３６０
  172. ＲＥＴＵＲＮ
  174. ＠ＧＥＴ＿ＡＬＴＩＴＵＤＥ
  175. ’Ｎｏ　ｎｅｅｄ　ｆｏｒ　ｎｅｅｄｌｅ　ｒｏｔａｔｉｏｎ
  176. ＣＯＳＡＬＴ＝ＳＩＮＡＺＣＯＳＡＬＴ／ＳＩＮ（ＡＺＲ）
  177. ＳＩＮＡＬＴ＝ＳＩＮ（ＬＡＴＲ）＊ＳＩＮ（ＤＥＣＲ）＋ＣＯＳ（ＬＡＴＲ）＊ＣＯＳ（ＤＥＣＲ）＊ＣＯＳ（ＨＡＲ）
  178. ＡＬＴ＝ＤＥＧ（ＡＴＡＮ（ＳＩＮＡＬＴ，ＣＯＳＡＬＴ））
  179. ＩＦ　ＡＬＴ＞９０　ＴＨＥＮ　ＡＬＴ＝１８０−ＡＬＴ
  180. ＩＦ　ＡＬＴ＜−９０　ＴＨＥＮ　ＡＬＴ＝−１８０−ＡＬＴ
  181. ＲＥＴＵＲＮ
  183. ＠ＧＥＴ＿ＡＮＧＬＥ
  184. ＳＵＮＤ＝ＡＺ
  185. ＴＣＨＤ＝（ＤＥＧ（ＡＴＡＮ（Ｙ−ＯＹ，Ｘ−ＯＸ））＋３６０）％３６０
  186. ’Ｎｏｒｔｈ／Ｓｏｕｔｈ　ａｎｇｌｅ　ｉｎ　ｄｅｇｒｅｅ
  187. ’ｃｏｕｎｔｅｒｃｌｏｃｋｗｉｓｅ
  188. ＳＤ＝（７２０−（ＴＣＨＤ−ＳＵＮＤ））％３６０
  189. ＮＤ＝（ＳＤ＋１８０）％３６０
  190. ＲＥＴＵＲＮ
  192. ＠ＲＯＴＡＴＥ
  193. ’Ｐａｉｎｔ　ｔｗｉｃｅ　ｔｏ　ａｖｏｉｄ　ｔｈｅ　ｂｕｇ
  194. ＧＰＡＩＮＴ　ＯＸ＋ＰＲ，ＯＹ＋ＰＲ，ＢＣ２，ＣＣ
  195. ＧＰＡＩＮＴ　ＯＸ＋ＰＲ，ＯＹ＋ＰＲ，ＢＣ，ＣＣ
  196. ’Ｓｏｕｔｈ
  197. Ｃ＝ＳＣ：ＷＤ＝５
  198. ＢＤ＝ＳＤ−ＷＤ：ＥＤ＝ＳＤ＋ＷＤ
  199. ＧＯＳＵＢ　＠ＤＲＡＷ＿ＮＥＥＤＬＥ
  200. ’Ｎｏｒｔｈ
  201. Ｃ＝ＮＣ：ＷＤ＝５
  202. ＢＤ＝ＮＤ−ＷＤ：ＥＤ＝ＮＤ＋ＷＤ
  203. ＧＯＳＵＢ　＠ＤＲＡＷ＿ＮＥＥＤＬＥ
  204. ＲＥＴＵＲＮ
  206. ＠ＤＲＡＷ＿ＮＥＥＤＬＥ
  207. ＢＤ＝ＦＬＯＯＲ（ＢＤ＋０．５）
  208. ＥＤ＝ＦＬＯＯＲ（ＥＤ＋０．５）
  209. ＩＦ　ＢＤ＜０　ＴＨＥＮ　ＧＯＳＵＢ　＠ＤＲＡＷ＿ＮＥＥＤＬＥ１
  210. ＩＦ　ＥＤ＞３６０　ＴＨＥＮ　ＧＯＳＵＢ　＠ＤＲＡＷ＿ＮＥＥＤＬＥ２
  211. ＩＦ　ＢＤ＝＝ＥＤ　ＴＨＥＮ　ＲＥＴＵＲＮ
  212. ＦＯＲ　Ｒ＝ＰＲ＋２　ＴＯ　ＣＲ−８
  213. 　ＧＣＩＲＣＬＥ　ＯＸ，ＯＹ，Ｒ，Ｃ，ＢＤ，ＥＤ
  214. ＮＥＸＴ
  215. ＲＥＴＵＲＮ
  217. ＠ＤＲＡＷ＿ＮＥＥＤＬＥ１
  218. ＦＯＲ　Ｒ＝ＰＲ＋２　ＴＯ　ＣＲ−８
  219. 　ＧＣＩＲＣＬＥ　ＯＸ，ＯＹ，Ｒ，Ｃ，ＢＤ＋３６０，３６０
  220. ＮＥＸＴ
  221. ＢＤ＝０
  222. ＲＥＴＵＲＮ
  224. ＠ＤＲＡＷ＿ＮＥＥＤＬＥ２
  225. ＦＯＲ　Ｒ＝ＰＲ＋２　ＴＯ　ＣＲ−８
  226. 　ＧＣＩＲＣＬＥ　ＯＸ，ＯＹ，Ｒ，Ｃ，０，ＥＤ−３６０
  227. ＮＥＸＴ
  228. ＥＤ＝３６０
  229. ＲＥＴＵＲＮ
  231. ＠ＡＤＪＵＳＴ
  232. ＧＯＳＵＢ　＠ＡＤＪＵＳＴ＿ＥＮＴＲＹ
  233. ＧＯＳＵＢ　＠ＡＤＪＵＳＴ＿ＭＡＩＮ
  234. ＧＯＳＵＢ　＠ＡＤＪＵＳＴ＿ＥＸＩＴ
  235. ＲＥＴＵＲＮ
  237. ＠ＡＤＪＵＳＴ＿ＥＮＴＲＹ
  238. ＧＣＬＳ
  239. ＧＯＳＵＢ　＠ＳＨＯＷ＿ＢＧＭＡＰ
  240. ＧＯＳＵＢ　＠ＤＲＡＷ＿ＧＲＩＤ
  241. ＧＯＳＵＢ　＠ＤＲＡＷ＿ＩＮＩＴ＿ＰＴＲ
  242. ＲＥＴＵＲＮ
  244. ＠ＡＤＪＵＳＴ＿ＭＡＩＮ
  245. ＶＳＹＮＣ　１
  246. ＩＦ　ＴＣＨＳＴ　ＴＨＥＮ　ＧＯＳＵＢ　＠ＡＤＪＵＳＴ＿ＬＯＣＡＴＩＯＮ
  247. ＢＴＮ＝ＢＴＲＩＧ（）
  248. ＩＦ　ＢＴＮ　ＡＮＤ　１６　ＴＨＥＮ　ＲＥＴＵＲＮ
  249. ＩＦ　ＢＴＮ　ＡＮＤ　１２８　ＴＨＥＮ　ＧＯＳＵＢ　＠ＩＮＰＵＴ＿ＬＯＣＡＴＩＯＮ
  250. ＧＯＴＯ　＠ＡＤＪＵＳＴ＿ＭＡＩＮ
  251. ＲＥＴＵＲＮ
  253. ＠ＡＤＪＵＳＴ＿ＥＸＩＴ
  254. ＧＯＳＵＢ　＠ＨＩＤＥ＿ＢＧＭＡＰ
  255. ＧＯＳＵＢ　＠ＤＲＡＷ＿ＣＯＭＰＡＳＳ
  256. ＲＥＴＵＲＮ
  258. ＠ＳＨＯＷ＿ＢＧＭＡＰ
  259. ＢＧＯＦＳ　０，０，２４＊８
  260. ＢＧＯＦＳ　１，０，２４＊８
  261. ＲＥＴＵＲＮ
  263. ＠ＨＩＤＥ＿ＢＧＭＡＰ
  264. ＢＧＯＦＳ　０，０，０
  265. ＢＧＯＦＳ　１，０，０
  266. ＲＥＴＵＲＮ
  268. ＠ＤＲＡＷ＿ＧＲＩＤ
  269. ＦＯＲ　ＧＸ＝０　ＴＯ　２５５　ＳＴＥＰ　ＤＸ
  270. 　ＧＬＩＮＥ　ＧＸ，０，ＧＸ，１９１，ＧＣ
  271. ＮＥＸＴ
  272. ＦＯＲ　ＧＹ＝０　ＴＯ　１９１　ＳＴＥＰ　ＤＹ
  273. 　ＧＬＩＮＥ　０，ＧＹ，２５５，ＧＹ，ＧＣ
  274. ＮＥＸＴ
  275. ＲＥＴＵＲＮ
  277. ＠ＤＲＡＷ＿ＩＮＩＴ＿ＰＴＲ
  278. ＴＸ＝ＦＬＯＯＲ（（ＬＯＮＧ−１２０）＊ＤＸ／５＋０．５）
  279. ＴＹ＝ＦＬＯＯＲ（（４５−ＬＡＴ）＊ＤＹ／５＋０．５）
  280. ＧＤＲＡＷＭＤ　１
  281. ＧＬＩＮＥ　ＴＸ，０，ＴＸ，１９１，ＰＣ
  282. ＧＬＩＮＥ　０，ＴＹ，２５５，ＴＹ，ＰＣ
  283. ＧＤＲＡＷＭＤ　０
  284. ＬＯＣＡＴＥ　０，１５：？　”　”＊３２＊７
  285. ＬＯＣＡＴＥ　０，１５
  286. ＣＬＳ：ＬＯＣＡＴＥ　０，０
  287. ？　”ＴＯＵＣＨ　ＹＯＵＲ　ＬＯＣＡＴＩＯＮ　ＯＮ　ＴＨＥ　ＭＡＰ．”
  288. ？
  289. ？　”−　ＰＲＥＳＳ　Х　ＴＯ　ＩＮＰＵＴ　ＹＯＵＲ　ＤＥＴＡＩＬ”
  290. ？　”　　ＬＯＣＡＴＩＯＮ．”
  291. ？　”−　ＰＲＥＳＳ　Ф　ＴＯ　ＲＥＴＵＲＮ．”
  292. ＬＯＣＡＴＥ　０，１５
  293. ？　”ＬＡＴ＝”；ＬＡＴ，”ＬＯＮＧ＝”；ＬＯＮＧ
  294. ＲＥＴＵＲＮ
  296. ＠ＡＤＪＵＳＴ＿ＬＯＣＡＴＩＯＮ
  297. ＶＳＹＮＣ　１
  298. ＩＦ　ＴＣＨＳＴ　ＴＨＥＮ：ＥＬＳＥ　＠ＥＮＤＩＦ＿ＡＰ
  299. 　ＧＤＲＡＷＭＤ　１
  300. 　ＧＬＩＮＥ　ＴＸ，０，ＴＸ，１９１，ＰＣ
  301. 　ＧＬＩＮＥ　０，ＴＹ，２５５，ＴＹ，ＰＣ
  302. 　ＴＸ＝ＴＣＨＸ：ＴＹ＝ＴＣＨＹ
  303. 　ＧＬＩＮＥ　ＴＸ，０，ＴＸ，１９１，ＰＣ
  304. 　ＧＬＩＮＥ　０，ＴＹ，２５５，ＴＹ，ＰＣ
  305. 　ＧＤＲＡＷＭＤ　０
  306. 　ＧＯＴＯ　＠ＡＤＪＵＳＴ＿ＬＯＣＡＴＩＯＮ
  307. ＠ＥＮＤＩＦ＿ＡＰ
  308. ＬＡＴ＝４５−ＴＹ＊５／ＤＹ
  309. ＩＦ　ＴＸ＜８＊ＢＸ　ＡＮＤ　ＴＹ＜８＊ＢＹ　ＴＨＥＮ　ＬＡＴ＝ＬＡＴ−１５
  310. ＬＯＮＧ＝１２０＋ＴＸ＊５／ＤＸ
  311. ＬＯＣＡＴＥ　０，１５：？　”　”＊３２＊７；
  312. ＬＯＣＡＴＥ　０，１５
  313. ？　”ＬＡＴ＝”；ＬＡＴ，”ＬＯＮＧ＝”；ＬＯＮＧ
  314. ＲＥＴＵＲＮ
  316. ＠ＩＮＰＵＴ＿ＬＯＣＡＴＩＯＮ
  317. ＣＬＳ：ＬＯＣＡＴＥ　０，０
  318. ？　”ＩＮＰＵＴ　ＹＯＵＲ　ＬＯＣＡＴＩＯＮ　ＩＮ　ＤＥＧＲＥＥ．”
  319. ＬＯＣＡＴＥ　０，１５
  320. ？　”ＬＡＴ＝”；ＬＡＴ，”ＬＯＮＧ＝”；ＬＯＮＧ
  321. ＠ＩＮＰＵＴ＿ＬＡＴ
  322. ＬＯＣＡＴＥ　０，１７
  323. ＬＩＮＰＵＴ　”ＮＯＲＴＨ　ＬＡＴＩＴＵＤＥ：　ＬＡＴ＝？”；Ｌ＄
  324. ＩＦ　Ｌ＄＝＝””　ＴＨＥＮ　＠ＩＮＰＵＴ＿ＬＯＮＧ
  325. Ｌ＝ＶＡＬ（Ｌ＄）
  326. ＩＦ　Ｌ＜２３．４４　ＯＲ　９０＜Ｌ　ＴＨＥＮ　？　”ＯＵＴ　ＯＦ　ＲＡＮＧＥ．”：ＧＯＴＯ　＠ＩＮＰＵＴ＿ＬＡＴ
  327. ＬＡＴ＝Ｌ
  328. ＠ＩＮＰＵＴ＿ＬＯＮＧ
  329. ＬＩＮＰＵＴ　”ＥＡＳＴ　ＬＯＮＧＩＴＵＤＥ：　ＬＯＮＧ＝？”；Ｌ＄
  330. ＩＦ　Ｌ＄＝＝””　ＴＨＥＮ　＠ＩＮＰＵＴ＿ＤＯＮＥ
  331. Ｌ＝ＶＡＬ（Ｌ＄）
  332. ＩＦ　Ｌ＜−１８０　ＯＲ　１８０＜Ｌ　ＴＨＥＮ　？　”ＯＵＴ　ＯＦ　ＲＡＮＧＥ．”：ＧＯＴＯ　＠ＩＮＰＵＴ＿ＬＯＮＧ
  333. ＬＯＮＧ＝Ｌ
  334. ＠ＩＮＰＵＴ＿ＤＯＮＥ
  335. ＷＡＩＴ　３０
  336. ＧＤＲＡＷＭＤ　１
  337. ＧＬＩＮＥ　ＴＸ，０，ＴＸ，１９１，ＰＣ
  338. ＧＬＩＮＥ　０，ＴＹ，２５５，ＴＹ，ＰＣ
  339. ＧＤＲＡＷＭＤ　０
  340. ＧＯＳＵＢ　＠ＤＲＡＷ＿ＩＮＩＴ＿ＰＴＲ
  341. ＲＥＴＵＲＮ
  343. ＠ＰＵＴ＿ＢＧＭＡＰ
  344. ’ＬＯＡＤ　”ＳＣＵ１：ＯＫ＿ＪＭＡＰ１”，ＦＡＬＳＥ
  345. ＲＥＳＴＯＲＥ　＠ＢＧＭＡＰ
  346. ＦＯＲ　Ｊ＝０　ＴＯ　２３
  347. 　ＲＥＡＤ　Ｄ＄
  348. 　ＦＯＲ　Ｉ＝０　ＴＯ　３１
  349. 　　ＩＤＸ＝ＦＬＯＯＲ（Ｉ／４）
  350. 　　ＭＤＲ＝ＰＯＷ（２，３−Ｉ％４）
  351. 　　ＩＦ　ＶＡＬ（”＆Ｈ”＋ＭＩＤ＄（Ｄ＄，ＩＤＸ，１））　ＡＮＤ　ＭＤＲ　ＴＨＥＮ　ＳＣＲＤ＝＆Ｈ８０２５　ＥＬＳＥ　ＳＣＲＤ＝＆Ｈ８００Ａ
  352. 　　ＢＧＰＵＴ　１，Ｉ，２４＋Ｊ，ＳＣＲＤ
  353. 　ＮＥＸＴ
  354. ＮＥＸＴ
  355. ＢＧＦＩＬＬ　０，０，２４，ＢＸ，２４＋ＢＹ，＆Ｈ０００Ｅ
  356. ＢＧＦＩＬＬ　０，０，２４，ＢＸ−１，２４＋ＢＹ−１，＆Ｈ００００
  357. ＲＥＴＵＲＮ
  359. ＠ＢＧＭＡＰ
  360. ＤＡＴＡ　００００００２０
  361. ＤＡＴＡ　００００００３８
  362. ＤＡＴＡ　００００００３Ｅ
  363. ＤＡＴＡ　００１０００７Ｃ
  364. ＤＡＴＡ　００００００Ｄ８
  365. ＤＡＴＡ　００４０００８０
  366. ＤＡＴＡ　００８０００４０
  367. ＤＡＴＡ　００００００Ｅ０
  368. ＤＡＴＡ　０８００００Ｅ０
  369. ＤＡＴＡ　００００００Ｅ０
  370. ＤＡＴＡ　０００００２Ｅ０
  371. ＤＡＴＡ　０００００１Ｃ０
  372. ＤＡＴＡ　０００００ＢＣ０
  373. ＤＡＴＡ　０００１０ＦＣ０
  374. ＤＡＴＡ　００００１Ｆ８０
  375. ＤＡＴＡ　０００３ＦＦ８０
  376. ＤＡＴＡ　０００７ＦＦ００
  377. ＤＡＴＡ　００２６５８００
  378. ＤＡＴＡ　０００９Ｄ０００
  379. ＤＡＴＡ　００５Ｄ８０００
  380. ＤＡＴＡ　０００Ｃ００００
  381. ＤＡＴＡ　０００Ｃ００００
  382. ＤＡＴＡ　００００００００
  383. ＤＡＴＡ　０００８００００

CHECKER FLAG (ひとことコメント)

この作品に対するコメントがあれば一言どうぞ。(作品に直接関係ない質問や雑談は掲示板へ)

  • 投稿者 : ご意見ご要望があればぜひ。 (2012/05/20 (日) 02:15:27)
  • しーきゃ : 計算結果で表示される変数の意味（　ＥＯＴ＝時間の方程式　とか）をここの説明にのせたらいいんじゃないでしょうか (2012/05/20 (日) 22:10:42)
  • 名無しさん : あんまり自分でも分かっていないからなあ。とりあえず参考URLをひとつ載せました。 (2012/05/21 (月) 07:07:27)
  • 投稿者 : あと、AZの基準の説明の間違いをこそっと修正。 (2012/05/21 (月) 07:09:45)
  • 名無しさん : 画像が大きすぎてＱＲコードが表示されない (2012/05/22 (火) 03:02:10)
  • 名無しさん : 注意がｸｿﾜﾛﾀ (2012/05/22 (火) 15:45:12)
  • 名無しさん : エイコ゛カ゛ワカラナイＹＯ（　´ー｀）フウー (2012/05/22 (火) 15:51:50)
  • 投稿者 : QRコードを分割画像(縦横2倍)にして1ファイルのサイズを小さくしました。 (2012/05/24 (木) 01:14:15)
  • 投稿者 : ついでに参考URLを増やしたりしていじってみました。 (2012/05/24 (木) 01:24:41)
  • カービィ★KIRBY : 上画面の説明文がぁぁぁっ！ わか蘭っ！！！ (2012/06/03 (日) 14:04:33)
  • ウイング : なにこれすごい (2012/06/04 (月) 19:31:57)
  • Amako Soft : やべえ面白そう (2012/06/13 (水) 18:52:50)
  • nao sato : 英語だったので和訳してみました。 (2013/01/30 (水) 20:05:00)
  • ヨッシー : プチコン3号にうつそうとおもったけど、50行ほどいったところで400行は、無理だ。と思い考え中。 (2015/07/08 (水) 01:03:59)
  • 投稿者 : 3号に移植しました。一応モーションセンサー対応。公開キー：X3SK4P4Y (2015/10/02 (金) 00:21:28)

*1 5/20: 当初のQRコードとプログラムリストは172行目のRETURNが抜けていたのでこそっと修正しました。

表示モード : [ スマホ・3DS対応表示 | クラシック表示 ]
PukiWiki 1.4.7 Copyright © 2001-2006 PukiWiki Developers Team. License is GPL. Based on "PukiWiki" 1.3 by yu-ji
ページの処理時間 : 0.155 秒 | このページの最終更新 : 2022/09/20 (火) 12:44:03 (565d) | ログイン
Copyright(C) 2011-2014 プチコンまとめWiki ◆1sxkymI8ji30