プチコンまとめWiki (初代/mkII)

Toukou/Wind●ws8 の変更点

パンくずリスト


#title(投稿プログラム : プチコン版Wind●ws8)
#contents
// ↑この2行は削除しないでください。
2013年10月24日投稿
//------------------------------------------------------------------------------
// ・投稿者名は、将来的に投稿プログラム一覧に表示するために使用します。
// ・「名無しさん」のままにしておくと、匿名の方からの投稿として扱われます。
// ↓↓↓
/ 投稿者 : sou51
// ↑↑↑
//------------------------------------------------------------------------------
// ・適当にタグをつけることができます。半角のコンマ区切りで複数つけられます。
//   タグをつけると、同じタグが付いたページを検索することができます。
// ★次に該当するプログラムは、特定のタグを設定するようご協力お願いします。
//   これらを設定すると、将来的に投稿プログラム一覧に目立つマークが付くようになる予定です。
// ・短いプログラム → 「1行プログラム」「数行プログラム」「1画面プログラム」タグのいずれか1つ
// ・初代プチコンでも動作するプログラム → 「初代対応」タグ
// ・mkII 以降専用のプログラム → 「mkII専用」タグ
// ・QRコードを掲載している → 「QRコード」タグ
// ・該当するなら「ゲーム」「実用ツール」「音楽」タグのいずれか
// ↓↓↓
/ &tag(投稿プログラム,ネタ,ツール,QRコード,ランチャ,mkII専用);
// ↑↑↑

//------------------------------------------------------------------------------
// ここに概要とか書きます。
// ・** や *** で始まる行は子見出しとなります。* の数で深さが決まります。
// ・[#英数字] はページ内リンクに使用されるアンカーですが、
//   書かなかったり、消したりしてもかまいません。ない場合はランダムな文字列が自動付与されます。

* 概要 [#Summary]
Windows8.1が発売されましたが、プチコンにもなんか出たようです。

* 使い方 [#vd24d666]
Windows8のスタート画面風のジョークソフトです。~
プログラム末尾のDATA文を編集することで、パネルを変更できます。~

DATA文の内容は、サイズ、色、ラベル、動作定義 となっています。~
サイズは1,2,4が指定可能で、2を指定すると2x1(横2倍)サイズ、4を指定すると2x2サイズになります。~
DATA文は8個ごとに1セットとなっており、2や4を指定したパネルがあるとその分末尾のDATAは非表示となります。~
動作定義の箇所に文字列を入れておくと、EXEC命令が実行されます。~
また動作定義を"@"で始まる文字列にすると、そのラベルへGOTOでジャンプします。~
最大で8x3=24個のパネルを配置できます。

ジョークソフトとして早急に作ったので、"@"の動作などかなり荒い作りになっていますがご了承ください。~

ペイントを選択するとCHREDが起動します。~
ミュージックを選択するとプログラム内でBGMPLAYテスト用のソフトが起動されます。~
それ以外のパネルは全てダミーです。

パネル部分はBG1枚分で作っています。~
これをループするようにすればもっと登録できてランチャとしても実用的になるのかもしれません。

/////////////////////////////////

* スクリーンショット・動画 [#ScreenShots]
// 動作しているところを撮影した写真や動画があれば貼り付けてください。

// ページを作成すると、画像の添付ができるようになります。(作成する前はできません)
// 作成後のページの右上、ウィキメニューにある「添付」から画像をアップロードできます。
// (添付ファイルはページごとに別個に管理されています。必ず作成後のページに添付してください)
// 画像をアップロードしたら、以下の書式でページ内に貼り付けられます。
// #ref(添付ファイル名)

// 以下の書式で、YouTube やニコニコ動画を貼り付けられます。
// #youtube(0HWX7kovgY8)
// #nicovideo(sm13684820)

/////////////////////////////////
// QR コードがない場合は、この部分は削除してください

* QR コード [#QR]
プチコンmkII向けのインストール用画像データです。3枚組となっています。

// 【重要】旧プチコンから mkII に転送したプログラムは、mkII で保存しなおしてから
// QR コード化すると、枚数が半分ぐらいに減ります。ぜひお試し下さい。
// 【重要】添付できるのは画像ファイルのみです。zip ファイルは解凍してください。

// ページを作成すると、QR コードの添付ができるようになります。(作成する前はできません)
// 作成後のページの右上、ウィキメニューにある「添付」から画像をアップロードできます。
// (添付ファイルはページごとに別個に管理されています。必ず作成後のページに添付してください)
// QR コードをアップロードしたら、以下の書式でページ内に貼り付けられます。
// #ref(アップロードしたファイル名)

// QR コードを大きくしたい場合は、倍率指定ができます。コンマは必ず 2 つ指定してください。
// ブラウザによっては補完がかかってボケますが、それでも問題なく読み込み可能です。
// #ref(アップロードしたファイル名,,200%)

#ref(S51WIN8.PNG,,100%)

// 複数の QR コードを貼り付けるために表組みを用いる場合、&ref(); を使用します。
// (#ref() を表に埋め込んでしまうと、古い Internet Explorer でうまく表示されません)
// |>|>|~PRG:FILENAME|
// |~1/3|~2/3|~3/3|
// |&ref(qr0.png,,200%);|&ref(qr1.png,,200%);|&ref(qr2.png,,200%);|

/////////////////////////////////

* プログラムリスト [#List]
#basic{{
@START
ACLS:CLEAR
GPAGE 1:BGPAGE 1
PNLTYPE”OFF”
DIM PNLS(3,8),PNLC(3,8)
DIM PNLN$(3,8),PNLF$(3,8)
DIM BGP$(67,24)

PNLSTR 1,1,”スタ−ト”,0
PNLSTR 24,1,”sou51 Ж”

GPAINT 0,0,6
X=0
PX1=0:PX2=66
PY1=0:PY2=23
PN$=””:GOSUB@SETAR

GOSUB@LDDATA
FOR I=0 TO 2
 PX=0:PY=0
 FOR J=0 TO 7
  N=PNLS(I,J)
  PX1=3+I*21+PX*10
  PY1=4+PY*5
  PX2=PX1+8+(N%2==0)*10
  PY2=PY1+3+(N>2)*5
  PN$=PNLF$(I,J)
  GOSUB@SETAR
  BGFILL 1,PX1,PY1,PX2,PY2,6,PNLC(I,J),0,0
  N2=LEN(PNLN$(I,J))
  IF N2>8 THEN N2=8
  FOR K=0 TO N2−1
   BGPUT 0,PX1+K,PY1+3,256+ASC(MID$(PNLN$(I,J),K,1)),0,0,0
  NEXT
  PX=(PX+(N%2))%2
  PY=PY+(PX==0)+(N>2)
  IF PY>3 THEN J=99
 NEXT
NEXT

TF=TCHST:TF0=TF
TOX=TCHX:TOY=TCHY
BX=0:T0=MAINCNTL
@LP
 TCH=TF0 XOR TF
 IF TCH AND TF THEN TOX=TCHX:TX0=TCHX:T0=MAINCNTL:SWP=0
 IF !TF THEN @LP0
 IF ABS(TCHX−TX0)<4 THEN @ELP
  TX=TCHX−TOX
  BX=BX−TX
  TOX=TCHX
  IF BX<0 THEN BX=0
  IF BX>279 THEN BX=279
  BGOFS 0,BX,0
  BGOFS 1,BX,0
  SWP=SWP OR(ABS(TOX−TX0)>8)
  GOTO @ELP
 @LP0
  IF !TCH THEN @ELP
  IF SWP THEN @ELP
   TBX=FLOOR((BX+TCHX)/8)
   TBY=FLOOR(TCHY/8)
   F$=BGP$(TBX,TBY)
   ?TBX”,”TBY”,”CHR$(34);F$;CHR$(34)
   IF F$==”” THEN @ELP
   IF LEFT$(F$,1)!=”@” THEN ACLS:EXEC F$
   GOTO F$
@ELP
TF0=TF
TF=TCHST
GOTO@LP
END

@SETAR
FOR AX=PX1 TO PX2
 FOR AY=PY1 TO PY2
  BGP$(AX,AY)=PN$
 NEXT
NEXT
RETURN

@MUSIC
 ACLS:GPAGE 1:BGPAGE 1
 GPAINT 0,0,6

 GFILL 8,32,71,96,13
 GBOX 12,36,15,92,15
 GLINE 16,64,41,36,15:GLINE 16,65,41,92,15:GLINE 41,36,41,92,15
 GLINE 42,64,67,36,15:GLINE 42,65,67,92,15:GLINE 67,36,67,92,15

 GFILL 184,32,247,96,13
 GBOX 240,36,243,92,15
 GLINE 239,64,213,36,15:GLINE 239,65,213,92,15:GLINE 213,36,213,92,15
 GLINE 213,64,187,36,15:GLINE 213,65,187,92,15:GLINE 187,36,187,92,15

 GFILL 76,32,180,96,13
 GLINE 78,36,78,92,15
 GLINE 78,36,118,64,15
 GLINE 78,92,118,65,15
 GBOX 128,36,176,92,15

 GFILL 4,4,20,20,13
 GLINE 6,12,10,6,15
 GLINE 6,12,10,18,15
 GLINE 6,12,18,12,15

 MN=0:MP=0
@MUSICLP
T0=TCHST
VSYNC 1
IF !(TCHST XOR T0)OR !TCHST THEN GOTO@MUSICLP
 TX=TCHX:TY=TCHY:T0=TCHST
 IF TX>7 AND TX<72 AND TY>31 AND TY<97 THEN MN=(MN+28)%29:GOTO@MUSICLP
 IF TX>183 AND TX<248 AND TY>31 AND TY<97 THEN MN=(MN+1)%29:GOTO@MUSICLP
 IF TX>75 AND TX<181 AND TY>31 AND TY<97 AND !MP THEN BGMPLAY MN:MP=1:GOTO@MUSICLP
 IF TX>75 AND TX<181 AND TY>31 AND TY<97 AND MP THEN BGMSTOP:MP=0:GOTO@MUSICLP
 IF TX>3 AND TX<21 AND TY>3 AND TY<21 THEN @MUSICEND
GOTO@MUSICLP
@MUSICEND
BGMSTOP
GOTO@START

@LDDATA
RESTORE@LDDATA
FOR I=0 TO 2
 FOR J=0 TO 7
  READ PNLS(I,J),PNLC(I,J),PNLN$(I,J),PNLF$(I,J)
 NEXT
NEXT

FOR I=0 TO 255
 CHRREAD(”BGF”,I),S$
 CHRSET ”BGU1”,I,S$
NEXT

RETURN

DATA 2,1,”テ゛スクトッフ゜”,””
DATA 1,2,”メ−ル”,””
DATA 1,3,”フォト”,””
DATA 2,4,”People”,””
DATA 1,5,”メッセ−シ゛”,””
DATA 1,6,”テンキ”,””
DATA 1,0,””,””
DATA 1,0,””,””
DATA 1,8,”ケ゛−ム”,””
DATA 1,9,”IE”,””
DATA 1,11,”ストア”,””
DATA 1,12,”Map”,””
DATA 1,13,”SkyDrive”,””
DATA 1,14,”ニュ−ス”,””
DATA 1,15,”ミュ−シ゛ック”,”@MUSIC”
DATA 1,0,””,””
DATA 1,6,”iCloud”,””
DATA 1,1,”Dropbox”,””
DATA 1,2,”Word”,””
DATA 1,3,”Excel”,””
DATA 1,4,”ヘ゜イント”,”CHRED”
DATA 1,5,”OneNote”,””
DATA 1,6,”カレンタ゛−”,””
DATA 1,8,”Address”,””
}}

/////////////////////////////////
// コメントを募集したくないなら、ここから下は削除してください

* CHECKER FLAG (ひとことコメント) [#Comments]
この作品に対するコメントがあれば一言どうぞ。(作品に直接関係ない質問や雑談は[[掲示板>Board]]へ)
- ''しゃしゃつー'' : すげえ、それっぽいw (&new{2013/10/26 (土) 17:30:38};)
- ''かずえもん'' : このソフトといろいろなプログラムを組み合わせて、OSを作って公開してもいいですか? (&new{2013/10/28 (月) 15:03:33};)
- ''道産子(dosankosoft)'' : ランチャーが作れそうだな・・・ (&new{2013/10/28 (月) 22:05:23};)
- ''sou51'' : ネタで作っただけなので好きに使ってくれでいいですよ (&new{2013/11/03 (日) 20:37:08};)
- ''暁'' : 予想してたものと違った、あれかと思った (&new{2013/11/04 (月) 19:21:15};)
- ''nao20010128nao'' : 超そっくり!8の本物を持っている私は、大爆笑しちゃいました! (&new{2014/03/25 (火) 14:12:34};)
- ''名無しさん'' : おぉぉぉ (&new{2014/03/25 (火) 15:42:36};)
- ''しょうま'' : すごいいいいいいい!!!!! (&new{2014/09/22 (月) 18:05:02};)
- ''Shun8'' : タブレット見たいなOSを作ります。 (&new{2017/10/23 (月) 21:38:57};)

#comment

表示モード : [ スマホ・3DS対応表示 | クラシック表示 ]
PukiWiki 1.4.7 Copyright © 2001-2006 PukiWiki Developers Team. License is GPL. Based on "PukiWiki" 1.3 by yu-ji
ページの処理時間 : 0.011 秒 | ログイン
Copyright(C) 2011-2014 プチコンまとめWiki ◆1sxkymI8ji30