プチコンまとめWiki (初代/mkII)

Toukou/NightSniper の変更点

パンくずリスト


#title(投稿プログラム : NightSniper)
#title(投稿プログラム : Night Sniper)
#contents
2013年05月13日投稿
/ 投稿者 : バイカウントメルビル
/ &tag(投稿プログラム,ゲーム,アクションゲーム,オリジナル曲,シンプル,QRコード,mkII専用);
/ 検索用→【メルビル】

** 概要 [#Summary]
夜の街で空から落ちてくる火の玉を避けたり撃ったりします

きっと鳥と豆とかにかなり影響されている

*** 操作・ゲームの目的 [#Komidashi1]
最終的にはただの避けゲーです~
火の玉が地面に落ちると地面が消滅して穴ができます~
穴に落ちたり、火の玉に当たるとゲームオーバーです

火の玉は撃つことができます。
ちなみに空中で火の玉に命中させると高得点が狙えます

- A ジャンプ
- B 撃つ
- 左右キー 移動

** スクリーンショットとQRコード [#ScreenShots]
|~スクリーンショット|~QRコード|
|&ref(SS2.png);|&ref(qr.png);|
SS撮影協力:天郷思音氏
SS撮影協力:天郷思音さん

** プログラムリスト [#List]
#region(195行)
#basic{{
GOSUB @CHRSET:GOSUB @BGMSET
@START
ACLS:CLEAR
FOR I=0 TO 4
 GFILL 0,144-POW(2.3,I+1),255,144-POW(2.3,I),242+I
NEXT
FOR I=0 TO 15
 GPSET RND(256),RND(128),4
NEXT
GPUTCHR 216,24,"BGU0U",5,11,1
GPUTCHR 208,32,"BGU0U",6,11,1
GPUTCHR 216,32,"BGU0U",7,11,1
FOR I=0 TO 63
 IF !RND(2) THEN BGPUT 1,I,17,45060:I=I+W
 IF !RND(5) THEN W=RND(3)+1:BGFILL 1,I,17,I-W,16-RND(3),45058:BGFILL 1,I,17,I-W,17,45059:I=I+W
NEXT
BGFILL 0,0,18,63,18,45057
SPSET 0,64,15,0,0,1
SPOFS 0,128,128
SPANIM 0,4,15
SPHOME 0,8,0
SPCOL 0,-3,-8,6,16,0
FOR I=0 TO 7
 SPSET I+1,248,15,0,0,1
 SPOFS I+1,128,32
 SPHOME I+1,8,8
 SPANIM I+1,3,10
 SPSCALE I+1,200-I*24
NEXT
BGMPLAY 128
SCORE=0:BSCORE=0
CF=1:F=1

@LOOP
GOSUB @PLAYER
GOSUB @ENEMY
IF PY/4 >= 64 THEN BGMPLAY 129:GOTO @GAMEOVER
SCORE=SCORE+1
VSYNC (BUTTON() AND 768)!=768
GOTO @LOOP

@PLAYER
IF MAINCNTL%32==TM THEN CLS
LOCATE 26-LEN(STR$(FLOOR(SCORE/6)+BSCORE)),23:?"SCORE "FLOOR(SCORE/6)+BSCORE;
B=BUTTON()
IF BMF THEN IF !SPCHK(10) THEN BMF=0:SPCLR 10
IF B AND 4 THEN BGX=(BGX+1023)%1024:F=0:IF CF THEN SPCHR 0,64,15,1,0,1
IF B AND 8 THEN BGX=(BGX+1)%1024:F=1:IF CF THEN SPCHR 0,64,15,0,0,1
BGREAD(0,FLOOR((BGX+125)/8)%64,18+FLOOR(PY/32)),C
BGREAD(0,FLOOR((BGX+131)/8)%64,18+FLOOR(PY/32)),D
ON !(C+D) OR JF OR DF GOSUB @STOP,@DOWN
IF PY>0 THEN DF=1
IF BUTTON(2) AND 32 THEN GOSUB @BEAM
BGOFS 0,BGX,0,1
BGOFS 1,BGX/2,0,1
SPOFS 0,128,128+PY/4,1
RETURN

@BEAM
SPSET 10,219,15,0,0,2
SPCOL 10,0,7,16,2,0
SPOFS 10,128,128+PY/4
SPOFS 10,F*272-16,128+PY/4,8
BEEP 7,8192
BMF=1
RETURN

@DOWN
PY=PY+PG
PG=PG+1
IF !(C+D) THEN JF=0
RETURN

@STOP
PG=0:PY=0
IF BUTTON(2) AND 16 THEN PG=-16:JF=1
RETURN

@ENEMY
EW=(EW+0.5)%360
EH=(EH+4)%360
FOR I=0 TO 7
 SPOFS I+1,128+SIN(RAD((EW-I*8+360)%360))*64,32+SIN(RAD((EH-I*32+360)%360))*16,1
NEXT
IF !BF AND RND(100)==0 THEN GOSUB @BOMBSET
IF BF THEN GOSUB @BOMB
IF BY>=136 THEN BGPUT 0,FLOOR(BX/8),18,0 IF !!E THEN BF=0:SPCLR 9:BY=0:BEEP 9
IF BY>=192 THEN BF=0:SPCLR 9
RETURN

@BOMB
BG=BG+1
BY=BY+BG/16
SPOFS 9,(BX-BGX+1020)%1024,BY,1
SPANIM 9,2,10
IF !DF AND SPHITSP(0,9) THEN DF=1:SPCHR 0,88:BEEP 14:CF=0
IF BMF THEN IF SPHITSP(10,9) THEN GOSUB @HIT
RETURN

@HIT
SPREAD(9),X,Y
SPCLR 9:SPCLR 10
BF=0:BMF=0
BEEP 60
PBS=200+!(C+D)*300
BSCORE=BSCORE+PBS
LOCATE X/8,Y/8:?PBS
TM=MAINCNTL%32
RETURN

@BOMBSET
SPSET 9,42,2,0,0,2
SPCOL 9,5,5,6,6,0
BX=FLOOR((128+SIN(RAD(EW))*64+BGX)/8)*8
BY=40+SIN(RAD(EH))*16
SPOFS 9,BX-BGX-4,BY
BG=0:BF=1
BGREAD(0,FLOOR(BX/8),18),E
RETURN

@GAMEOVER
FOR I=0 TO 1:I=!BGMCHK():NEXT
FOR I=0 TO 1:I=BUTTON(2):NEXT
GOTO @START

@CHRSET
FOR I=1 TO 7
 READ C$
 CHRSET "BGU0U",I,C$
NEXT
RETURN

@BGMSET
FOR I=0 TO 120 STEP 8
 P$=P$+HEX$(I,2)
NEXT
FOR I=120 TO -128 STEP -8
 P$=P$+HEX$(I,2)
NEXT
FOR I=-128 TO -8 STEP 8
 P$=P$+HEX$(I,2)
NEXT
BGMPRG 224,127,127,127,127,P$
BGMSETD 128,@MML
BGMSET 129,"T96:0@11L12<<DC+>B<C+6>AD6EA6:1@11DE>A."
RETURN

DATA "6666666465545441654544416454444165444441644444416444444141211111"
DATA "111111111DD11DD11111111111111DD1111111111DD111111111111111111111"
DATA "111111111DD11DD11111111121211DD1121212122DD121222222222222222222"
DATA "0022200002DDD000020000000200000002000000020000000200000002000000"
DATA "9990000000998000000998000000998000009980000099980000999800009998"
DATA "9000000090000000990000000990000008999999008999990008899900000888"
DATA "0009999800099998009999989999998099999980999998009998800088800000"

@MML
DATA "T120"
DATA ":0@144L12@V64"
DATA "[A6AA6<C+DC+>B<C+6>A"
DATA "BAG+A6ED6EC+4"
DATA "F+F+G+A6E<DC+>BA6E"
DATA "<DC+>B<C+6>AD6EA6E"
DATA "@V64A6AA6<C+DC+>B<C+6>A"
DATA "BAG+A6ED6EC+4"
DATA "F+F+G+A6E<DC+>BA6E"
DATA "<F+EDE6C+>F+6G+A4"
DATA "@224@V127A6AA6<C+DC+>B<C+6>A"
DATA "BAG+A6ED6EC+4"
DATA "F+F+G+A6E<DC+>BA6E"
DATA "<DC+>B<C+6>AD6EA4"
DATA "@144@V48A6AA6<C+DC+>B<C+6>A"
DATA "BAG+A6ED6EC+4"
DATA "F+F+G+A6E<DC+>BA6E"
DATA "<F+EDE6C+>F+6G+A4"
DATA "@224@V127"
DATA "[F+4F+4F+6EC+DE"
DATA "A4E4A6EC+E<C+"
DATA "D4D4>E6>B<EF+G+"
DATA "A6A<DC+>BA2]2]"

DATA ":1@145L12O3@V48"
DATA "[[R1R1R1R1"
DATA "A6AA6<C+DC+>B<C+6>A"
DATA "BAG+A6ED6EC+4"
DATA "F+F+G+A6E<DC+>BA6A"
DATA "<DC+>B<C+6>AD6EA4]2"
DATA "R1R1R1R1"
DATA "@224@V127O5"
DATA "E2.&EDC+>B4A2E4"
DATA "<D2E4&EDC+>BAB<DC+>BA2]"

DATA ":3@147O3@V64"
DATA "[[A1D2.E4F+2E2D4E4>A2]4"
DATA "[<D1>A1<F+2E2D4E4A4>A4]2]"
DATA 0
}}
#endregion

** CHECKER FLAG (ひとことコメント) [#Comments]
この作品に対するコメントがあれば一言どうぞ。(作品に直接関係ない質問や雑談は[[掲示板>Board]]へ)
- ''田中(天才)'' : Let's shoot! (&new{2013/05/13 (月) 23:20:56};)
- ''Citrine'' : メル曲001だー (&new{2013/05/13 (月) 23:25:42};)
- ''くぉくぉくぉ'' : 久しぶりの投稿だな (&new{2013/05/14 (火) 13:29:57};)
- ''名無しさん'' : 作曲のコツを教えてください (&new{2013/05/14 (火) 14:55:23};)
- ''メルビル'' : 三毛さんも言ってましたが、ゲームの音量を消して、「自分だったらこんな曲をつけるなー」って考えればいいトレーニングになりそうです (&new{2013/05/14 (火) 18:32:04};)
- ''名無しさん'' : http://www.geocities.jp/melville515/petitcom/petitcom こちらには載っていないようですぜ (&new{2013/09/04 (水) 19:51:28};)
- ''名無しさん'' : スタートボタンとかでポーズとかできたら良いのになー (&new{2013/09/04 (水) 19:53:43};)
- ''名無しさん'' : 1031点取れたー (&new{2013/09/05 (木) 02:17:44};)
- ''名無しさん'' : 8635点取れた (&new{2013/09/05 (木) 02:50:26};)

#comment

表示モード : [ スマホ・3DS対応表示 | クラシック表示 ]
PukiWiki 1.4.7 Copyright © 2001-2006 PukiWiki Developers Team. License is GPL. Based on "PukiWiki" 1.3 by yu-ji
ページの処理時間 : 0.006 秒 | ログイン
Copyright(C) 2011-2014 プチコンまとめWiki ◆1sxkymI8ji30