プチコンまとめWiki (初代/mkII)

Toukou/COMMAND PROMPT の変更点

パンくずリスト


#title(投稿プログラム : コマンドプロンプト)
#contents

2013年7月12日投稿
/ 投稿者 : いったん
/ &tag(投稿プログラム,ツール,ランチャ,QRコード,mkII専用);

* 概要 [#Summary]
最近ランチャブームですね。~
そこで、何番煎じなんだという気はしますが、コマンドプロンプト作ってみました。~
結構いろいろな機能が詰まっている気がします。多分。~

** バグ情報 [#buginfo]
バグ等あれば下のコメント欄にお願いします。

** 機能説明 [#Kinou]
起動するとカーソルが出てくるのでコマンドを入力します。わからない時はまず
 HELP
と打ってみましょう。~
コマンド入力についてですが、LINPUT命令中はボタンなどを受け付けてもらえない((あたりまえだ!!))のでLINPUT命令の代用を入力ルーチンでまかなっています。~
上下のボタンで前に入力したコマンドを参照できます。~
また、TABキーによる入力補完ができます。~

** コマンド説明 [#COMMAND]
コマンドに引数を指定する場合は「HELP /S」のように間に空白を挟んで使用します。~
文字列をダブルクオーテーションで囲む必要はありません。~
場合によっては引数を正しく指定しないとエラーになる事があります。

#region(一覧と説明)
&color(purple,white){''RUN''};
-----
 RUN FILENAME
で他のプログラムを直接実行(EXEC)します。
/Lを追加するとプログラム内のラベルにジャンブします。

&color(purple,white){''LOAD''};
-----
 LOAD XXX:FILENAME
でキャラなどのファイルを読み込みます。
グラフィックなどの表示はできません。

&color(purple,white){''EXIT''};
-----
コマンドプロンプト終了します。

&color(purple,white){''HELP''};
-----
現在登録されているコマンド一覧を表示します。~
/Sでコマンド名だけを表示します。

&color(purple,white){''VER''};
-----
コマンドプロンプトとプチコンのバージョンを表示します。

&color(purple,white){''TIME''};
-----
現在の日付時刻を表示します。

&color(purple,white){''HISTORY''};
-----
過去に入力したコマンドを表示します。~
一画面に入りきらない場合は画面送りで表示します。

&color(purple,white){''CLS''};
-----
画面を消去します。

&color(purple,white){''MAN''};
-----
マニュアル(という名の操作方法)を表示します。

&color(purple,white){''RENAME''};
-----
 RENAME XXX:OLDNAME NEWNAME
でプチコン内のファイルの名前を変更します

&color(purple,white){''DELETE''};
-----
 DELETE XXX:FILENAME
でプチコン内のファイルを削除します。

&color(purple,white){''MAINCNT''};
-----
起動時間を表示します。145分以上の情報も表示されます。

&color(purple,white){''COLOR''};
-----
 COLOR 文字色 背景色
で文字色、背景色を指定します。~
/RGBを追加すると16進のHTMLカラーコードで指定することができます。

&color(purple,white){''TYPE''};
-----
 TYPE FILENAME
でMEMファイルを読み込み、表示します。

&color(purple,white){''BACKCMD''};
-----
バックグラウンドで起動中のコマンド一覧を表示します。

&color(purple,white){''ALARM''};
-----
 ALARM HH:MM:SS BGMNO.
で指定時間に音楽を鳴らします。アラーム起動中はバックグラウンドで待機します。

&color(purple,white){''CLOCK''};
-----
右上の時計の表示・非表示を変更します。

&color(purple,white){''FPSCHK''};
-----
バックグラウンドすべてのプログラムのFPSを表示します。

#endregion

** コマンド作成 [#t58ba39c]
コマンドを作成する場合は@CMDDATAにコマンド、ラベル、説明をデータ文で書き込み、その後ラベルを作成してください。サブルーチン扱いなので戻る時はRETURNとしてください。~
バックグラウンドで起動させるには、BACKCMDSTを呼び出します。その場合@コマンド名+BKというラベルが呼び出されます。また、停止させるときには変数INOにコマンド番号を入れ、BACKCMDEDを呼び出してください。~
まあ、リスト見ればわかると思います。
/////////////////////////////////
* スクリーンショット [#screenshots]
&ref(SCR_GRP2.png);
* QR コード [#QR]
プチコンmkII 向けの QR コードです。

// 【重要】旧プチコンから mkII に転送したプログラムは、mkII で保存しなおしてから
// QR コード化すると、枚数が半分ぐらいに減ります。ぜひお試し下さい。
// 【重要】添付できるのは画像ファイルのみです。zip ファイルは解凍してください。

// ページを作成すると、QR コードの添付ができるようになります。(作成する前はできません)
// 作成後のページの右上、ウィキメニューにある「添付」から画像をアップロードできます。
// (添付ファイルはページごとに別個に管理されています。必ず作成後のページに添付してください)
// QR コードをアップロードしたら、以下の書式でページ内に貼り付けられます。
// #ref(アップロードしたファイル名)

// QR コードを大きくしたい場合は、倍率指定ができます。コンマは必ず 2 つ指定してください。
// ブラウザによっては補完がかかってボケますが、それでも問題なく読み込み可能です。
// #ref(アップロードしたファイル名,,200%)

// 複数の QR コードを貼り付けるために表組みを用いる場合、&ref(); を使用します。
// (#ref() を表に埋め込んでしまうと、古い Internet Explorer でうまく表示されません)
|>|~PRG:ITNCMD|
|&ref(qr000.png);|&ref(qr001.png);|
|&ref(qr002.png);|&ref(qr003.png);|

/////////////////////////////////

* プログラムリスト [#List]
なんでこんなに長くなったんだ・・・
#region(プログラムリスト)
#basic{{
'コマント゛ フ゜ロンフ゜ト v1.0
'Programmed by Ittan
'ムタ゛ンシヨウ,カイソ゛ウ→シ゛ユウ
'   (テ゛キレハ゛レンラクシテクタ゛サイ。)
'サイハイフ→キンシ
'シ゛フ゛ンノPRGニクミコムノハOK。
'シヨウヘンスウ(システム、メインコマント゛ノミ。)
'KY$:KYS$(10):KYSNO:STK$
'IN$:IN2$:I
'BT:NOWKEY$
'C0$:C1$:C2$:CLOG:CY
'CMNO:CMDNM:CMMAX
'CMDLIST$(128,3)
'CMDLOG$(128)
'CSX CSY
'BCMD(128)
'BCN
'HELPS
'CMDLOGL:CMDNO:KYB:VER$
'TABC:TABNO
'FOUND:SPNO
'CHK$:NCO

@CMD コマント゛ フ゜ロンフ゜トノ ショキセッテイ
VISIBLE 1,1,0,0,1,0
COLOR 0:CLS:CLEAR
SPPAGE 0
SPCLR
PNLTYPE "KYA"

DIM KYS$(10)
DIM CMDLIST$(128,3)
DIM CMDLOG$(128)
DIM BCMD(128)
SPNO=0'スフ゜ライト シヨウハ゛ンコ゛ウ

CHRREAD("SPS1",176),C$
CHRSET "SPU0",0,C$
CHRSET "SPU0",4,"0"*64

SPSET SPNO,0,0,0,0,0,8,8
SPOFS SPNO,0,-16
SPANIM SPNO,2,31

FOR I=0 TO 4
 BREPEAT I,30,4
NEXT
BREPEAT 7,30,4

@CMDDATA
'----メインコマント゛
'    コマント゛ ラヘ゛ル   セツメイ
DATA"RUN","RUN00","8モシ゛ノエイスウシ゛ヲイレ、PRGシ゛ッコウ。 /L テ゛ ラヘ゛ルシ゛ャンフ゜。"
DATA"LOAD","LOADC","RSC:FILENAME テ゛ キャラクタナト゛ノ ヨミコミヲ シマス。"
DATA"EXIT","EXIT","CMDヲ シュウリョウシマス。"
DATA"HELP","HELP","コマント゛ノ イチラント セツメイヲ ヒョウシ゛シマス。/Sテ゛ナマエタ゛ケ ヒョウシ゛シマス。"
DATA"VER","PUTVER","CMD,フ゜チコンノハ゛-シ゛ョンヲヒョウシ゛シマス。"
DATA"TIME","TIME","イマノシ゛カンヲ ヒョウシ゛シマス。"
DATA"HISTORY","HISTORY","ニュウリョクシタ コマント゛イチランヲ ヒョウシ゛シマス。"
DATA"CLS","CLRS","スクリ-ンヲ ショウキョシマス
DATA"MAN","MAN","マニュアルヲ ヒョウシ゛ シマス。"
'----
DATA"RENAME","RENAME","RSC:OLDNAME NEWNAMEテ゛ ファイルメイヲ ヘンコウシマス。"
DATA"DELETE","DELETE","RSC:NAME テ゛ ファイルヲ サクシ゛ョシマス。"
DATA"MAINCNT","MAINCNT","キト゛ウシ゛カンヲ ヒョウシ゛シマス。"
DATA"COLOR","COLOR","[モシ゛ショク] [ハイケイショク] テ゛コンソ-ルノ イロヲ シテイ シマス。/RGB ヲシテイスルト RRGGBBテ゛ イロヲ ニュウリョクシマス。
DATA"TYPE","TYPE","[FILENAE] テ゛MEMファイルノ ナイヨウヲ ヒョウシ゛ シマス。"
DATA"BACKCMD","BACKCMD","ハ゛ックク゛ラウント゛ テ゛ キト゛ウチュウノ コマント゛ノ イチランヲ ヒョウシ゛ シマス。"
'----シ゛ョウチュウカ゛タ コマント゛
DATA"ALARM","ALARM","[HH:MM:SS] [M NO.]シテイシ゛カンニ オンカ゛クヲ ナラシマス。"
DATA"CLOCK","CLOCK","ミキ゛ウエニ トケイヲ ヒョウシ゛シマス。"
DATA"FPSCHK","FPSCHK","ショリカイスウ/1mヲ ヒョウシ゛シマス。
DATA"","",""
RESTORE @CMDDATA

VER$="1.0"
'コマント゛ ヨミコミ
FOR I=0 TO 1 STEP 0
 READ C0$,C1$,C2$
 IF C0$=="" THEN I=2:CMMAX=CMNO
 CMDLIST$(CMNO,0)=C0$
 CMDLIST$(CMNO,1)=C1$
 CMDLIST$(CMNO,2)=C2$
 CMNO=CMNO+1-(CMNO==127)
NEXT
'ショキメ-ッセ-シ゛
GOSUB @PUT00


'メインル-チン
@CMDMAIN
?">";
IN$=""
CMDNM=CMDLOGL
FOR I=0 TO 1:I=INKEY$()==""NEXT
CSX=1:CSY=CSRY
GOSUB @INPUT
IF IN$=="" THEN GOTO@CMDMAIN
SPOFS SPNO,0,-8
GOSUB @LOGPUT
GOSUB @GETKEY
CMD=-1
FOUND=FALSE
FOR I=0 TO CMMAX-1
 IF KY$==CMDLIST$(I,0) THEN GOSUB @JUMPCMD
NEXT
IF FOUND THEN GOTO@CMDMAIN
IF KY$=="" THEN GOTO@CMDMAIN
?CHR$(34)+KY$+CHR$(34);" is not found."
BEEP 2
GOTO @CMDMAIN

'コマント゛シ゛ャンフ゜
@JUMPCMD
GOSUB "@"+CMDLIST$(I,1)
I=CMMAX
FOUND=TRUE
RETURN

'キ-ニュウリョク
@INPUT
'カ-ソル
SPOFS SPNO,CSRX*8,CSRY*8
I$=INKEY$()
BT=BTRIG()
KYB=KEYBOARD
VSYNC 1
IF I$==CHR$(13) THEN ?:RETURN
IF BT AND 3 THEN GOSUB @LOGREAD
IF BT AND 4 THEN CSX=CSX-1+(CSX==1)
IF BT AND 8 THEN CSX=CSX+1-(CSX==LEN(IN$)+1)
IF BT AND 16 THEN ?:RETURN
IF KYB==15 OR !!(BT AND 128) THEN GOSUB @BACKSPACE
IF KYB==32 THEN GOSUB @TAB
IN$=MID$(IN$,0,CSX-1)+I$+MID$(IN$,CSX-1,LEN(IN$)-(CSX-1))
LOCATE 0,CSY:?">"+LEFT$(IN$+CHR$(0)*32,30);
LOCATE 1,CSY:?IN$;
IF I$!="" THEN CSX=CSX+1
LOCATE CSX,CSY+CSX/32
GOSUB @BCKCMD
GOTO@INPUT

'ハ゛ックク゛ラウント゛
@BCKCMD
FOR BKC=0 TO BCN-1
GOSUB "@"+CMDLIST$(BCMD(BKC),1)+"BK"
NEXT
RETURN

@BACKCMDST
BCMD(BCN)=I
BCN=BCN+1
RETURN

@BACKCMDED
FOR II=0 TO BCN-1
 IF INO==BCMD(II) THEN INO=-1:BCMD(I)=BCMD(II+1)
 IF INO<0 THEN BCMD(II)=BCMD(II+1)
NEXT
IF INO<0 THEN BCN=BCN-1
RETURN

'ニュウリョクホカン
@TAB
I$=""
FOR I=0 TO 1:I=INKEY$()==""
NEXT
TABC=0
FOR I=0 TO CMMAX-1
 IF LEFT$(CMDLIST$(I,0),LEN(IN$))==IN$ THEN TABC=TABC+1:TABNO=I
NEXT
IF TABC==1 THEN IN$=CMDLIST$(TABNO,0)
CSX=LEN(IN$)+1
RETURN

'ハ゛ックスヘ゜-ス
@BACKSPACE
IF IN$=="" OR CSX==1 THEN RETURN
CSX=CSX-1+(IN$=="")
IN$=MID$(IN$,0,CSX-1)+MID$(IN$,CSX,LEN(IN$)-CSX+1)
RETURN
'ロク゛ ヨヒ゛タ゛シ
@LOGREAD
IF CMDNM==CMDLOGL THEN NOWKEY$=IN$
IF BT AND 1 THEN CMDNM=CMDNM-1 AND 1023
IF BT AND 2 THEN CMDNM=CMDNM+1 AND 1023
IN$=MID$(CMDLOG$(CMDNM/8),32*FLOOR(CMDNM%8),32)
IF CMDNM==CMDLOGL THEN IN$=NOWKEY$
FOR I=0 TO 31
IF MID$(IN$,I,1)==CHR$(0) THEN IN$=LEFT$(IN$,I):I=64
NEXT
CSX=LEN(IN$)+1
RETURN

'ロク゛ニ コマント゛ヲ キロク
@LOGPUT
IN2$=LEFT$(IN$+CHR$(0)*32,32)
CMDLOG$(CMDLOGL/8)=CMDLOG$(CMDLOGL/8)+IN2$
CMDLOGL=CMDLOGL+1
RETURN

'キ-ヲ サカ゛ス
@GETKEY
KYSNO=-1
KY$=""
FOR I=0 TO 9:KYS$(I)="":NEXT
FOR I=0 TO LEN(IN$)
STK$=MID$(IN$,I,1)
IF STK$==" " THEN STK$="":KYSNO=KYSNO+1
IF KYSNO==-1 THEN KY$=KY$+STK$
IF KYSNO>-1 THEN KYS$(KYSNO)=KYS$(KYSNO)+STK$
NEXT
RETURN

@PUT00
?"COMMAND PROMPT v"VER$
?"Programmed by Ittan
?"
RETURN

@TIME
?DATE$
?TIME$
RETURN

@HELP
CY=2+FLOOR(LEN(CMDLIST$(0,2))/32)+1
HELPS=FALSE
IF KYS$(0)=="/S" THEN HELPS=TRUE:CY=1
FOR I=0 TO CMMAX-1
 FOR J=1 TO !HELPS
 COLOR 4
 ?CMDLIST$(I,0)
 COLOR NCO
 ?CMDLIST$(I,2)
 ?
 CY=CY+2+FLOOR(LEN(CMDLIST$(I+1 AND 127,2))/32)+1
 IF CY>=21 THEN GOSUB @HELPLOOP
 VSYNC 1
 NEXT J
 FOR J=1 TO HELPS
 COLOR NCO
 ?CMDLIST$(I,0)
 CY=CY+1
 IF CY>=22 THEN GOSUB @HELPLOOP
 VSYNC 1
 NEXT J
NEXT
RETURN
@HELPLOOP
?"Press enter key";
CY=2+FLOOR(LEN(CMDLIST$(I+1 AND 127,2))/32)+1
@HELPLOOP2
IF KEYBOARD==60 OR BTRIG()==16 THEN CY=0:?:?:RETURN
GOTO @HELPLOOP2

@RUN00
IF KYS$(0)=="" THEN BEEP 2:?"ファイルメイヲ シテイシテ クタ゛サイ。":RETURN
?"RUN:"KYS$(0)
WAIT 20
IF KYS$(1)=="/L" THEN GOTO"@"+KYS$(0)
CHK$=KYS$(0)
GOSUB @CHKNAME
IF CHKRS==FALSE THEN BEEP 2:?"ファイルメイカ゛ タタ゛シク アリマセン。":RETURN
EXEC KYS$(0)
RETURN

@LOADC
IF KYS$(0)=="" THEN BEEP 2:?"ファイルメイヲ シテイシテ クタ゛サイ。":RETURN
CHK$=KYS$(0)
GOSUB @CHKNAME
IF CHKRS==FALSE THEN BEEP 2:?"ファイルメイカ゛ タタ゛シク アリマセン。":RETURN
?"LOAD:"KYS$(0)
WAIT 20
LOAD KYS$(0),0
RETURN

@PUTVER
?
?"CMD v"VER$
?"Programmed by Ittan
?
?"Petit Computer v"HEX$(VERSION)
?"Developed by SmileBoom
?
RETURN

@HISTORY
FOR I=0 TO CMDLOGL-2
?MID$(CMDLOG$(I/8),I%8*32,32);
IF I%23==0 AND I!=0 THEN GOSUB @HISLOOP
NEXT
RETURN
@HISLOOP
?"Press enter key";
@HISLOOP2
IF KEYBOARD==60 OR BTRIG()==16 THEN CY=0:?:WAIT 1:RETURN
GOTO @HISLOOP2

@EXIT
ACLS
CHRINIT"SPU0"
FOR I=0 TO 11
BREPEAT I,0,0
NEXT
CLEAR
END

@MAN
?
?"COMMAND PROMPT v"VER$
?"
?"ツカイカタ"
?" ↑↓:マエノ コマント゛ヲ サンショウシマス。
?"TAB:ニュウリョクホカン ヲ シマス。
?"  Y:ハ゛ックスヘ゜-スキ-ニ ナリマス。
?"  A:エンタ-キ-ニ ナリマス。
?"ヒント
?"・コマント゛ イチランハ HELPテ゛ カクニンテ゛キマス。
?"・シ゛ョウチュウカ゛タ コマント゛ハ ハ゛ク゛カ゛ オオイ。
?"・ファイルカンケイノ エラ-ハ、アナタノ ウチマチカ゛イテ゛ス。";
RETURN

@CLRS
CLS
RETURN

@MAINCNT
MC=FLOOR(MAINCNTL%60*100/60)
MS=FLOOR(MAINCNTL/60)%60
MMH=FLOOR(MAINCNTL/3600)+MAINCNTH*145
MM=MMH%60
MH=FLOOR(MMH/60)%60
?RIGHT$("  0"+STR$(MH),3);":";
?RIGHT$("00"+STR$(MM),2);":";
?RIGHT$("00"+STR$(MS),2);".";
?RIGHT$("00"+STR$(MC),2)
RETURN

@CHKNAME
CHKRS=TRUE
FOR I=0 TO LEN(CHK$)-1
C$=MID$(CHK$,I,1)
IF !((C$>="0" AND C$<="9") OR (C$>="A" AND C$<="Z") OR C$==":" OR C$=="_") THEN CHKRS=FALSE
IF C$==":" AND I<3 I>5 THEN CHKRS=FALSE
NEXT
RETURN

@RENAME
IF KYS$(0)=="" OR KYS$(1)=="" THEN BEEP 2:?"ファイルメイヲ シテイシテ クタ゛サイ。":RETURN
CHK$=KYS$(0)
GOSUB @CHKNAME
IF CHKRS==FALSE THEN BEEP 2:?"ファイルメイカ゛ タタ゛シク アリマセン。":RETURN
CHK$=KYS$(1)
GOSUB @CHKNAME
IF CHKRS==FALSE THEN BEEP 2:?"ファイルメイカ゛ タタ゛シク アリマセン。":RETURN
RENAME KYS$(0),KYS$(1)
RETURN

@DELETE
IF KYS$(0)=="" THEN BEEP 2:?"ファイルメイヲ シテイシテ クタ゛サイ。":RETURN
CHK$=KYS$(0)
GOSUB @CHKNAME
IF CHKRS==FALSE THEN BEEP 2:?"ファイルメイカ゛ タタ゛シク アリマセン。":RETURN
DELETE KYS$(0)
RETURN

@COLOR
IF KYS$(2)=="/RGB" THEN @COLOR2
COLOR VAL(KYS$(0)),VAL(KYS$(1))
NCO=VAL(KYS$(0))
RETURN
@COLOR2
COLSET "BG",47,KYS$(0)
COLSET "BG",63,KYS$(1)
COLOR 2,3
NCO=2
RETURN

@BACKCMD
FOR I=0 TO BCN-1
?CMDLIST$(BCMD(I),0)
NEXT
IF BCN==0 THEN ?"ハ゛ックク゛ラウント゛ テ゛ キト゛ウチュウノ コマント゛ハ アリマセン。"
RETURN

@TYPE
IF KYS$(0)=="" THEN BEEP 2:?"ファイルメイヲ シテイシテ クタ゛サイ。":RETURN
CHK$=KYS$(0)
GOSUB @CHKNAME
IF CHKRS==FALSE THEN BEEP 2:?"ファイルメイカ゛ タタ゛シク アリマセン。":RETURN
LOAD"MEM:"+KYS$(0),0
?MEM$
RETURN

@ALARM
INO=I
IF KYS$(0)=="" THEN @ALARMRS
GOSUB @BACKCMDST
ALMT$=KYS$(0)
ALMM=VAL(KYS$(1))
ALBP=FALSE
AMH=VAL(MID$(ALMT$,0,2))
AMM=VAL(MID$(ALMT$,3,2))
AMS=VAL(MID$(ALMT$,6,2))
?AMH":"AMM":"AMS"ニ アラ-ム(BGM"ALMM")ヲセットシマシタ。
RETURN

@ALARMRS
BGMSTOP
GOSUB @BACKCMDED
?
?"アラ-ムヲ テイシ シマシタ。"
LOCATE CSX,CSY+2
CSY=CSRY
RETURN

@ALARMBK
TMREAD(TIME$),TH,TM,TS
FOR _IF=1 TO TH==AMH AND TM==AMM AND TS==AMS AND ALBP==FALSE
 BGMPLAY ALMM
 ALBP=TRUE
 ?
 ?"アラ-ム:セットシタ シ゛カンニ ナリマシタ。ナニカ オスト トマリマス。"
 LOCATE CSX,CSY+3
 CSY=CSRY
NEXT _IF
IF ALBP==FALSE THEN RETURN
IF KYB OR BT THEN INO=BCMD(BKC):GOTO @ALARMRS
RETURN

@CLOCK
CLOCKVS=!CLOCKVS
IF CLOCKVS==TRUE THEN ?"トケイヲ ヒョウシ゛シマス。":GOSUB @BACKCMDST:RETURN
INO=I
GOSUB @BACKCMDED
?"トケイヲ ヒヒョウシ゛ニ シマス。"
CY=CSRY
CX=CSRX
LOCATE 24,0:?CHR$(0)*8;
LOCATE CX,CY
RETURN

@CLOCKBK
IF !CLOCKVS THEN RETURN
CY=CSRY
CX=CSRX
IF CY==0 THEN CY=CY+1:CSY=CSY+1
LOCATE 24,0:?TIME$;
LOCATE CX,CY
RETURN

@FPSCHK
FPSCHKVS=!FPSCHKVS
IF FPSCHKVS THEN GOSUB @BACKCMDST:?"FPSヲ ヒョウシ゛シマス。":RETURN
INO=I
GOSUB @BACKCMDED
?"FPSヲ ヒヒョウシ゛ニ シマス。"
CY=CSRY
CX=CSRX
LOCATE 24,1:?CHR$(0)*8;
LOCATE CX,CY
RETURN

@FPSCHKBK
FPSCT=FPSCT+1
CY=CSRY
CX=CSRX
IF CY==1 THEN CY=CY+1:CSY=CSY+1
IF OFPSTM+60>MAINCNTL THEN RETURN
LOCATE 24,1:?FPSCT;"FPS";
LOCATE CX,CY
FPSCT=0
OFPSTM=MAINCNTL
RETURN
'----------------------------

}}
#endregion
/////////////////////////////////
// コメントを募集したくないなら、ここから下は削除してください

* CHECKER FLAG (ひとことコメント) [#Comments]
この作品に対するコメントがあれば一言どうぞ。(作品に直接関係ない質問や雑談は[[掲示板>Board]]へ)
- ''名無しさん'' : EXITとか終了する命令あった方がいいんじゃね? (&new{2013/07/13 (土) 00:05:50};)
- ''いったん'' : ↑ありますよ? (&new{2013/07/13 (土) 00:14:12};)
- ''名無しさん'' : 作っていたけど先を越されてしまいました。敵ながらあっぱれ! (&new{2013/07/15 (月) 21:52:04};)
- ''ありふれた'' : いったんさん、あなたの、プログラムが、OKOSで、使われて、いました。 (&new{2013/07/23 (火) 08:42:15};)
- ''12さいくん'' : すごい!!!!開発中のOSに組み込みたいくらいだ... (&new{2013/07/23 (火) 11:16:16};)
- ''名無しさん'' : よしGUIつけようぜ (&new{2013/07/23 (火) 18:59:30};)
- ''名無しさん'' : わりとガチで気に入った。 (&new{2013/07/23 (火) 19:28:53};)
- ''いったん'' : ↑4 無断使用・改造は自由と言っているので別に構わないです。むしろ使われて嬉しいくらいです。 (&new{2013/07/24 (水) 18:18:50};)
- ''かず'' : しくみを使います。 (&new{2013/07/26 (金) 12:34:26};)
- ''かず'' : というよりか、RUN→入力ルーチン→ENDのプログラムを作っては頂けませんか? (&new{2013/07/26 (金) 12:40:11};)
- ''名無しさん'' : 無断使用・改造は自由なので自分で改造してみたらどうでしょうか使用してるみたいですし (&new{2013/07/26 (金) 14:23:23};)
- ''いったん'' : ↑2入力ルーチンってことはlinputの代用ルーチンを作ればいいってことですか? (&new{2013/07/26 (金) 16:10:19};)
- ''名無しさん'' : ↑3 &basic(){FOR I=0 TO 1I=KEYBORD==60 GOSUB@};入力ルーチン&basic(){:NEXT};でエンターが押されるまで繰り返して、押されたらやめるというのだったらできる (&new{2013/08/13 (火) 12:24:29};)
- ''名無しさん'' : &basic(){I=KEYBORD==60};を&basic(){I=(KEYBORD==60AND BUTTON(2)==16)};にかえることで、Aボタンが押されるまでという動作を付け加えられるので、自力で頑張って下さい。(&new{2013/08/13 (火) 12:26:26};)
- ''ぷちぷち'' : 制作中のOSに使います。 (&new{2014/01/05 (日) 09:41:54};)
- ''jdcogu'' : aNzECnaCqJc (&new{2018/04/11 (水) 02:55:03};)
- ''hsisfs'' : KHHNkdeuq (&new{2018/04/11 (水) 12:00:21};)
- ''H'' : hhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhh (&new{2019/12/14 (土) 20:19:36};)

#comment

表示モード : [ スマホ・3DS対応表示 | クラシック表示 ]
PukiWiki 1.4.7 Copyright © 2001-2006 PukiWiki Developers Team. License is GPL. Based on "PukiWiki" 1.3 by yu-ji
ページの処理時間 : 0.023 秒 | ログイン
Copyright(C) 2011-2014 プチコンまとめWiki ◆1sxkymI8ji30