プチコンまとめWiki (初代/mkII)

Toukou/ローマ字ワープロ の変更点

パンくずリスト


#title(投稿プログラム:ローマ字ワープロ)
#contents
2012年9月1日投稿
/ 投稿者:わぁぃ@
/ &tag(投稿プログラム,実用ツール,QRコード,mkII専用);~

*概要 [#m6b7d14d]
簡易的なワープロです。
-ローマ字入力ができます。
-ひらがなとカタカナの混在表示ができます。
--[[「PETIKANA」>Toukou/かなフォントPETIKANA]]フォントのCHRファイルを&basic{"PETIKANA"};というファイル名で保存しておいて下さい。
--また、&basic{"PRG:PETIKANA"};より&basic{@PKN};ルーチンをお借りしています。
-MEMリソースやGRPリソースを用いてテキストの読み書きができます。

*注意 [#w0ace5e4]
このプログラムはv0.7です。~
-小さい「ゃ」「ゅ」「ょ」は打てません。
-小文字は打てません。
-一度改行すると前の行に戻れません。

*不具合、更新情報 [#x17670d5]
-「YA」が「も」に変換される。(&new{2012/09/03 (月) 19:39:10};)
--72行目の&basic{AS>35};を&basic{AS>36};にすると直るようです。(&new{2012/09/03 (月) 19:39:10};)
--簡単に修正できるので、修正版は出しません。(&new{2012/09/03 (月) 19:39:10};)

#BASIC(start=72){{
IF AS>3<COLOR>(#e00){6} THEN AS=AS-1
}}

*操作方法 [#aeb738a4]
入力以外の操作はシステムアイコンで行います。
-「ABC」を押すたび、「直接」→「ローマ字カタカナ」→「ローマ字ひらがな」の順に入力モードを切り替わります。
-ページを切り替え、以下の組み合わせで押すとMEMリソースやGRPリソースに読み書きができます。
|~\|~MEM|~GRP|
|~↑|MEM&br;読み込み|GRP&br;読み込み|
|~↓|MEM&br;書き込み|GRP&br;書き込み|

*QRコード [#w93bab2d]
プチコンmkII向けのQRコードです。
|>|~PRG:WAROME|
|~1/2|~2/2|
|&ref(PRG-WAROME-QR0.png,,200%);|&ref(PRG-WAROME-QR1.png,,200%);|
-補正がかかって読み込めない場合は、画像をクリックすると等倍サイズのQRコードがご覧になれますのでぜひご利用ください。

*プログラムリスト [#programlist]
#basic{{
'ローマジワープロ v0.7

VISIBLE 1,1,0,0,0,0
CLS:COLOR 0
CLEAR
LOAD "BGF:PETIKANA",0
ICONCLR:ICONPUSE=1
ICONPAGE=0
ICONSET 0,35
DIM AX$(8,3)
DATA "A","I","U","E","O"
DATA "K","S","T","N","H"
DATA "M","Y","R"
DATA "G","Z","D","","B"
DATA "P"
DATA 44,"WA",-10,"WO"
DATA 45,"NN"
FOR I=0 TO 4
READ AY$(I)
NEXT
FOR I=0 TO 7
READ AX$(I,0)
NEXT
FOR I=0 TO 4
READ AX$(I,1)
NEXT
READ AX$(0,2)
FOR I=0 TO 2
READ RAS(I),RAK$(I)
NEXT

@LOOP
VSYNC 1
OIP=IP:IP=ICONPAGE
IF OIP!=IP THEN ICONCLR:ON IP GOSUB @MENU1,@MENU2
IK$=INKEY$():IL=IK$!=""
IF IK$!="" THEN IK=ASC(IK$)
IF KEYBOARD==15 THEN LOCATE CSRX-1,CSRY:PRINT CHR$(0);:LOCATE CSRX-1,CSRY
IF IK$==CHR$(13) THEN PRINT CHR$(13):IW$="":IK$=""
IF ICONPAGE THEN GOSUB @FILEMENU ELSE IF !ICONCHK() THEN BEEP 9:MD=(MD+1)%3:IW$="":IK$="":WAIT 2
IF !IL THEN @LOOP
IF !MD THEN PRINT IK$;:GOTO @LOOP
'-(マイナス)ハ -(チョウオン)ニ ヘンカン
IF IK$=="-" THEN IK$="-"
IF IK>64 AND IK<91 THEN GOSUB @ROME ELSE PRINT IK$;
GOTO @LOOP
@ROME
IW$=IW$+IK$
FOR I=0 TO 4
IF IW$==AY$(I) THEN GOSUB @CHK
NEXT
IF LEN(IW$)>=2 THEN GOSUB @CHK
RETURN
@CHK
DD$="":AX=0:AY=0:J=0
IF LEN(IW$)==1 THEN J=1:GOTO @SKIP2
IF MID$(IW$,1,1)=="N" THEN @SKIP1
IF MID$(IW$,0,1)==MID$(IW$,1,1) THEN AS=-1:GOTO @SKIP3
@SKIP1
FOR I=0 TO 7
IF I<4 THEN IF IW$==RAK$(I) THEN AS=RAS(I):I=7:J=1
IF MID$(IW$,0,1)==AX$(I,0) THEN AX=I+1
IF MID$(IW$,0,1)==AX$(I,1) THEN AX=I+1:DD$="゛"
IF MID$(IW$,0,1)==AX$(I,2) THEN AX=I+5:DD$="゜"
NEXT
IF J THEN @SKIP3
@SKIP2
FOR I=0 TO 4
IF MID$(IW$,1-J,1)==AY$(I) THEN AY=I+1
NEXT
AS=AY+AX*5
IF AS>35 THEN AS=AS-1
IF AS>38 THEN AS=AS-1
@SKIP3
PKCA=AS+176
IF MD==2 THEN GOSUB @PKNC
PRINT CHR$(PKCA);DD$;
IF AS==-1 THEN IW$=MID$(IW$,1,1):RETURN
IW$=""
RETURN

@PKNC
PKCA=PKCA-163
'ヘンカン タイショウカ゛イ ナラ モト゛ル
IF PKCA<3 THEN RETURN
IF PKCA==13 THEN RETURN
IF PKCA>58 THEN RETURN

'カタカナハ ヒラカ゛ナニ ヘンカン
IF PKCA>8 THEN PKCA=PKCA+5
IF PKCA>17 THEN PKCA=PKCA+2
IF PKCA>23 THEN PKCA=PKCA+2
IF PKCA>27 THEN PKCA=PKCA+100
IF PKCA>143 THEN PKCA=PKCA+12
IF PKCA>159 THEN PKCA=PKCA+72
IF PKCA>239 THEN PKCA=PKCA+4
RETURN

@MENU1
ICONSET 0,35
RETURN

@MENU2
ICONSET 0,44
ICONSET 1,46
ICONSET 2,49
ICONSET 3,53
RETURN

@FILEMENU
IF ICONCHK()==0 THEN F1=1
IF ICONCHK()==1 THEN F1=2
IF ICONCHK()==2 THEN F2=1
IF ICONCHK()==3 THEN F2=2
IF !F1 OR !F2 THEN RETURN
IF F1==1 THEN ON F2-1 GOTO @MEMLOAD,@GRPLOAD
FOR I=0 TO 2
TEXT$(I)=""
FOR J=0 TO 255
TEXT$(I)=TEXT$(I)+CHR$(CHKCHR(J%32,FLOOR(J/32)+I*8))
NEXT
NEXT
IF F1==2 THEN ON F2-1 GOTO @MEMSAVE,@GRPSAVE
@FILEINIT
F1=0:F2=0
RETURN

@MEMLOAD
FOR I=0 TO 2
LOAD "MEM:R_TEXT"+STR$(I)
PRINT MEM$;
NEXT
GOTO @FILEINIT

@GRPLOAD
LOAD "GRP:R_TEXT0"
FOR I=0 TO 767
PRINT CHR$(GSPOIT(I%256,FLOOR(I/256)));
NEXT
GOTO @FILEINIT

@MEMSAVE
FOR I=0 TO 2
MEM$=TEXT$(I)
SAVE "MEM:R_TEXT"+STR$(I)
NEXT
GOTO @FILEINIT

@GRPSAVE
FOR I=0 TO 2
FOR J=0 TO LEN(TEXT$(I))-1
GPSET J,I,ASC(MID$(TEXT$(I),J,1))
NEXT
NEXT
SAVE "GRP:R_TEXT0"
GOTO @FILEINIT
}}

*CHECKER FLAG (ひとことコメント) [#f8b3dc57]
この作品に対するコメントがあれば一言どうぞ。(その他の雑談は[[掲示板>Board]]か[[OFコーナー>OverFlow]]でしようって。)~
- ''ななし@おなかいっぱい'' : どうやってローマ字変換されるんだ?変換されない(´;ω;`) (&new{2012/09/01 (土) 17:22:22};)
- ''わぁぃ@'' : すみません。「操作方法」を掲載しました。 (&new{2012/09/01 (土) 17:41:57};)
- ''名無しさん'' : YAがモに。JAがアに。ZYAを打とうとしてZYでゴに。ローマ字変換の組み合わせは多いですよ。 (&new{2012/09/01 (土) 17:58:29};)
- ''名無しさん'' : 「小さい「ゃ」「ゅ」「ょ」は打てません」って、それだけ単独で出すのができないという意味でなくて、JAも打てないということか・・・ (&new{2012/09/01 (土) 18:06:34};)
- ''わぁぃ@'' : 「YA」が「も」なのはバグでそれ以外は未実装です。あせらずv1.0にしてから投稿したほうが良かったかな。 (&new{2012/09/01 (土) 18:32:40};)
- ''わぁぃ@'' : ↑のバグは72行目の&basic{AS>35};を&basic{AS>36};にすると直るようです。お手数おかけして申し訳ありません。 (&new{2012/09/01 (土) 18:42:23};)
- ''メルビル'' : うぽつです (&new{2012/09/02 (日) 09:49:18};)
- ''&basic{otyaken};'' : &basic{ウポツ}; (&new{2012/09/02 (日) 09:53:12};)
- ''AmakoSoft'' : ローマ字変換ライブラリ作ったのに・・・ (&new{2012/09/05 (水) 23:34:33};)
- ''名無しさん'' : ↑? (&new{2012/09/05 (水) 23:54:48};)
- ''名無しさん'' : ↑↑サブルーチンで変換? それなら部品として有用なので是非公開を。 (&new{2012/09/06 (木) 11:59:51};)
- ''hatena'' : ↑*3 是非、[[サンプルプログラム集>Sample]]のサブルーチンに載せて下さい。 (&new{2012/09/06 (木) 19:03:39};)
- ''名無しさん'' : [[http://wiki.hosiken.jp/petc/?Toukou%2F%A5%ED%A1%BC%A5%DE%BB%FA%A4%CE%B5%D9%C6%FC]]です (&new{2012/09/06 (木) 23:54:57};)
- ''名無しさん'' : 100行くらいあるからサンプルプログラム集に載せられない (&new{2012/09/07 (金) 23:40:34};)
- ''名無しさん'' : ↑↑リンクが間違ってる? (&new{2012/09/08 (土) 11:24:24};)
- ''わぁぃ@'' : ↑またはページが消えたか? (&new{2012/09/08 (土) 11:33:51};)
- ''ななし'' : こっちは?http://wiki.hosiken.jp/petc/?Toukou%2F%A5%ED%A1%BC%A5%DE%BB%FA%A4%CE%B5%D9%C6%FC (&new{2012/09/08 (土) 11:48:51};)
- ''わぁぃ@'' : 見れました。中身が違うから使いたい方を使えば良い。 (&new{2012/09/08 (土) 12:05:29};)
- ''名無しさん'' : 「PETIKANA」フォントのCHRファイルを”PETIKANA”というファイル名で保存しておいて下さいっていうのどうやるんですか? (&new{2012/11/12 (月) 15:27:58};)
- ''↑'' : やり方わかんないんで具体的に教えて下さい (&new{2012/11/12 (月) 15:29:12};)
- ''道産子の初心者'' : ↑説明します。1.PETIKANAを取り込む 2.「プログラムを作る」からそれを実行 3.フォントが変わる 4.そのままCHREDを起動 5.フォントを編集する所へ 6.フォントにひらがながあることを確認 7.そのまま保存 (&new{2012/11/12 (月) 16:19:06};)
- ''道産子の初心者'' : ↑少し長々しいですが、そう難しいことは書いてない(はず)です。疑問があったらお知らせください。 (&new{2012/11/12 (月) 16:28:34};)
- ''天郷思音'' : ↑*2 3.の次にSAVE"BGF:PETIKANA"(enter)ってやって「はい」でもok (&new{2012/11/12 (月) 17:17:10};)
- ''名無しさん'' : RENAMEじゃだめ? (&new{2012/11/12 (月) 18:16:30};)
- ''道産子の初心者'' : RENAMEって何でしたっけ…。 (&new{2012/11/13 (火) 17:10:04};)
- ''名無しさん'' : 説明書見よう (&new{2012/11/13 (火) 17:28:30};)
- ''天郷思音'' : ↑3 RENAMEは改名ですからこの場面では意味ないです。 (&new{2012/11/14 (水) 12:12:39};)

#comment

表示モード : [ スマホ・3DS対応表示 | クラシック表示 ]
PukiWiki 1.4.7 Copyright © 2001-2006 PukiWiki Developers Team. License is GPL. Based on "PukiWiki" 1.3 by yu-ji
ページの処理時間 : 0.013 秒 | ログイン
Copyright(C) 2011-2014 プチコンまとめWiki ◆1sxkymI8ji30