プチコンまとめWiki (初代/mkII)

Toukou/プチコ積み の変更点

パンくずリスト


#title(投稿プログラム : プチコ積み)
2014年8月1日投稿 / 投稿者 : まげ / &tag(投稿プログラム,ゲーム,QRコード,mkII専用,パズル,プチコちゃん);

#contents

今日のアクセス:&counter(today);  トータルアクセス:&counter(total);

* 概要 [#z23c672c]
#ref(pckdown_op.jpg)
俗に「落ちものパズル」と呼ばれるタイプのゲームです。プチコと、友人のスパコ、ポケコの顔を模したブロック(^^;)が落ちてくるので、ルールに従って上手に積み上げ、消していきましょう。&br;
ルールの基本は「タテに挟んで消す」で、図柄Aで図柄Bを挟むと、どちらも消えます。別の図柄Cが混ざると消せません。(ゲーム内にて、より詳しい説明があります)&br;

※「プチコちゃん」はオリジナルキャラであり、同名の他のキャラとは無関係です。

* 遊び方 [#n60c364c]
** タイトル画面 [#m4d4085b]
Aボタンでゲーム開始、Xボタンで終了します。&br;
ゲーム開始後、起動時のみ、チュートリアルが始まります。

** ゲーム画面 [#i5955910]
#ref(pckdown_gm.jpg)
方向ボタンの左右、および下で、落ちてくるブロックを移動できます。&br;
エンディングはないので、高得点を出すことを目的としてください。

* 戯れ言 [#i9d4b8ab]
コンソール表現には32×24の制限がありますが、そこをやりくりするのが楽しいのです。PB-100の12×1に比べたら広大なんですから。&br;

プチコちゃんシリーズ作品です。顔だけながら、プチコの友人、スパコとポケコが初登場です。今後の作品にも登場予定なので、お見知置きを。&br;
スピードアップすると、なぜか「同じ色で積みたくなる」んですよねって、私だけでしょうか?(^^;)&br;

よろしければ拙HP・[[【プチコRoom】:http://mage.kir.jp/puchiko_hp]]へもお越しください。こちらには絶対に載せられない作品もあります(^^;)。&br;

* アンケート [#k382c91a]
このゲーム、何に似てると思いました?
#vote(テトリス[0],コラムス[0],ぷよぷよ[3],その他[1],なし[1])
#vote(テトリス[0],コラムス[0],ぷよぷよ[4],その他[1],なし[1])

* QR コード [#z303150a]
プチコンmkII 向けの QR コードです。

|&ref(qr000.gif);|&ref(qr001.gif);|&ref(qr002.gif);|&ref(qr003.gif);|

* プログラムリスト [#x692199f]

#region(プログラムリスト/527行)
#basic{{
CLEAR:ACLS:PNLTYPE "OFF":COLOR 0,0:BGMSTOP


DIM ST(3,7),STD(3,7),B$(11,4),CL(11),TT$(3,8),TC(3)
RESTORE @CHARA
FOR Q=0 TO 10:FOR I=0 TO 3
READ B$(Q,I)
NEXT I
READ CL(Q)
NEXT Q
TT$(0,0)="──Ё─┬┘──┐"
TT$(0,1)=" ┌┘─┼─  │"
TT$(0,2)="─┘ ─┘ ──┘"
TT$(2,6)="PUCHIKO"
TT$(2,7)="TSUMI"
TT$(1,0)="┌┬┘ ─┼─"
TT$(1,1)=" │   ┼"
TT$(1,2)="─┼─ ─┴─"
TT$(1,3)="┌┼┐ ┌─┐"
TT$(1,4)="││└ ├─┤"
TT$(1,5)="┘│  ├─┤ ─┐"
TT$(1,6)=" │  └─┘ ┌┼┼┐"
TT$(1,7)=" │  ┘ └ └┘┘"
TC(0)=0:TC(1)=3:TC(2)=7
TB$="@S9@E10@N2450"
DEMOS=0

'タイトル<---------------------
@TITLE
IF BUTTON()!=0 THEN @TITLE
CLS
BGMPLAY 22
TTC=0
@TLOOP
R=RND(3)+1:PX=RND(26)
PY=0
@TLOOP2
COLOR CL(R)
LOCATE PX,PY:?"       ";
FOR Z=0 TO 3
LOCATE PX,PY+Z+1:? B$(R,Z);
NEXT Z
FOR Z=0 TO 7
COLOR TC(TTC)
LOCATE 6,3+Z:? TT$(0,Z)
LOCATE 6,3+Z:? TT$(2,Z)
LOCATE 15,3+Z:? TT$(1,Z)
TTC=TTC+1:IF TTC>2 THEN TTC=0
NEXT Z
LOCATE 3,0:COLOR 14:?"(C)MAGE/Studio LOVEMARINE"
COLOR 4
LOCATE 6,21:?"кжжжл"
LOCATE 5,22:?"к     л"
LOCATE 5,23:?"з     и";
COLOR 12
LOCATE 14,18:?"┝┿┿┿┰"
LOCATE 14,19:?"┿┿┿┿┿"
LOCATE 13,20:?"┝┿┿┿┿┿┰"
LOCATE 13,21:?"┸└▼▼▼┘┥"
LOCATE 14,22:?"клйкл"
LOCATE 13,23:?"ккз илл";
COLOR 9
LOCATE 23,17:?"┝┿┰"
LOCATE 22,18:?"┝┿┿┿┰"
LOCATE 22,19:?"●┿┿┿●"
LOCATE 22,20:?"●┥▼┸●"
LOCATE 22,21:?"бкжлб"
LOCATE 22,22:?"кжжжл"
LOCATE 21,23:?"ккз илл";
LOCATE 10,14:COLOR 0:?"Аスタ-ト  Фエント゛"
TLC=5
@TBWAIT
BT=BUTTON(2)
IF BT AND 16 GOTO @DEMO
IF BT AND 64 GOTO @QUIT
WAIT 1
TLC=TLC-1
IF TLC>0 THEN @TBWAIT
PY=PY+1
IF PY<20 THEN @TLOOP2
LOCATE PX,20:?"       ";
LOCATE PX,21:?"       ";
LOCATE PX,22:?"       ";
LOCATE PX,23:?"       ";
GOTO @TLOOP

'テ゛モ<----------------------
@DEMO
IF BUTTON()!=0 THEN @DEMO
CLS
BGMSTOP 0,1
WAIT 60
IF DEMOS==1 THEN @START
BGMPLAY 9
Z=1
@DLOOP
CLS
GOSUB ("@DEMO"+STR$(Z))
COLOR 2
LOCATE 4,23:?"Аツキ゛ノ セツメイ   Бセツメイ トハ゛ス";
@DWAIT
BT=BUTTON(2)
WAIT 1
IF BT==32 THEN @DSKIP
IF BT!=16 THEN @DWAIT
Z=Z+1
IF Z<6 THEN @DLOOP
@DSKIP
CLS
BGMSTOP 0,1
WAIT 60

'ショキカ<---------------------
@START
IF BUTTON()!=0 THEN @START
FOR Q=0 TO 2:FOR I=0 TO 5
ST(Q,I)=0
STD(Q,I)=0
NEXT I
ST(Q,6)=9
NEXT Q
SC=0
BT=-1:BW=40
CLS
GOSUB @FRAME
COLOR 0
LOCATE 24,0:?"Next"
LOCATE 24,8:?"SCORE"
BGMPLAY 4
DWT=200
@SWAIT
IF BUTTON()!=0 THEN DWT=0
WAIT 1
DWT=DWT-1
IF DWT>0 THEN @SWAIT
BGMPLAY 0,14,100
R2=RND(3)+1

'メイン<----------------------
@LOOP
R=R2
R2=RND(3)+1
PX=1:PY=0

COLOR CL(R2)
FOR Z=0 TO 3
LOCATE 24,2+Z:? B$(R2,Z);
NEXT Z

@PYLOOP
FOR BC=0 TO BW
ST(PX,PY)=R

GOSUB @STAGE
PPX=0:PPY=0
BN=BUTTON()
IF BN==BT THEN @PASS
BT=BN
WAIT 1
ST(PX,PY)=0
IF BT==4 AND PX-1>=0 THEN PPX=-1
IF BT==8 AND PX+1<=2 THEN PPX=1
IF BT==2 THEN PPY=1:BC=BC+2
IF ST(PX+PPX,PY+PPY)!=0 THEN PPX=0:PPY=0
@PASS
ST(PX,PY)=0
PX=PX+PPX:PY=PY+PPY
NEXT BC
IF ST(PX,PY+1)!=0 THEN @SKIP
PY=PY+1
GOTO @PYLOOP

'ハンテイ<---------------------
@SKIP
GOSUB @STAGE

BEEP 33
ST(PX,PY)=R
CY=PY+1:CP=0

@CLOOP1
IF CY>5 THEN @PASS1
IF ST(PX,CY)==R THEN CP=1:GOTO @PASS1
CY=CY+1
GOTO @CLOOP1

@PASS1
IF CY>PY+1 AND CP==1 THEN CP=0 ELSE GOTO @PASS3
STD(PX,PY)=1:STD(PX,CY)=1
CY=PY+1:CM=ST(PX,CY)

'ハサンテ゛イル<------------------
@CLOOP2
IF ST(PX,CY)==R THEN @PASS2
IF ST(PX,CY)!=CM THEN @PASS3
STD(PX,CY)=1:CP=CP+1
CY=CY+1
GOTO @CLOOP2

'ケス<-----------------------
@PASS2
BEEP 6

FOR Y=0 TO 6:FOR X=0 TO 2
FOR W=0 TO 2
IF STD(X,Y)!=1 THEN @CPASS
FOR Z=0 TO 3
COLOR 0
LOCATE X*7+1,Y*4+Z
IF W==0 THEN VK=ST(X,Y)+7:VW=6
IF W==1 THEN VK=4:VW=2
IF W==2 THEN VK=0:VW=2
COLOR CL(VK)
? B$(VK,Z);
NEXT Z
GOSUB @FRAMETOP
ST(X,Y)=0
WAIT VW
@CPASS
NEXT W
NEXT X:NEXT Y

PP=CP+(CP-1)*2
SC=SC+PP
COLOR 13
LOCATE PX*7+2,PY*4+1:?"+";PP
COLOR 3
GOSUB @SCORE
WAIT BW
BW=BW-2
IF BW<4 THEN BW=4

@PASS3
FOR Y=0 TO 6:FOR X=0 TO 2
STD(X,Y)=0
NEXT X:NEXT Y

IF ST(1,0)!=0 THEN @END
GOTO @LOOP

'エント゛<---------------------
@END
BGMSTOP
BEEP 37
COLOR 14
FOR Y=5 TO 0 STEP -1
FOR X=0 TO 2
FOR Z=0 TO 3
IF Y==0 AND X!=1 AND Z==0 THEN @EPASS
LOCATE X*7+1,Y*4+Z
IF ST(X,Y)!=0 THEN VS=ST(X,Y)+4 ELSE VS=0
? B$(VS,Z);
@EPASS
NEXT Z
NEXT X
WAIT 5
NEXT Y
GOSUB @FRAMETOP

COLOR 13
GOSUB @SCORE

COLOR 13:LOCATE 7,10
?"GAME OVER"
COLOR 3:LOCATE 5,13
?"Аサイフ゜レイ  Бタイトル"
DEMOS=1
@PWAIT
BT=BUTTON(2)
IF BT AND 16 GOTO @START
IF BT AND 32 GOTO @TITLE
GOTO @PWAIT

END

'オワリ-----------------------
@QUIT
COLOR 0,0:CLS
BGMSTOP 0,1
WAIT 30
LOCATE 0,8
?"     ┌─────────┐  ┝┿┿┿┰    "
?"     │         │  ┸┥┥┥┥    "
?"     │ マ タ ネ ♪ ├ ┝│^ ^│┰   "
?"     │         │ ┸└ ▽ ┘┥   "
?"     └─────────┘  к   л";:COLOR 12:?"フ゜チコ"
COLOR 0

TALK TB$+"マタ'ネ-?"
WAIT 60

END


'┿┿┿┿┿ サフ゛ル-チン ┿┿┿┿┿┿┿┿┿┿┿┿

@STAGE
FOR Y=0 TO 5
FOR X=0 TO 2
FOR Z=0 TO 3
IF Y==0 AND X!=1 AND Z==0 THEN @SPASS
COLOR CL(ST(X,Y))
LOCATE X*7+1,Y*4+Z
? B$(ST(X,Y),Z);
@SPASS
NEXT Z
NEXT X:NEXT Y
GOSUB @FRAMETOP
COLOR 0
GOSUB @SCORE
RETURN

@FRAME
COLOR 14
FOR Y=0 TO 23
LOCATE 0,Y:?"╂";
LOCATE 22,Y:?"╂";
NEXT Y
GOSUB @FRAMETOP
RETURN

@FRAMETOP
COLOR 14
LOCATE 1,0:?"╂"*7
LOCATE 15,0:?"╂"*7
RETURN

@SCORE
LOCATE 30-(LEN(STR$(SC))-1),9
? SC
RETURN

@DEMO1
COLOR 3
?"■セツメイ 1/5"
?"жжжжжжжжж"
COLOR 0
?"イワユル 「オチモノ ツミ ハ゜ス゛ル」 テ゛ス。"
?
?"フ゜チコ、スハ゜コ、ホ゜ケコ ノ 「カオ」 ヲ。"
?
COLOR 3
?"ホウコウキ- ノ ←、→、↓";:COLOR 0:?" テ゛ イト゛ウ シテ"
?
?"ツンテ゛イキマス。"
?
?
COLOR 12:?"   ┝┿┿┿┰    ";:COLOR 9:?"  ┝┿┰     ";:COLOR 4:?" кжжжл"
COLOR 12:?"   ┸┥┥┥┥    ";:COLOR 9:?" ┝┸ハ┥┰    ";:COLOR 4:?"к ллл л"
COLOR 12:?"  ┝│・ ・│┰   ";:COLOR 9:?" ●□ж□●    ";:COLOR 4:?"зк┃ ━ли"
COLOR 12:?"  ┸└ ▽ ┘┥   ";:COLOR 9:?"б●л-к●б   ";:COLOR 4:?"л└ ▽ ┘к"
COLOR 12:?
COLOR 12:?"   フ゜チコ     ";:COLOR 9:?"  スハ゜コ    ";:COLOR 4:?" ホ゜ケコ"
RETURN

@DEMO2
COLOR 3
?"■セツメイ 2/5"
?"жжжжжжжжж"
COLOR 12:?"  ┝┿┿┿┰"
COLOR 12:?"  ┸┥┥┥┥     ";:COLOR 0:?"オナシ゛ カオ テ゛"
COLOR 12:?" ┝│・ ・│┰    ";:COLOR 0:?"タテ ニ ツム ト ケセマス。"
COLOR 12:?" ┸└й▽й┘┥"
COLOR 12:?"    ・        ┝┿┿┿┰     ";:COLOR 0:?"л  и  к"
COLOR 12:?"    ・        ┸┥┥┥┥"
COLOR 12:?"    ・       ┝│・ ・│┰"
COLOR 12:?"    ↓       ┸└й▽й┘┥    ";:COLOR 0:?"к  з  л"
COLOR 4:?"  кжжжл      кжжжл     ";:COLOR 0:?"л  и  к"
COLOR 4:?" к ллл л    к ллл л"
COLOR 4:?" зк┃ ━ли    зк┃ ━ли"
COLOR 4:?" л└й▽й┘к ";:COLOR 13:?"─┰ ";:COLOR 4:?"л└й▽й┘к ";
COLOR 13:?"─┰ ";:COLOR 0:?"к  з  л"
COLOR 4:?"  кжжжл  ";:COLOR 13:?"─┸  ";:COLOR 4:?"кжжжл  ";
COLOR 13:?"─┸ ";:COLOR 0:?"л  и  к"
COLOR 4:?" к ллл л    к ллл л"
COLOR 4:?" зк┃ ━ли    зк┃ ━ли"
COLOR 4:?" л└й▽й┘к    л└й▽й┘к    ";:COLOR 0:?"к  з  л"
COLOR 12:?"  ┝┿┿┿┰      ┝┿┿┿┰     ";:COLOR 0:?"л  и  к"
COLOR 12:?"  ┸┥┥┥┥      ┸┥┥┥┥"
COLOR 12:?" ┝│・ ・│┰    ┝│・ ・│┰"
COLOR 12:?" ┸└й▽й┘┥    ┸└й▽й┘┥    ";:COLOR 0:?"к  з  л"
RETURN

@DEMO3
COLOR 3
?"■セツメイ 3/5"
?"жжжжжжжжж"
COLOR 12:?"  ┝┿┿┿┰"
COLOR 12:?"  ┸┥┥┥┥     チカ゛ウ カオ カ゛"
COLOR 12:?" ┝│・ ・│┰    マサ゛ル ト ケセマセン。"
COLOR 12:?" ┸└й▽й┘┥"
COLOR 12:?"    ・        ┝┿┿┿┰      ┝┿┿┿┰"
COLOR 12:?"    ・        ┸┥┥┥┥      ┸┥┥┥┥"
COLOR 12:?"    ・       ┝│・ ・│┰    ┝│・ ・│┰"
COLOR 12:?"    ↓       ┸└й▽й┘┥    ┸└й▽й┘┥"
COLOR 9:?"   ┝┿┰        ┝┿┰        ┝┿┰"
COLOR 9:?"  ┝┸ハ┥┰      ┝┸ハ┥┰      ┝┸ハ┥┰"
COLOR 9:?"  ●□ж□●      ●□ж□●      ●□ж□●"
COLOR 9:?" б●л-к●б ";:COLOR 13:?"─┰ ";:COLOR 9:?"б●л-к●б ";
COLOR 13:?"─┰ ";:COLOR 9:?"б●л-к●б"
COLOR 4:?"  кжжжл  ";:COLOR 13:?"─┸  ";:COLOR 4:?"кжжжл  ";
COLOR 13:?"─┸  ";:COLOR 4:?"кжжжл"
COLOR 4:?" к ллл л    к ллл л    к ллл л"
COLOR 4:?" зк┃ ━ли    зк┃ ━ли    зк┃ ━ли"
COLOR 4:?" л└й▽й┘к    л└й▽й┘к    л└й▽й┘к"
COLOR 12:?"  ┝┿┿┿┰      ┝┿┿┿┰      ┝┿┿┿┰"
COLOR 12:?"  ┸┥┥┥┥      ┸┥┥┥┥      ┸┥┥┥┥"
COLOR 12:?" ┝│・ ・│┰    ┝│・ ・│┰    ┝│・ ・│┰"
COLOR 12:?" ┸└й▽й┘┥    ┸└й▽й┘┥    ┸└й▽й┘┥"
RETURN

@DEMO4
COLOR 3
?"■セツメイ 4/5"
?"жжжжжжжжж"
COLOR 0
?"タクサン ツンテ゛ ケスホト゛ ";:COLOR 13:?"コウトクテン ";:COLOR 0:?"テ゛ス。"
?
COLOR 12:?"   ┝┿┿┿┰         ┝┿┿┿┰"
COLOR 12:?"   ┸┥┥┥┥ ";:COLOR 0:?"x1= ";:COLOR 13:?"+1  ";
COLOR 12:?"┸┥┥┥┥ ";:COLOR 0:?"x2= ";:COLOR 13:?"+4"
COLOR 12:?"  ┝│^ ^│┰       ┝│^ ^│┰"
COLOR 12:?"  ┸└///┘┥       ┸└///┘┥"
?
COLOR 12:?"   ┝┿┿┿┰         ┝┿┿┿┰"
COLOR 12:?"   ┸┥┥┥┥ ";:COLOR 0:?"x3= ";:COLOR 13:?"+7  ";
COLOR 12:?"┸┥┥┥┥ ";:COLOR 0:?"x4= ";:COLOR 13:?"+10"
COLOR 12:?"  ┝│^ ^│┰       ┝│^ ^│┰"
COLOR 12:?"  ┸└///┘┥       ┸└///┘┥"
?
COLOR 2:?"(スハ゜コ、ホ゜ケコ テ゛モ オナシ゛トクテン テ゛ス)"
RETURN

@DEMO5
COLOR 3
?"■セツメイ 5/5"
?"жжжжжжжжж"
COLOR 0
?"カオ ノ ラッカ ソクト゛ ハ ケ゛-ム カ゛ ススムト"
?
?"ト゛ント゛ン ハヤクナリマス。"
?
?
?"カオ カ゛ テ゛ク゛チ ヲ フサク゛ト"
?
COLOR 13:?"ケ゛-ムオ-ハ゛- ";:COLOR 0:?"テ゛ス。"
?
?
COLOR 14
?"    ╂╂╂╂╂╂╂╂ ┝┿┿┿┰ ╂╂╂╂╂╂╂╂"
?"    ╂        ┸┥┥┥┥  ┝┸ハ┥┰ ╂"
?"    ╂       ┝│> <│┰●●■ж■●●╂"
?"    ╂       ┸└й^й┘┥б л к б╂"
?"    ╂        ┝┿┿┿┰  кжжжл ╂"
?"    ╂  ┝┿┰   ┸┥┥┥┥ к ллл л╂"
?"    ╂ ┝┸ハ┥┰ ┝│> <│┰зк- -ли╂"
RETURN


'┿┿┿┿┿ テ゛-タ ┿┿┿┿┿┿┿┿┿┿┿┿┿┿┿

@CHARA
DATA "       "
DATA "       "
DATA "       "
DATA "       "
DATA 0

DATA " ┝┿┿┿┰ "
DATA " ┸┥┥┥┥ "
DATA "┝│・ ・│┰"
DATA "┸└ ▽ ┘┥"
DATA 12

DATA "  ┝┿┰  "
DATA " ┝┸ハ┥┰ "
DATA " ●□ж□● "
DATA "б●л-к●б"
DATA 9

DATA " кжжжл "
DATA "к ллл л"
DATA "зк┃ ━ли"
DATA "л└ ▽ ┘к"
DATA 4

DATA "л  и  к"
DATA "       "
DATA "       "
DATA "к  з  л"
DATA 0

DATA " ┝┿┿┿┰ "
DATA " ┸┥┥┥┥ "
DATA "┝│> <│┰"
DATA "┸└ ^ ┘┥"
DATA 14

DATA "  ┝┿┰  "
DATA " ┝┸ハ┥┰ "
DATA "●●■ж■●●"
DATA "б л к б"
DATA 14

DATA " кжжжл "
DATA "к ллл л"
DATA "зк- -ли"
DATA "л└ ▽ ┘к"
DATA 14

DATA " ┝┿┿┿┰ "
DATA " ┸┥┥┥┥ "
DATA "┝│^ ^│┰"
DATA "┸└///┘┥"
DATA 12

DATA "  ┝┿┰  "
DATA " ┝┸ハ┥┰ "
DATA " ●Ш Ш● "
DATA "б●□ж□●б"
DATA 9

DATA " кжжжл "
DATA "к ллл л"
DATA "зк┷ ┷ли"
DATA "л└ ▽ ┘к"
DATA 4
}}
#endregion

/////////////////////////////////
// コメントを募集したくないなら、ここから下は削除してください

* CHECKER FLAG (ひとことコメント) [#o2510255]
この作品に対するコメントがあれば一言どうぞ。(作品に直接関係ない質問や雑談は[[掲示板>Board]]へ)
- ''ぷちぷち'' : まげさんってコンソールの使い方がうまいですよね。 (&new{2014/08/06 (水) 22:54:09};)
- ''投稿者'' : >ぷちぷちさん:ありがとうございます! でも、実はかなり強引なコトもしてまして、それに対応してくれるプチコンが素晴らしいんだと私は思います(^^;)。 (&new{2014/08/06 (水) 23:23:58};)

#comment

表示モード : [ スマホ・3DS対応表示 | クラシック表示 ]
PukiWiki 1.4.7 Copyright © 2001-2006 PukiWiki Developers Team. License is GPL. Based on "PukiWiki" 1.3 by yu-ji
ページの処理時間 : 0.011 秒 | ログイン
Copyright(C) 2011-2014 プチコンまとめWiki ◆1sxkymI8ji30