プチコンまとめWiki (初代/mkII)

Toukou/エクスプローラー の変更点

パンくずリスト


#title(投稿プログラム : エクスプローラー)
'''Ittan EXPLORER'''
#contents
// ↑この2行は削除しないでください。
// ←このように「//」で始まる行はコメントです。ページ本文には反映されません。
//------------------------------------------------------------------------------
// ・投稿年月日は、このページを投稿しようとしている今日の日付を半角数字で入力してください。
//   この日付は、投稿プログラムを自動的に年月日順に並べる際に使用されます。
// ↓↓↓
2012年6月24日投稿
// ↑↑↑
//------------------------------------------------------------------------------
// ・投稿者名は、将来的に投稿プログラム一覧に表示するために使用します。
// ・「名無しさん」のままにしておくと、匿名の方からの投稿として扱われます。
// ↓↓↓
/ 投稿者 : いったん
// ↑↑↑
//------------------------------------------------------------------------------
// ・適当にタグをつけることができます。半角のコンマ区切りで複数つけられます。
//   タグをつけると、同じタグが付いたページを検索することができます。
// ★次に該当するプログラムは、特定のタグを設定するようご協力お願いします。
//   これらを設定すると、将来的に投稿プログラム一覧に目立つマークが付くようになる予定です。
// ・短いプログラム → 「1行プログラム」「数行プログラム」「1画面プログラム」タグのいずれか1つ
// ・初代プチコンでも動作するプログラム → 「初代対応」タグ
// ・mkII 以降専用のプログラム → 「mkII専用」タグ
// ・QRコードを掲載している → 「QRコード」タグ
// ・該当するなら「ゲーム」「実用ツール」「音楽」タグのいずれか
// ↓↓↓
/ &tag(投稿プログラム,ツール,QRコード,mkII専用);
// ↑↑↑

* 概要  Summary [#Summary]
様々なファイルの整理をするプログラムです。~
フォルダ分けができたり、見出しの名前を作れたりします。~
その他、FILES命令からファイルを作成したり。名前や削除の手続きをプログラム上でできたりします。~
キャラなどはプレビュー機能もあるので便利なのではないでしょうか。~
質問、バグ報告、改善点などありましたらぜひコメントしてください。~
特にバグ調査は万全でないのでご注意ください。見つけ次第直していきます。~
// This is the software that manages the file on PetitComputer.~
// This can make a folder or the name of the header.~

** 更新履歴 [#Kousin]
只今v3.2です(12/17更新)~
~次回更新予定:特になし。
~6/30更新~
バグ修正・SORT機能を追加したv1.1を投稿しました。~
修正内容:PUTGRPの仕組みを修正,文字の綴り修正,アンダーバーができないところを修正
~7/2更新~
バグ修正をしました。
これまでのプログラムではGRPの書き込みにバグがありました。~
下のプログラムを使うと必要な部分以外が消されて整理されるようになっています。~
~手順
+ 下にあるFEREPAIRを実行する。
+ ファイルを入力
+ 修正(時間がかかります。)の後に保存するファイルを入力~

~10/14更新~
バグ修正をしました。(詳細はプログラム内に)~
コピー・ペースト機能(挿入可能)、~
フォルダへのショートカットを追加しました。~
なんとなく起動音をwindows98っぽくしました。~
ファイルエディター→エクスプローラーに変更。
~11/22更新~
日本語バージョンを追加しました。~
バグを修正しました。~
修正内容:フォルダ作成の時、無限ループするバグ,バージョン変数,SORT時のショートカットがファイルになるバグを修正
~12/17更新~
バグの修正、全文に英語での説明を追加、プチコンのファイルへの変更機能の追加、バージョン情報の追加、FILESから作成モードを追加~
注意!v3.0以降で作成したGRPはこれまでのものでは使えません。

*** バグ情報 [#Buginfo]
今のところありません。

* 基本操作 [#Play]
- X、Bボタンでセーブ、終了ができます。
-  その他の作業は基本タッチで行います。以下説明
|~タッチ項目|~タッチ項目(日本語版)|~内容|
|>|>|~フォルダ表示中|
|&basic{Name};|&basic{なまえへんこう};|今のフォルダの名前変更、ショートカットの名前変更|
|&basic{Back};|&basic{もどる};|一つ前のフォルダに戻る|
|&basic{New};|&basic{しんき};|ファイル、フォルダ、ショートカットの新規作成のメニューを出します。|
|&basic{folder};|&basic{ふぉるだ};|今のフォルダに新しくフォルダを作ります。|
|&basic{file};|&basic{ふぁいる};|今のフォルダに新しくファイルを作ります。|
|&basic{fm files};|なし|今のフォルダに新しくファイルを''FILES命令から''作ります。|
|&basic{shortcut};|&basic{しょーとかっと};|今のフォルダに新しくフォルダのショートカットを作ります。|
|&basic{Deletefolder};|&basic{ふぉるだをしょうきょ};|今のフォルダを削除します。|
|&basic{Paste};|&basic{ぺーすと};|クリップボードに貼り付けているファイルを指定位置にコピーします。|
|&basic{Sort};|&basic{ならびかえ};|ファイルを文字列コードの昇順に並び替え|
|&basic{▲};|&basic{▲};|ページ送り|
|&basic{▼};|&basic{▼};|ページ送り|
|ファイル名|ファイル名|そのファイルを選択|
|>|>|~ファイル表示中|
|&basic{Deletefile};|&basic{ーしょうきょするー};|選択中のファイルを削除します。|
|&basic{Change};|&basic{ーへんこうー};|その段の項目を編集します。|
|&basic{Execute};|&basic{ーよみこみ ー};|ファイル実行|
|&basic{Copy};|&basic{こぴー};|クリップボードにファイルの情報を書き込みます(複数選択可能)|
|&basic{▲};|&basic{▲};|読み込みタイプのページ送り|
|&basic{▼};|&basic{▼};|読み込みタイプのページ送り|
わからないことがあったら聞いてください。

* 最初の操作 [#Saisyo]
最初に読み込むグラフィックを聞かれます。
@Nで新しくファイルを作成できます。
~また、プログラムに直接データ文で記述することもできます。
- その場合は書いてある注意事項を読んでから書いてください

* 投票 [#Tohyo]
常識の範囲内で項目を増やしてもOKです。
#vote(すごい![20],まあまあ[1],いまいち[0],操作しにくい[4],便利[3],参考になった[1],もう少し変えたほうがいいかも[3])


* スクリーンショット・動画 [#ScreenShots]
// 動作しているところを撮影した写真や動画があれば貼り付けてください。
以下はv1.2の時のものです。ですのでかなり違うと思います。
#ref(IMG1.JPG)
#ref(IMG2.JPG)

* QR コード [#QR]
プチコンmkII 向けの QR コードです。
v3.1eまたはv2.2jです。v2.1から前の方はぜひ読みなおしてください。~
''QRコード(通常版v3.1e)''
|>|>|~PRG:EXPLORER|
|~1/15|~2/15|~3/15|
|&ref(qr0v3.1e.PNG);|&ref(qr1v3.1e.PNG);|&ref(qr2v3.1e.PNG);|
|~4/15|~5/15|~6/15|
|&ref(qr3v3.1e.PNG);|&ref(qr4v3.1e.PNG);|&ref(qr5v3.1e.PNG);|
|~7/15|~8/15|~9/15|
|&ref(qr6v3.1e.PNG);|&ref(qr7v3.1e.PNG);|&ref(qr8v3.1e.PNG);|
|~10/15|~11/15|~12/15|
|&ref(qr9v3.1e.PNG);|&ref(qr10v3.1e.PNG);|&ref(qr11v3.1e.PNG);|
|~13/15|~14/15|~15/15|
|&ref(qr12v3.1e.PNG);|&ref(qr13v3.1e.PNG);|&ref(qr14v3.1e.PNG);|

#region(QRコード(日本語版v2.2j))
|>|>|~PRG:EXPLRJ|
|~1/12|~2/12|~3/12|
|&ref(qr0v2.2j.PNG);|&ref(qr1v2.2j.PNG);|&ref(qr2v2.2j.PNG);|
|~4/12|~5/12|~6/12|
|&ref(qr3v2.2j.PNG);|&ref(qr4v2.2j.PNG);|&ref(qr5v2.2j.PNG);|
|~7/12|~8/12|~9/12|
|&ref(qr6v2.2j.PNG);|&ref(qr7v2.2j.PNG);|&ref(qr8v2.2j.PNG);|
|~10/12|~11/12|~12/12|
|&ref(qr9v2.2j.PNG);|&ref(qr10v2.2j.PNG);|&ref(qr11v2.2j.PNG);|
#endregion
GRPを整理するプログラムです。V1.1より前の人はこれを実行することで処理が早くなります。(やらなくてもOK)~
v3.1にも対応しています。
|>|~PRG:FEREPAIR|
|~1/2|~2/2|
|&ref(qr0_r.PNG);|&ref(qr1_r.PNG);|
/////////////////////////////////

* プログラムリスト [#List]
v3.1のプログラムリストです。~

#region(プログラムリスト)
#basic{{
’Explorer v3.1English
’(C)2012 Ittan programs
’      Developed by Ittan
’       Composed by Frasatie
’
’ハ゛ク゛&カイセ゛ンテン ナト゛
’ホウコクシテイタタ゛クト アリカ゛タイテ゛ス。
’ I`m glad when you report 
’bugs or improvements
’,such as.
’
’テ゛−タフ゛ン ショウサイハ LIST @USER
’For more infomation about
’data :LIST @USER
’
’History
’6/1
’カイハツ チャクシュ
’6/16
’システム ケ゛ンケイ カンセイ
’6/22
’ヨミコミケイ カンセイ
’6/28
’コ゛シ゛シュウセイ
’6/29
’Sort キノウ ツイカ
’7/1
’ク゛ラフィックカキコミ ノ ハ゛ク゛ シュウセイ
’9/13
’ファイルヲケストキノ ハ゛ク゛,フリ−ス゛ハ゛ク゛
’シュウセイ
’9/20
’FILE EDITOR → EXPLORER
’9/24
’Copy&Paste ツイカ
’10/14
’ショ−トカット ツイカ
’11/22
’ハ゛ク゛ シュウセイ
’12/10
’ハ゛ク゛ シュウセイ
’FILES モ−ト゛ ツイカ
’12/16
’セ゛ンフ゛ン エイコ゛カ
’フ゜チコンノファイル ヘノ カンショウキノウ ツイカ
’version info ツイカ
’−−−
IF NFSFLG THEN @NFSRTNBRK
GPAGE 1,2,2:GCLS 0
GPAGE 0,3,3:GCLS 0:ACLS
GPRIO 0
CLEAR
SYSBEEP=FALSE
DIM F$(500,4)
DIM OF$(100)
DIM OX(100),OY(100)
DIM FLCX(500),FLCY(500)
DIM ST$(200)
DIM CLIPBORD$(32)
DIM GRP(240,4)
DIM PUTFLIES$(5)
MAXT=32
FDVER$=”3.1E”
DIM TYPE$(MAXT)
MFILE$=”FILE”
       ’↑↑ココニ イツモツカウファイル
       ’ヲ カキ нカХ ヲオシテキト゛ウ
       ’スレハ゛ スク゛ ヨミコム。
       ’This is shortcut key.
OFL=0
OF$(0)=”Library”
PNLTYPE ”OFF”
LC=0

RESTORE @TYPEDATA
FOR I=0 TO MAXT−1
READ TYPE$(I)
NEXT
CLS
GOSUB @ON
GOSUB @LOADGRP
CHK$=”Libraly”:GOSUB @BUGCHK
CHK$=”Library”
GOSUB @GRPREAD
GOSUB @PRINTBK
GOSUB @PRINTFL
OT=TRUE


’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@MAINLOOP
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
TST=NOT(OT) AND TCHST
OT=TCHST
IF TST THEN  @TOUCH
PNLSTR 24,0,TIME$,1
VSYNC 1
BT=BTRIG()
IF BT THEN @BTN
GOTO@MAINLOOP


’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@BTN
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
IF BT AND 128 THEN @VERINFO
IF BT AND 64 THEN @_END
IF BT AND 32 THEN GOSUB @_SAVE
’IF BT AND 1024 THEN GOSUB @TEST
GOTO@MAINLOOP


’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@TOUCH
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
TX=TCHX:TY=TCHY
TX=FLOOR(TX/8):TY=FLOOR(TY/8)
IF TY==20 THEN @TOU0
IF TY==21 THEN @TOU1
IF TY==0 AND TX>17 AND TX<22 THEN @CHFRN
IF TY==2 AND TX>26 AND TX<32 THEN @SORT
IF TY==2 AND TX>19 AND TX<25 THEN @PASTE
IF PAGE>0 AND TX==6 AND TY==2 GOTO@BEFORE
TI=CANCEL
TI2=CANCEL
FOR I=0 TO 7
IF F$(PAGE*8+I,0)==”−” THEN I=8:GOTO@TCHNT
IF TY!=I*2+4 THEN @TCHNT
IF TX<2 THEN @TCHNT
IF F$(I+PAGE*8,0)==”2” AND TX>26 AND TX<32 THEN TI2=I+PAGE*8
IF TX>(2+LEN(F$(I+PAGE*8,1))) THEN @TCHNT
TI=I+PAGE*8
@TCHNT
NEXT
IF TI2!=CANCEL THEN @TCHSCS
IF TI==CANCEL GOTO@MAINLOOP
IF F$(TI,0)==”1” THEN @TCHFL
IF F$(TI,0)==”2” THEN @TCHSC
’−−−
@TCHFD
BEEP 9
OLCX=FLCX(TI)
OLCY=FLCY(TI)
CHK$=F$(TI,1)
OF$(OFL)=FF$
OFL=OFL+1
OF$(OFL)=CHK$
GOSUB @GRPREAD
GOSUB @PRINTBK
GOSUB @PRINTFL
GOTO@MAINLOOP
’−−−
@TCHSC
TCHSCF=TRUE
GOTO@TCHFD
’−−−
@TCHSCS
BEEP 9
I$=””
GPAGE 0:GCLS 0
LOCATE 0,10
?”NewShortcut Name?(Ф→Delete)”
PNLTYPE ”KYA”
@TSSLP
P$=INKEY$()
LOCATE 0,11:?I$+” ”;
IF BTRIG() AND 64 THEN @TSSEC2
IF KEYBOARD==15 THEN I$=LEFT$(I$,LEN(I$)−1+(I$==””)):BEEP
IF P$==CHR$(13) THEN @TSSEC
VSYNC 1
IF P$==”” THEN @TSSLP
PCHK$=P$
GOSUB @PRGCHK2
IF ER THEN BEEP 2:P$=””
I$=I$+P$
GOTO@TSSLP
@TSSEC
IF I$==”Library” THEN I$=””:BEEP 2
IF I$==OF$(OFL) THEN I$=””:BEEP 2
PNLTYPE ”OFF”
LOCATE 0,10:?” ”*18
IF I$==”” THEN @TS2EC
?”Please wait...”
FX=(FLCX(TI2)+1)
FY=FLCY(TI2)+FLOOR(FX/256)
FX=FX AND 255
DELL=LEN(F$(TI2,1))
DELX=FX
DELY=FY
GOSUB @DELGRP
PUTX=FX
PUTY=FY
PUT$=I$
GOSUB @PUTGRP
GOSUB @GRPREAD
@TS2EC
GOSUB @PRINTBK
GOSUB @PRINTFL
BEEP 3
GOTO@MAINLOOP
’−
@TSSEC2
CLS:LOCATE 0,0
GPAGE 0:GCLS 0
COLOR 13
?”Delete shortcut”
COLOR 0
?
?”Й◇”;F$(TI2,1);”ヲ フォルタ゛カラ
?”サクシ゛ョ シマス。
?
?”Й◇”;F$(TI2,1);” will removed”
?”from the folder”

INPUT”(Y/N)”;I$
PNLTYPE ”OFF”
IF I$!=”Y” THEN GOTO@TSSEC3
DELX=FLCX(TI2)
DELY=FLCY(TI2)
DELL=LEN(F$(TI2,1))
DELL=DELL+3
GOSUB @DELGRP
CHK$=OF$(OFL)
@TSSEC3
GOSUB @GRPREAD
GOSUB @PRINTBK
GOSUB @PRINTFL
BEEP 3
GOTO@MAINLOOP

’−−−−−−−−−−−
@TCHFL
CLS
GOSUB @PRINTBK
BEEP 9
LOCATE 0,0
?CHR$(0)*96;
PNLSTR 0,0,”・”+F$(TI,1)+”.”+F$(TI,3),1
PNLSTR 1,2,”FileName:”+F$(TI,1),1
PNLSTR 25,2,”Change”,11
PNLSTR 1,4,”ReadName:”+F$(TI,2),1
PNLSTR 25,4,”Change”,11
PNLSTR 1,6,”FileType:”+F$(TI,3),1
PNLSTR 25,6,”Change”,11
PNLSTR 1,8,”Execute”,13
PNLSTR 1,20,”Back”,11
PNLSTR 8,20,”DeleteFile”,11
PNLSTR 21,20,”Copy”,11

’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@FILELOOP
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
IF GOFL THEN GOFL=0:GOTO@TCHFL
TST=NOT(OT) AND TCHST
OT=TCHST
PNLSTR 24,0,TIME$,1
VSYNC 1
IF TST==0 THEN  @FILELOOP
TX=TCHX:TY=TCHY
TX=FLOOR(TX/8):TY=FLOOR(TY/8)
IF TY==20 AND TX>0 AND TX<5 THEN GOTO@FILEEC
IF TY==8 AND TX>0 AND TX<8 THEN GOTO@EXECF
IF TX>8 AND TX<18 AND TY==20 THEN GOTO@DELFILE
IF TX>20 AND TX<25 AND TY==20 THEN GOTO@FILECOPY

IF TX>31 OR TX<26 THEN GOTO@FILELOOP
IF TY==2 THEN @CHNAME
IF TY==4 THEN @CHREAD
IF TY==6 THEN @CHTYPE
GOTO@FILELOOP
’−−−
@DELFILE
CLS:LOCATE 0,0
GPAGE 0:GCLS 0
COLOR 13
?”Delete file”
COLOR 0
?
?F$(TI,1);”ヲ フォルタ゛カラ
?”サクシ゛ョ シマス。
?”フ゜チコンカラモ サクシ゛ョシマスカ?
?
?F$(TI,1);” will removed 
?”from the foloder.
?”Do you remove it from 
?”Petit Computer?”
?
?” ハイ     イイエ    キャンセル
?”     (フォルタ゛ノミ)(ナニモシナイ)
?” Yes    No     Cancel
DEFI=0
@DLFLP
LOCATE DEFI*7,13:?”→”
IF BTRIG() AND 8 THEN LOCATE DEFI*7,13:?” ”:DEFI=DEFI+1
IF BTRIG() AND 4 THEN LOCATE DEFI*7,13:?” ”:DEFI=DEFI−1
IF BTRIG() AND 16 THEN GOTO@DLFEC
DEFI=DEFI+(DEFI<0)*3−(DEFI>2)*3
VSYNC 1
GOTO@DLFLP
@DLFEC
BEEP 9
IF DEFI==2 THEN GOTO@DLFEC2
DELX=FLCX(TI)
DELY=FLCY(TI)
DELL=LEN(F$(TI,1)+F$(TI,2)+F$(TI,3))
DELL=DELL+4
GOSUB @DELGRP
IF DEFI==1 THEN GOTO@DLFEC2
PCHK$=F$(TI,2)
GOSUB @PRGCHK
IF ER!=0 THEN GOTO @DFLER
IF LEFT$(F$(TI,3),3)==”PRG” THEN DF$=”PRG:”
IF LEFT$(F$(TI,3),3)==”GRP” THEN DF$=”GRP:”
IF LEFT$(F$(TI,3),3)==”MEM” THEN DF$=”MEM:”
IF LEFT$(F$(TI,3),3)==”SCU” THEN DF$=”SCU:”
IF LEFT$(F$(TI,3),3)==”COL” THEN DF$=”COL:”
IF DF$==”” THEN DF$=”CHR:”
DF$=DF$+F$(TI,2)
CLS
?”ファイルサクシ゛ョ ”
DELETE DF$
IF RESULT==0 THEN @DFLER
@DLFEC2
GOSUB @GRPREAD
GOSUB @PRINTBK
GOSUB @PRINTFL
BEEP 3
GOTO@MAINLOOP
@DFLER
BEEP 2
?”Error!!”
?
?”ソノ ファイルハ ソンサ゛イシマセン。
?”Sorry. It does not exist.
?”
WAIT 60
GOTO@DLFEC2

’−−−
@CHNAME
I$=””
BEEP 9
GPAGE 0:GCLS 0:CLS
LOCATE 0,0
?”NewName?”
PNLTYPE ”KYA”
@CHNLP
GOFL=TRUE
P$=INKEY$()
LOCATE 0,11:?I$+” ”;
IF KEYBOARD==15 THEN I$=LEFT$(I$,LEN(I$)−1+(I$==””)):BEEP
IF P$==CHR$(13) THEN @CHNEC
VSYNC 1
IF P$==”” THEN @CHNLP
PCHK$=P$
GOSUB @PRGCHK2
IF ER THEN BEEP 2:P$=””
I$=I$+P$
GOTO@CHNLP
@CHNEC
PNLTYPE ”OFF”
LOCATE 0,0:?”         ”
IF I$==”” THEN @TCHFL
LOCATE 0,12:?”Plese wait...”;
FX=FLCX(TI)+1 AND 255
FY=FLCY(TI)+(FX==0)
DELL=LEN(F$(TI,1))
DELX=FX
DELY=FY
GOSUB @DELGRP
PUTX=FX
PUTY=FY
PUT$=I$
GOSUB @PUTGRP
NP=PAGE
GOSUB @GRPREAD
PAGE=NP
BEEP 3
GOTO@FILELOOP
’−−−
@CHREAD
GOFL=TRUE
I$=””
BEEP 9
GPAGE 0:GCLS 0:CLS
?”NewReadName?”
PNLTYPE ”KYA”
@CHRLP
P$=INKEY$()
LOCATE 0,1:?I$+” ”;
IF KEYBOARD==15 THEN I$=LEFT$(I$,LEN(I$)−1+(I$==””)):BEEP
IF P$==CHR$(13) THEN @CHREC
VSYNC 1
PCHK$=P$:GOSUB @PRGCHK
IF P$==”” THEN ER=0
IF LEN(I$)>=8 AND P$!=”” THEN ER=1
IF ER THEN P$=””:BEEP 2
IF P$==”” THEN @CHRLP
I$=I$+P$
GOTO@CHRLP
@CHREC
CLS
PNLTYPE ”OFF”
IF I$==”” THEN @FILELOOP
?”フ゜チコン テ゛ノ ナマエモ カエマスカ?”
?”Do you also change the name 
?”in Petit Computer?”
?”(Y/N)
INPUT YN$
?
?”Please wait...”;
FX=(FLCX(TI)+LEN(F$(TI,1))+2)
FY=FLCY(TI)+FLOOR(FX/256)
FX=FX AND 255
DELL=LEN(F$(TI,2))
DELX=FX
DELY=FY
GOSUB @DELGRP
PUTX=FX
PUTY=FY
PUT$=I$
GOSUB @PUTGRP
IF YN$!=”Y” GOTO@CHREC2
PCHK$=F$(TI,2)
GOSUB @PRGCHK
IF ER!=0 THEN GOTO @DFLER
IF LEFT$(F$(TI,3),3)==”PRG” THEN DF$=”PRG:”
IF LEFT$(F$(TI,3),3)==”GRP” THEN DF$=”GRP:”
IF LEFT$(F$(TI,3),3)==”MEM” THEN DF$=”MEM:”
IF LEFT$(F$(TI,3),3)==”SCU” THEN DF$=”SCU:”
IF LEFT$(F$(TI,3),3)==”COL” THEN DF$=”COL:”
IF DF$==”” THEN DF$=”CHR:”
DF$=DF$+F$(TI,2)
CLS
?”ファイルメイヘンコウ”
RENAME DF$,I$
@CHREC2
NP=PAGE
GOSUB @GRPREAD
PAGE=NP
BEEP 3
GOTO@FILELOOP


’−−−
@CHTYPE
TPAGE=0
PNLSTR 13,9,”▲”,11
PNLSTR 13,19,”▼”,11
@CHTLP0
FOR I=0 TO 8
P=TPAGE*9+I
IF P>=32 THEN P$=CHR$(0)*5:GOTO@CHTNT
P$=TYPE$(P)+CHR$(0)*5
@CHTNT
P$=LEFT$(P$,5)
PNLSTR 11,I+10,P$,11
NEXT I
@CHTLP
TST=NOT(OT) AND TCHST
OT=TCHST
PNLSTR 24,0,TIME$,1
VSYNC 1
IF TST==0 THEN  @CHTLP
TX=TCHX:TY=TCHY
TX=FLOOR(TX/8):TY=FLOOR(TY/8)
IF TX==13 AND TY==9 THEN TPAGE=TPAGE−1+(TPAGE==0):BEEP 9:GOTO@CHTLP0
IF TX==13 AND TY==19 THEN TPAGE=TPAGE+1−(TPAGE==3):BEEP 9:GOTO@CHTLP0
IF TX<11 OR TX>15 THEN GOTO@CHTLP
IF TY<10 OR TY>18 THEN GOTO@CHTLP
IF TPAGE==3 AND TY>14 THEN GOTO@CHTLP
?”Please wait...”;
I$=TYPE$((TY−10)+TPAGE*9)
FX=FLCX(TI)
FX=FX+LEN(F$(TI,1))
FX=FX+LEN(F$(TI,2))
FX=FX+3
FY=FLCY(TI)+FLOOR(FX/256)
FX=FX AND 255
DELX=FX
DELY=FY
DELL=LEN(F$(TI,3))
GOSUB @DELGRP
PUTX=FX
PUTY=FY
PUT$=I$
GOSUB @PUTGRP
NP=PAGE
GOSUB @GRPREAD
PAGE=NP
GOFL=TRUE
BEEP 3
GOTO@FILELOOP


’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@EXECF
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
BGMPLAY”L16@144V60CG
PCHK$=F$(TI,2)
GOSUB @PRGCHK
IF ER==1 THEN @EXECERR
A$=””
FA$=LEFT$(F$(TI,3),3)
IF FA$==”GRP” THEN A$=”@EXGRP”
IF FA$==”MEM” THEN A$=”@EXMEM”
IF FA$==”PRG” THEN A$=”@EXPRG”
IF FA$==”COL” THEN A$=”@EXCOL”
IF FA$==”SCU” THEN A$=”@EXSCU”
IF A$==”” THEN A$=”@EXCHR”
GOSUB A$
GOTO@FILELOOP
’−−−
@EXSCU
READFILE$=F$(TI,3)+”:”+F$(TI,2)
LOAD READFILE$,FALSE
LOCATE 0,0
?”ヨミコミカ゛ カンリョウ シマシタ。
?”Complete loading”
BGPAGE 0
BGOFS 0,0,0
BGOFS 1,0,0
RETURN

’−−−
@EXCOL
LOCATE 0,0
FOR I=0TO 3?CHR$(0)*256;:NEXT
GPAGE 0
READFILE$=”COL2:”+F$(TI,2)
LOAD READFILE$,0
GCLS 0
FOR I=0 TO 255
X=FLOOR(I%16)*8
Y=FLOOR(I/16)*8
GFILL X,Y,X+7,Y+7,I
NEXT
RETURN
’−−−
@EXGRP
LOCATE 0,0
FOR I=0TO 3?CHR$(0)*256;:NEXT
GPAGE 0
READFILE$=”GRP0:”+F$(TI,2)
LOAD READFILE$,0
IF BUTTON()==32 THEN READFILE$=”COL2:”+F$(TI,2):LOAD READFILE$,0
RETURN
’−−−
@EXPRG
GPAGE 0:GCLS 0
CLS
COLOR 13
?”PRGヨミコミ
COLOR 0
?
?”PRG:”+F$(TI,2)” ヲ ヨミコミマス。”
?”イマノテ゛−タヲGRPニホソ゛ンシマス。”
?
?”PRG:”+F$(TI,2)” will loaded.”
?”Data will be saved to GRP
?
S$=”GRP2:”+FILE$
SAVE S$
ACLS
L$=”PRG:”+F$(TI,2)
EXEC L$
BEEP 2
CLS
?”error!”
?”コ゛シテイノファイルハ ミツカリマセンテ゛シタ。
?”Sorry. It does not exist.
WAIT 60
GOFL=TRUE
RETURN
’−−−
@EXCHR
LOCATE 0,0
FOR I=0TO 3?CHR$(0)*256;:NEXT
GPAGE 0:GCLS 0
READFILE$=F$(TI,3)+”:”+F$(TI,2)
LOAD READFILE$,FALSE
IF LEFT$(F$(TI,3),2)==”SP” THEN @EXCSP
IF RIGHT$(F$(TI,3),1)==”U” THEN BGPAGE 0
IF RIGHT$(F$(TI,3),1)==”L” THEN BGPAGE 1
FOR I=0 TO 255
X=(I%32)*8
Y=FLOOR(I/32)*8
GPUTCHR X,Y,F$(TI,3),I,0,1
NEXT
RETURN
’−
@EXCSP
FOR I=0 TO 255
X=(I%2)*8+FLOOR((I%64)/4)*16
Y=FLOOR(I%4/2)*8+FLOOR(I/64)*16
GPUTCHR X,Y,F$(TI,3),I,0,1
NEXT
RETURN
’−−−
@EXMEM
LOCATE 0,0
FOR I=0TO 3?CHR$(0)*256;:NEXT
LOCATE 0,0
GPAGE 0:GCLS 0
READFILE$=”MEM:”+F$(TI,2)
LOAD READFILE$,FALSE
?MEM$
RETURN
’−−−
@EXECERR
GPAGE 0:GCLS 0
CLS:BEEP 7
?”Meseeage”
?”ヨミコミメイカ゛ シヨウフカノウナモシ゛
?”ヲフクンテ゛イル、
?”モシクハ ヨミコミメイカ゛ナイ タメニ
?”ヨミコミヲ チュウタ゛ンシマシタ。
?”==タイショ==
?”ヨミコミメイヲ カエテ タメシテネ。
?
?”ホ゛タンヲオスト モト゛リマス。
?
?”Specified name is can`t use.
?”Please change the name.
?
?”Please press any button.
FOR I=0TO 1:I=BTRIG():NEXT
GOTO@TCHFL
’−−−
@FILECOPY
CLIPBORD$(CB)=”・”+F$(TI,1)+”:”+F$(TI,2)+”.”+F$(TI,3)+”,”
BEEP 75
BEEP 75,2389.333
?CLIPBORD$(CB)
CB=CB+1 AND 31
GOTO@FILELOOP
’−−−
@FILEEC
BGPAGE 0
BGCLR
BEEP 9
NP=PAGE
GOSUB @GRPREAD
GOSUB @PRINTBK
PAGE=NP
GOSUB @PRINTFL
GOTO@MAINLOOP
’−−−
@TOU0
IF TX>0 AND TX<5 THEN GOTO@BACK
IF NEXTF==TRUE AND TX==6 GOTO@AFTER
IF TX>7 AND TX<20 THEN GOTO@DELFOLDER
IF TX>22 AND TX<26 THEN GOTO@NEWMADE
GOTO@MAINLOOP
’−−−
@TOU1
GOTO@MAINLOOP
’−−−
@NEWMADE
BEEP 9
PNLSTR 20,14,”┌────────┐”,11
PNLSTR 20,15,”│fm files│”,11
PNLSTR 20,16,”│ folder │”,11
PNLSTR 20,17,”│  file  │”,11
PNLSTR 20,18,”│shortcut│”,11
PNLSTR 20,19,”└───┬┬───┘”,11
NI=0
@NWMLP
PNLSTR 24,0,TIME$,1
VSYNC 1
TX=FLOOR(TCHX/8)
TY=FLOOR(TCHY/8)
IF TCHST==0 THEN @NWMLP
IF TX>30 OR TX<20 OR TY<14 OR TY>21 THEN NI=0:GOTO@NWMEC
IF TX>21 AND TX<29 AND TY==15 THEN NI=4:GOTO@NWMEC
IF TX>22 AND TX<28 AND TY==16 THEN NI=1:GOTO@NWMEC
IF TX>23 AND TX<27 AND TY==17 THEN NI=2:GOTO@NWMEC
IF TX>21 AND TX<29 AND TY==18 THEN NI=3:GOTO@NWMEC
GOTO@NWMLP
@NWMEC
GOSUB@PRINTBK
GOSUB@PRINTFL
ON NI GOTO @MAINLOOP,@NEWFD,@NEWFL,@NEWSC,@NEWFILES
GOTO@MAINLOOP
’−−−
@BACK
BEEP 9
IF OFL==0 THEN GOTO@MAINLOOP
OFL=OFL−1
CHK$=OF$(OFL)
GOSUB @GRPREAD
GOSUB @PRINTBK
GOSUB @PRINTFL
GOTO@MAINLOOP
’−−−
@BEFORE
BEEP 9
PAGE=PAGE−1
GOSUB @PRINTBK
GOSUB @PRINTFL
GOTO@MAINLOOP
’−−−
@AFTER
BEEP 9
PAGE=PAGE+1
GOSUB @PRINTBK
GOSUB @PRINTFL
GOTO@MAINLOOP
’−−−
@NEWFL
BEEP 9
?”Please wait...”;
?”
PUTX=GRPX:PUTY=GRPY
PUT$=”・NEWFILE:FILE.PRG,”
NP=PAGE
GOSUB @PUTGRP
GOSUB @GRPREAD
GOSUB @PRINTBK
PAGE=NP
GOSUB @PRINTFL
BEEP 3
GOTO@MAINLOOP
’−−−
@NEWFD
?”Please wait...”;
GPAGE 1,2,1
BEEP 9
NP=PAGE
X=GRPX:Y=GRPY
@NFDLP
G=GSPOIT(X,Y)
IF G==0 THEN NX=X:NY=Y:GOTO@NFDEC
Y=Y+(X==255)
X=X+1 AND 255
GOTO@NFDLP
@NFDEC
NUM=0
@NFDLP2
CHK$=”NEWFOLDER”+STR$(NUM)*(NUM!=0)
CHKD=1
GOSUB @GRPREAD
IF FIND==1 THEN NUM=NUM+1:GOTO@NFDLP2
CHKD=0
CHK$=OF$(OFL)
PUTX=NX:PUTY=NY
PUT$=”@NEWFOLDER”+STR$(NUM)*(NUM!=0)+”{}”
’−−−
GOSUB @PUTGRP
GOSUB @GRPREAD
PUTX=GRPX:PUTY=GRPY
PUT$=”◇NEWFOLDER”+STR$(NUM)*(NUM!=0)+”:,”
GOSUB @PUTGRP
GOSUB @GRPREAD
GOSUB @PRINTBK
PAGE=NP
GOSUB @PRINTFL
BEEP 3
GOTO@MAINLOOP
’−−−
@NEWSC
?”Please wait...”;
GPAGE 1,2,1
BEEP 9
PUTX=GRPX:PUTY=GRPY
PUT$=”〜Shortcut:,”
NP=PAGE
GOSUB @PUTGRP
GOSUB @GRPREAD
GOSUB @PRINTBK
PAGE=NP
GOSUB @PRINTFL
BEEP 3
GOTO@MAINLOOP
’−−−
@NEWFILES
CLS
NP=PAGE
LOCATE 0,0
COLOR 13
?”FILESヨリ ファイル サクセイ”
?”Make new file from [FILES]”
COLOR 0
?”コノフォルタ゛ニ FILESカラノ ナイヨウヲ コヒ゜−シマス。
?”
?”STEP1:カクチョウシヲ エランテ゛クタ゛サイ
?”      select extension.
?” ↑
?”    А
?” ↓
L=0:ARG$=””
@NFSLP0
LOCATE 0,8
L=L+((BTRIG()AND 2)==2)
L=L−((BTRIG()AND 1)==1)
IF L<0 THEN L=6
IF L>6 THEN L=0
IF L==0 THEN ?”ALL”:ARG$=””
IF L==1 THEN ?”PRG”:ARG$=CHR$(34)+”PRG”+CHR$(34)
IF L==2 THEN ?”CHR”:ARG$=CHR$(34)+”CHR”+CHR$(34)
IF L==3 THEN ?”GRP”:ARG$=CHR$(34)+”GRP”+CHR$(34)
IF L==4 THEN ?”SCR”:ARG$=CHR$(34)+”SCR”+CHR$(34)
IF L==5 THEN ?”MEM”:ARG$=CHR$(34)+”MEM”+CHR$(34)
IF L==6 THEN ?”COL”:ARG$=CHR$(34)+”COL”+CHR$(34)
VSYNC 1
IF BTRIG()!=16 GOTO@NFSLP0
VSYNC 2

L=0
@NFSLP
CLS
?
?”STEP2:ツキ゛ノ サキ゛ョウ
?”      Next work.
?
?” 1.A テ゛ PRGヲ イッタン テイシ。 Аx1”
?” 2.ENTER ヲ 2カイ。        Аx2”
?” 3.ENTER ヲ ”L”カイ       Аx”;L
?” 4.SELECTホ゛タンヲ オス      SELECT”
?” 5.STARTホ゛タンヲ オス       START”
FOR I=0 TO 1 I=BTRIG() AND 16
NEXT
NFSFLG=TRUE
CLS
LOCATE 0,2
?”FILES”+ARG$
LOCATE 0,0
END
@NFSRTNBRK
NFSFLG=FALSE:NFSEND=FALSE
FL$=””:
PUTFILES$(0)=””:PUTFILES$(1)=””
PUTFILES$(2)=””
FOR Y=0 TO 22
FL$=””
 FOR X=0 TO 31
 G$=CHR$(CHKCHR(X,Y))
 IF G$==”” THEN X=31
 IF G$==CHR$(0) THEN G$=””:X=31
 IF G$==” ” THEN G$=””
 IF X==0 AND G$==”−” THEN G$=””:PUTFILES$(0)=””:PUTFILES$(1)=””:PUTFILES$(2)=””:X=31:NFSEND=TRUE
 FL$=FL$+G$
 NEXT
IF FL$!=”” THEN GOSUB @NFSPUT
NEXT
FOR NFS=0 TO 2
PUT$=PUTFILES$(NFS)
PUTX=GRPX:PUTY=GRPY
GOSUB @PUTGRP
GRPY=GRPY+FLOOR((GRPX+LEN(PUTFILES$(NFS)))/256)
GRPX=GRPX+LEN(PUTFILES$(NFS)) AND 255
NEXT
L=L+1
IF NFSEND==TRUE THEN @NFSEC
GOTO @NFSLP
@NFSEC
GOSUB @GRPREAD
GOSUB @PRINTBK
PAGE=NP
GOSUB @PRINTFL
BEEP 3
PNLTYPE”OFF”
GOTO@MAINLOOP


@NFSPUT
IF FL$==”OK” THEN NFSEND=TRUE:RETURN
IF FL$==”” THEN NFSEND=TRUE:RETURN
IF LEFT$(FL$,5)==”FILES” THEN NFSEND=TRUE:RETURN
FA$=””:FB$=””
FOR I=0 TO LEN(FL$)
G$=MID$(FL$,I,1)
IF G$==”:” THEN G$=””:FB$=FA$:FA$=””
FA$=FA$+G$
NEXT
IF FB$==”CHR” THEN FB$=”BGU0U”
IF FB$==”COL” THEN FB$=”COL0U”
IF FB$==”SCR” THEN FB$=”SCU0U”
PUTFILES$(Y/8)=PUTFILES$(Y/8)+”・”+FA$+”:”+FA$+”.”+FB$+”,”
RETURN

’−−−
@DELFOLDER
CLS:LOCATE 0,0
IF TCHSCF==TRUE THEN @DFRER2
IF OFL==0 THEN @DFRER
COLOR 13
?”ファルタ゛−サクシ゛ョ”
?”Delete folder
COLOR 0
?
?”フォルタ゛−ヲサクシ゛ョスルト
?”ナカノファイルモ スヘ゛テ ケサレマス
?”イイテ゛スカ?
?”If you delete this folder,
?”files are deleted from 
?”the folder.
?”OK?
?
INPUT”(Y/N)”;I$
IF I$!=”Y” THEN @DFREC
?”Please wait...”;
L=GRPX−GRPSX+(GRPY−GRPSY)*256+1
DELX=GRPSX
DELY=GRPSY
DELL=L
GOSUB @DELGRP
OFL=OFL−1
CHK$=OF$(OFL)
GOSUB @GRPREAD
I0=0
@DFRLP
IF F$(I0,1)==OF$(OFL+1) THEN @DFREC1
I0=I0+1
IF I0>=MAXF THEN BEEP
GOTO@DFRLP
@DFREC1
DELX=FLCX(I0)
DELY=FLCY(I0)
DELL=LEN(F$(I0,1))+3+LEN(F$(IO,2))
GOSUB @DELGRP
@DFREC
CHK$=OF$(OFL)
GOSUB @GRPREAD
GOSUB @PRINTBK
GOSUB @PRINTFL
BEEP 3
GOTO@MAINLOOP
@DFRER
?”@Libraryハ サクシ゛ョテ゛キマセン。”
?”You can`t delete [@Library]”
WAIT 60
GOTO@DFREC
@DFRER2
?”ショ−トカットカラハ サクシ゛ョテ゛キマセン。
?”You can`t delete if
?”you came here by
?”shortcut.”
WAIT 60
GOTO@DFREC
’−−−
@CHFRN
CLS
LOCATE 0,0
IF OFL==0 THEN @CHFER
PNLTYPE ”KYA”
?”NewFolderName?”
I$=””
@CHFLP
P$=INKEY$()
LOCATE 0,11:?I$+” ”;
IF KEYBOARD==15 THEN I$=LEFT$(I$,LEN(I$)−1+(I$==””)):BEEP
IF P$==CHR$(13) THEN @CHFEC0
VSYNC 1
IF P$==”” THEN @CHFLP
PCHK$=P$
GOSUB @PRGCHK2
IF ER THEN BEEP 2:P$=””
I$=I$+P$
GOTO@CHFLP
’−
@CHFEC0
?:?”Please wait...”;
PNLTYPE ”OFF”
IF I$==”” THEN @CHFEC
OCK$=OF$(OFL):CHK$=I$:CHKD=1
GOSUB @GRPREAD
IF FIND==1 THEN I$=I$+”+”:GOTO@CHFEC0
CHKD=0:CHK$=OCK$
FX=OLCX
FY=OLCY
DELX=FX
DELY=FY
DELL=LEN(OF$(OFL))+1
GOSUB @DELGRP
PUTX=FX
PUTY=FY
PUT$=”◇”+I$
GOSUB @PUTGRP
GOSUB @GRPREAD
FX=GRPSX+1 AND 255
FY=GRPSY+(FX==0)
DELX=FX
DELY=FY
DELL=LEN(OF$(OFL))
GOSUB @DELGRP
PUTX=FX
PUTY=FY
PUT$=I$
GOSUB @PUTGRP
OF$(OFL)=I$
CHK$=I$
GOSUB @GRPREAD
@CHFEC
GOSUB @PRINTBK
GOSUB @PRINTFL
BEEP 3
GOTO@MAINLOOP
@CHFER
?”@Libraryノ ナマエハ ”
?”カエルコトカ゛ テ゛キマセン。”
?
?”You can`t change name of
?”@Library
?
WAIT 60
GOTO@CHFEC


’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@SORT
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
I=0
BEEP 9
?”Please wait...”;
@SRTLP
IF F$(I,0)==”−” THEN @SRTEC
S$=””
IF F$(I,0)==”0” THEN SA$=”◇”
IF F$(I,0)==”1” THEN SA$=”・”
IF F$(I,0)==”2” THEN SA$=”〜”
S$=SA$+F$(I,1)+”:”
IF SA$==”・” THEN S$=S$+F$(I,2)+”.”+F$(I,3)
S$=S$+”,”
ST$(I)=S$
I=I+1
GOTO@SRTLP
@SRTEC
SORT 0,I,ST$
I2=I
DELX=FLCX(0)
DELY=FLCY(0)
DELL=(GRPY−DELY)*256
DELL=DELL+GRPX−DELX
GOSUB @DELGRP
FOR SI=I2−1 TO 0 STEP −1
PUT$=””
PUTX=FLCX(0)
PUTY=FLCY(0)
@SRTLP2
PUT$=ST$(SI)+PUT$
IF SI==0 THEN @SRTEC2
IF LEN(PUT$)+LEN(ST$(SI−1))>256 THEN @SRTEC2
SI=SI−1
GOTO@SRTLP2
@SRTEC2
GOSUB @PUTGRP
NEXT
GOSUB @GRPREAD
GOSUB @PRINTBK
GOSUB @PRINTFL
BEEP 3
GOTO@MAINLOOP
’−−−−−−−−−−−−−−−−−−−−−−−−−−−
@PASTE
’−−−−−−−−−−−−−−−−−−−−−−−−−−−
LOCATE 0,0
?”↑↓コヒ゜−ファイルセンタク:Choose copy file”
?
?”Аテ゛ ケッテイ:А→OK                  ”

@PSTLP
LOCATE 0,1
?LEFT$(CLIPBORD$(BC)+” ”*32,32)
VSYNC 1
BT=BTRIG()
IF BT AND 1 THEN BC=BC−1+(BC==0)*32
IF BT AND 2 THEN BC=BC+1−(BC==31)*32
IF BT AND 16 THEN @PSTEC
IF BT AND 2028 THEN NP=PAGE:GOTO@PSTEC2
GOTO@PSTLP
@PSTEC
?”↑↓テ゛ソウニュウスルトコロヲ エランテ゛クタ゛サイ
?”↑↓Please choose location 
?”  of insertion
BC2=−1
VSYNC 1
COLOR 11,15
@PSTLP2
LOCATE 0,6
IF BC2==−1 THEN ?” ”*21:GOTO @PSTSK
IF F$(BC2,0)==”0” THEN ?”◇”;
IF F$(BC2,0)==”1” THEN ?”・”;
IF F$(BC2,0)==”2” THEN ?”Й”;
?LEFT$(F$(BC2,1)+” ”*32,20)
@PSTSK
?”ココニ コヒ゜−  А Copy here”
IF BC2==MAXF THEN ?” ”*21:GOTO @PSTSK2
IF F$(BC2+1,0)==”2” THEN ?”Й”;
IF F$(BC2+1,0)==”1” THEN ?”・”;
IF F$(BC2+1,0)==”0” THEN ?”◇”;
?LEFT$(F$(BC2+1,1)+” ”*32,20)
@PSTSK2
BT=BTRIG()
IF BT AND 1 THEN BC2=BC2−1+(BC2==−1)*(MAXF+2)
IF BT AND 2 THEN BC2=BC2+1−(BC2==MAXF)*MAXF
IF BT AND 16 THEN @PSTEC3
VSYNC 1
GOTO@PSTLP2
@PSTEC3
COLOR 0,0
PUTX=FLCX(BC2+1):PUTY=FLCY(BC2+1)
PUT$=CLIPBORD$(BC)
NP=PAGE
GOSUB @PUTGRP
GOSUB @GRPREAD
@PSTEC2
GOSUB @PRINTBK
PAGE=NP
GOSUB @PRINTFL
BEEP 3
GOTO @MAINLOOP

’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@VERINFO
VSYNC 1
COLOR 4,0
CLS:GPAGE 0:GCLS
PNLTYPE”PNL”
?,” ┠┠┠┠┠┠┠┠┠┠┠┠┠┠┠┠┠┠┠┠┠”
?,”┻ITTAN EXPLORER       ┛”
?,”┻ version 3.1.1.0E    ┛”
?,”┻                     ┛”
?,”┻(C)2012              ┛”
?,”┻    Ittan programs   ┛”
?,”┻                     ┛”
?,”┻ Developed by Ittan  ┛”
?,”┻                     ┛”
?,”┻ Composed by Frasatie┛”
?,”┻                     ┛”
?,”┻コノ フ゜ロク゛ラムノ          ┛”
?,”┻・カイソ゛ウ               ┛”
?,”┻・サイハイフ               ┛”
?,”┻  ヲキンシ゛マス。           ┛”
?,”┻                     ┛”
?,”┻          А          ┛”
?,” ┏┏┏┏┏┏┏┏┏┏┏┏┏┏┏┏┏┏┏┏┏”
COLOR 0,0
FOR I=0 TO 1
I=BTRIG() AND 16
VSYNC 1
NEXT
GOSUB @PRINTBK
GOSUB @PRINTFL
PNLTYPE ”OFF”
GOTO@MAINLOOP
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@PRINTBK
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
CLS:GPAGE 0:GCLS
?”Ф:Save and End
?”Б:Save
?”Х:version info:ハ゛−シ゛ョン シ゛ョウホウ
BGPAGE 1
BGFILL 0,0,0,31,23,15,0,0,0
PNLSTR 0,1,”┌──────────────────────────────┐”,1:
FOR I=2 TO 22
PNLSTR 0,I,”│”+” ”*30+”│”,1
NEXT
PNLSTR 0,23,”└──────────────────────────────┘”,1
PNLSTR 1,22,”EXPLORER v”+FDVER$+” by Ittan”,15
RETURN


’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@PRINTFL
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
’ファイルヒョウシ゛
NEXTF=0
I0=PAGE*8
PNLSTR 1,2,”P:”+STR$(PAGE+1),1
PNLSTR 0,0,”◇”+FF$,1
PNLSTR 18,0,”Name”,11
PNLSTR 27,2,”Sort”,11
PNLSTR 20,2,”Paste”,11
IF PAGE>0 THEN  PNLSTR 6,2,”▲”,11
@PFLLP
I1$=F$(I0,0)
IF I1$==”−” THEN @PFLEC
IF I0>=8+(PAGE*8) THEN  PNLSTR 6,20,”▼”,11:NEXTF=TRUE:GOTO@PFLEC
IF I1$==”2” THEN GOTO@SCUT
IF I1$==”1” THEN GOTO@FILE
IF I1$!=”0” THEN @PFLEC
PNLSTR 2,(I0%8)*2+4,”◇”+F$(I0,1),11
I0=I0+1
GOTO@PFLLP
@FILE
PNLSTR 2,(I0%8)*2+4,”・”+F$(I0,1)+”.”+F$(I0,3),11
I0=I0+1
GOTO@PFLLP
@SCUT
PNLSTR 2,(I0%8)*2+4,”Й◇”+F$(I0,1),11
PNLSTR 27,(I0%8)*2+4,”Name”,11
I0=I0+1
GOTO@PFLLP
@PFLEC
PNLSTR 1,20,”Back”,11
PNLSTR 8,20,”DeleteFolder”,11
PNLSTR 23,20,”New”,11
RETURN


’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@GRPREAD
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
’CHK$
’ク゛ラフィックヨミコミ
I0=0:FFLG=0:FF=0
X=0:Y=0:PAGE=0
GS$=””
FIND=TRUE
GPAGE 1,2,1
’−−−
@GRPLP
G$=CHR$(GSPOIT(X,Y))
IF G$==CHR$(0) THEN @GRPER
IF G$==”@” THEN FF=1:G$=””:IF CHKD==0 THEN GRPSY=Y:GRPSX=X
Y=Y+(X==255)
X=X+1 AND 255
IF G$==”{” AND FF THEN @CHKG
IF FF THEN GS$=GS$+G$
GOTO@GRPLP
’−−−
@GRPEC
G$=CHR$(GSPOIT(X,Y))
Y=Y+(X==255)
X=X+1 AND 255
IF G$==”〜” THEN GC$=”2”:G$=””:GS$=””
IF G$==”・” THEN GC$=”1”:G$=””:GS$=””
IF G$==”◇” THEN GC$=”0”:G$=””:GS$=””
IF G$==”:” THEN GA$=GS$:G$=””:GS$=””
IF G$==”.” THEN GB$=GS$:G$=””:GS$=””
IF G$==”,” THEN GOSUB@GRPPT
IF G$==”}” THEN GOSUB@GRPPT:GOTO@GRPEC2
GS$=GS$+G$
’?GS$:WAIT 5
GOTO@GRPEC
’−−−
@GRPPT
IF GA$==”” THEN RETURN
IF GC$==”” THEN GC$=”1”
F$(I0,0)=GC$
F$(I0,1)=GA$
F$(I0,2)=GB$
F$(I0,3)=GS$
FLCX(I0+1)=X:FLCY(I0+1)=Y
GA$=””:GB$=””:GC$=””
GS$=””:G$=””
I0=I0+1
RETURN 
@GRPEC2
F$(I0,0)=”−”
GRPY=Y−(X==0)
GRPX=X−1+(X==0)*256
FF$=CHK$
MAXF=I0−1
RETURN
’−−−
@CHKG
IF GS$!=CHK$ THEN FF=0:GS$=””:GOTO@GRPLP
IF CHKD THEN FIND=1:RETURN
PX=X:PY=Y
FLCX(0)=PX:FLCY(0)=PY
GS$=””
FF=0
GOTO@GRPEC
’−−−
@GRPER
FIND=0
IF TCHSCF THEN @GRESC
IF CHKD THEN RETURN
BEEP 7
CLS:COLOR 0
?”Meseeage”
?”ケンサクフォルタ゛カ゛ミツカラナカッタヨ。”
?”ホ゛タンヲオスト モト゛リマス。
?”Sorry. It does not exist.
?”Please press any button.
?
OFL=OFL−1
FOR I=0 TO 1:I=BTRIG():NEXT
GOSUB @PRINTBK
GOSUB @PRINTFL
GOTO @MAINLOOP
@GRESC
TCHSCF=FALSE
BEEP 7
CLS:COLOR 0
?”Meseeage”
?”ケンサクフォルタ゛カ゛ミツカラナカッタヨ。”
?”ホ゛タンヲオスト モト゛リマス。
?”Please press any button.
?”Sorry. It does not exist.
?
FOR I=0 TO 1:I=BTRIG():NEXT
GOSUB @PRINTBK
GOSUB @PRINTFL
OFL=OFL−1
GOTO @MAINLOOP

@BUGCHK
GPAGE 1,2,1
X=0:Y=0:PAGE=0
FF=0
GS$=””
@BGCLP
G$=CHR$(GSPOIT(X,Y))
IF G$==CHR$(0) THEN RETURN
IF G$==”@” THEN FF=1:G$=””:IF CHKD==0 THEN GRPSY=Y:GRPSX=X
Y=Y+(X==255)
X=X+1 AND 255
IF G$==”{” AND FF THEN @BGCCHKG
IF FF THEN GS$=GS$+G$
GOTO@BGCLP

@BGCCHKG
IF GS$==”Library” THEN RETURN
IF GS$!=CHK$ THEN FF=0:GS$=””:GOTO@BGCLP
DELX=GRPSX
DELY=GRPSY
DELL=LEN(GS$)+1
GOSUB @DELGRP
PUTX=GRPSX
PUTY=GRPSY
PUT$=”@Library”
GOSUB @PUTGRP
RETURN

’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@_SAVE
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
?”セ−フ゛シマス。”
?”SAVE GRP”
S$=”GRP2:”+FILE$
SAVE S$
LOCATE 0,CSRY−2
?CHR$(0)*8
?CHR$(0)*8
RETURN


’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@_END
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
GOSUB @_SAVE
GPAGE 0,2,2:GCLS 0
GPAGE 1,3,3:GCLS 0
ACLS:CLEAR
?”コ゛リヨウ アリカ゛トウコ゛サ゛イマシタ。
?”Shank you for useing.

END

’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@LOADGRP
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
CLS
COLOR 0
PNLTYPE ”KYA”
?”ヨミコミテ゛−タニュウリョク:Input load name”
?
?”@N:シンキサクセイ:new file”
?”@R:テ゛−タニヨル ヨミコミ:read to data”
IF BUTTON() AND 512+128 THEN I$=MFILE$:GOTO@LGRSK
INPUT I$
IF I$==”@N” THEN @NEW
IF I$==”@R” THEN @READDATA
PCHK$=I$:GOSUB @PRGCHK
IF ER THEN @RGRER
@LGRSK
IF LEN(I$)>8 THEN @RGRER
FILE$=I$
I$=”GRP2:”+I$
LOAD I$,0
IF RESULT==FALSE THEN @LOADGRP
@RGRLP
I$=”[EXPLORER]”:G$=””
GPAGE 0,2,0
FOR I=0 TO LEN(I$)−1
G$=G$+CHR$(GSPOIT(I,0))
NEXT
GPAGE 0,0,0
IF G$==I$ THEN PNLTYPE ”OFF”:RETURN
I$=”[FILEEDT]”:G$=””
GPAGE 0,2,0
FOR I=0 TO LEN(I$)−1
G$=G$+CHR$(GSPOIT(I,0))
NEXT
GPAGE 0,0,0
IF G$==I$ THEN @RGRBUG
@RGRER
CLS
BEEP 2
?”error!”
?”ヨミコンタ゛ファイルハ 
?”コノ フ゜ロク゛ラム ニハ ツカエマセン。
?”==カイケツホウホウ==
?”・アタラシク ファイルヲ ツクル。
?”・ヨミコム ファイルヲ カエル。
?
?”Sorry.
?”It can`t use for this soft.
?
?”ホ゛タンヲオスト モト゛リマス。
?”Please Press any button.”
FOR I=0 TO 1:I=BTRIG()NEXT
GOTO@LOADGRP
@RGRBUG
DELX=0:DELY=0
DELL=LEN(”[FILEEDT]”)
GOSUB @DELGRP
PUTX=0:PUTY=0
PUT$=”[EXPLORER]”
GOSUB @PUTGRP
GOTO@RGRLP
’−−−
@NEW
INPUT”シンファイルメイ:New file name”;I$
PCHK$=I$:GOSUB @PRGCHK
IF ER!=0 THEN BEEP 2:CLS:GOTO @NEW
FILE$=I$
PUT$=”[EXPLORER]@Library{}”
PUTX=0:PUTY=0
GOSUB @PUTGRP
I$=”GRP2:”+FILE$
SAVE I$
PNLTYPE ”OFF”
RETURN
’−−−
@READDATA
INPUT”ヨミコミラヘ゛ル:read label”;I$
PCHK$=I$:GOSUB @PRGCHK
IF ER!=0 THEN BEEP 2:CLS:GOTO @READDATA
FILE$=LEFT$(I$,8)
PNLTYPE ”OFF”
RESTORE”@”+I$
X=0:Y=0
GPAGE 0,2,0
@RDLP
READ I0$
IF I0$==”−” THEN @RDEC
FOR I=0 TO LEN(I0$)−1
I1$=MID$(I0$,I,1)
GPSET X,Y,ASC(I1$)
Y=Y+(X==255)
X=X+1 AND 255
NEXT
GOTO@RDLP
@RDEC
GPAGE 0,0,0
RETURN


’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@PUTGRP
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
LOCATE 0,0:CLS
?”Writing(put)”
?”Please wait...
?
?”Info”
?” x :”PUTX
?” y :”PUTY
?”str:”;CHR$(34);PUT$;CHR$(34)
GPAGE 1,2,1
’PUTX:PUTY:PUT$
PL=LEN(PUT$)
X=PUTX:Y=PUTY
 @PGRLP
 I0$=””
 PX=X:PY=Y
 FOR I=0 TO PL−1
  G$=CHR$(GSPOIT(X,Y))
  IF G$==CHR$(0) THEN G$=””
  I0$=I0$+G$
  Y=Y+(X==255)
  X=X+1 AND 255
 NEXT
 X=PX:Y=PY
 FOR I=0 TO PL−1
  I1$=MID$(PUT$,I,1)
  I1=0
  IF I1$!=”” THEN I1=ASC(I1$)
  GPSET X,Y,I1
  Y=Y+(X==255)
  X=X+1 AND 255
 NEXT
 IF I0$==”” THEN @PGREC
 PUT$=I0$
 GOTO@PGRLP
 @PGREC
RETURN


’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@DELGRP
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
LOCATE 0,0:CLS
?”Writing(delete)”
?”Please wait...
?
?”Info”
?” x :”DELX
?” y :”DELY
?”str:”DELL
GPAGE 1,2,1
’DELX,DELY,DELL
IF DELL==0 THEN RETURN
L=FLOOR((DELL−1)/256)
DELL2=DELL
FOR II=0 TO L
X=DELX:Y=DELY
DELL=DELL2
IF DELL>256 THEN DELL=256
@DGRLP
LOCATE 0,2
 I0$=””
 PX0=X:PY0=Y
 PY1=Y+FLOOR((X+DELL)/256)
 PX1=X+DELL AND 255
 X=PX1:Y=PY1
 FOR I=0 TO DELL−1
  G$=CHR$(GSPOIT(X,Y))
  IF G$==CHR$(0) THEN G$=””
  I0$=I0$+G$
  Y=Y+(X==255)
  X=X+1 AND 255
 NEXT
 X=PX0:Y=PY0
 FOR I=0 TO DELL−1
  I1$=MID$(I0$,I,1)
  I1=0
  IF I1$!=”” THEN I1=ASC(I1$)
  GPSET X,Y,I1
  Y=Y+(X==255)
  X=X+1 AND 255
 NEXT
 IF I0$==”” THEN @DGREC
 PUT$=I0$
 GOTO@DGRLP
 @DGREC
DELL2=DELL2−256
NEXT II
RETURN


’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@PRGCHK
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
’PCHK$
PCL=LEN(PCHK$)
ER=PCL==0
FOR I=0 TO PCL−1
G$=MID$(PCHK$,I,1)
IF G$>=”A” AND G$<=”Z”THEN @RGCNT
IF G$>=”0” AND G$<=”9”THEN @RGCNT
IF G$==”_” THEN @RGCNT
ER=TRUE
@RGCNT
NEXT
RETURN
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@PRGCHK2
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
’PCHK$
PCL=LEN(PCHK$)
ER=PCL==0
FOR I=0 TO PCL−1
G$=MID$(PCHK$,I,1)
IF G$==”:” THEN ER=ER+1
IF G$==”,” THEN ER=ER+1
IF G$==”.” THEN ER=ER+1
IF G$==”@” THEN ER=ER+1
IF G$==”{” THEN ER=ER+1
IF G$==”}” THEN ER=ER+1
IF G$==”・” THEN ER=ER+1
IF G$==”◇” THEN ER=ER+1
IF G$==”〜” THEN ER=ER+1
NEXT
RETURN

@ON
BGMSTOP
BGMSETD 128,@MMLDATA
BGMPLAY 0,128
LOCATE 2,10
COLOR 1
?”Explorer programmed by Ittan
PNLSTR 7,12,”press А or н button.”,15
FOR I=0 TO 512 STEP 2
IF I%32==0 THEN GRP(I/32,0)=RND(256):GRP(I/32,1)=RND(192):GRP(I/32,2)=176+RND(16)
FOR J=0 TO I/32
GRP(J,3)=GRP(J,3)+2
IF GRP(J,3)>256 THEN GOTO@SKIP
GCIRCLE GRP(J,0),GRP(J,1),GRP(J,3)−2,0
GCIRCLE GRP(J,0),GRP(J,1),GRP(J,3)−1,0
GCIRCLE GRP(J,0),GRP(J,1),GRP(J,3),GRP(J,2)
GCIRCLE GRP(J,0),GRP(J,1),GRP(J,3)+1,GRP(J,2)
@SKIP
NEXT
VSYNC 1
COL$=HEX$(I−(I>255)*(I−255),2)*3
COLSET ”BG”,31,COL$
VSYNC 2
IF (BUTTON() AND 512+16) THEN I=512
NEXT I
GCLS
BGMSTOP 0,1
RETURN

@MMLDATA
DATA”T60
DATA”{R=@E127,0,0,100}
DATA”{E=@E127,20,0,70}
DATA”:0{R}V127@49O1C1&C1
DATA”:1{R}V127@49O2C1&C1
DATA”:2{E}V127@48      RED  A<A1
DATA”:3{E}V127R64@48   RGG  B<B1
DATA”:4{E}V127R32@48   RBA <D<D1
DATA”:5{E}V127R32.@48  RR<D A<F+1
DATA”:6{E}V127R16@48   RR<F+<DA1
DATA”:7{E}V127R16R64@48RR<<DF+R1

DATA 0
@TEST
’テ゛ハ゛ック゛ヨウ
LOCATE 0,0:COLOR 0
GPAGE 1,2,0
FOR YY=0 TO 191
 FOR XX=0 TO 255
 GG$=CHR$(GSPOIT(XX,YY))
 ?GG$;
 VSYNC 1
 IF GG$==CHR$(0) THEN XX=800:YY=800
 NEXT XX
NEXT YY
WAIT 120
RETURN


@TYPEDATA
’カクチョウシヨウ
DATA”PRG”,”GRP”,”MEM”
DATA”SCU0U”,”SCU1U”
DATA”SCU0L”,”SCU1L”
DATA”COL0U”,”COL1U”,”COL2U”
DATA”COL0L”,”COL1L”,”COL2L”
DATA”BGF0U”,”BGF0L”
DATA”BGU0U”,”BGU1U”
DATA”BGU2U”,”BGU3U”
DATA”BGU0L”,”BGU1L”
DATA”BGU2L”,”BGU3L”
DATA”SPU0”,”SPU1”,”SPU2”
DATA”SPU3”,”SPU4”,”SPU5”
DATA”SPU6”,”SPS0”,”SPS1”
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
@USER −−−−−−−−−−−−−−−−−−−−−−−
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
’−−−−−−−−−−−−−−−−−−−−−−−−−−−−
’テ゛−タ゛フ゛ンサクセイニツイテ
’1:テ゛−タ゛フ゛ンノ サイショニ
’  カナラス゛セントウニ”[EXPLORER] ヲ
’  イレテ クタ゛サイ。
’  (ホカノ GRPヲ アヤマッテ ヨミコマナイヨウ。)
’  サイコ゛ハ DATA”−” ヲカク
’2:フォルタ゛テイキ゛
’  @+フォルタ゛メイ
’  フォルタ゛ノ ナカミハ {} テ゛ククル。
’  *1:(・◇:,.@{})ハ ツカエマセン。
’  *2:サイサョニハ @Library ヲ
’  イレテクタ゛サイ。
’3:ファイルサクセイ
’  (ファイルメイ):[(ヨミコムナマエ).
’  (ヨミコムシュルイ)],
’  []ナイ ショウリャクカノウ。
’  
’  ファイルメイ
’  フォルタ゛ナラ(◇)
’  ショ−トカットナラ(〜)
’  ファイルナラ (・)ヲセントウニツケル。
’  (ナイト ナマエヲ カエルトキニ ハ゛ク゛ル。)
’
’  ヨミコムナマエ
’  ヨミコムトキニ ツカイマス 
’  セイカクニ カイテ クタ゛サイ
’  
’  ヨミコムシュルイ
’  PRGトカGRPトカSPU0トカテ゛ス。
’  

’Sample
@DATA0
DATA”[EXPLORER]”
DATA”@Library{”
DATA”◇キャラクタ:,
DATA”◇フ゜ロク゛ラム:,
DATA”}
DATA”@キャラクタ{
DATA”・ニンケ゛ン:NINGEN.SPU0,
DATA”・ハイケイ:BGROUND.SCU0U,
DATA”〜キャラクタ:,
DATA”}
DATA”@フ゜ロク゛ラム{
DATA”・サンカクハ:COSTEST.PRG,
DATA”・STG:GAME4.PRG,
DATA”〜キャラクタ:,
DATA”}
DATA”−”

’[EOF]
}}
#endregion
/////////////////////////////////
// コメントを募集したくないなら、ここから下は削除してください

* CHECKER FLAG (ひとことコメント) [#Comments]
この作品に対するコメントがあれば一言どうぞ。(作品に直接関係ない質問や雑談は[[掲示板>Board]]へ)
- ''名無しさん'' : CangeではなくChangeでは? もしくはEditにするのはどうでしょう。 (&new{2012/06/24 (日) 22:35:38};)
- ''いったん(投稿者)'' : ありがとうございます。次回治したいと思います。 (&new{2012/06/24 (日) 22:42:20};)
- ''名無しさん'' : ドラッグ&ドロップできたら最高 (&new{2012/06/25 (月) 15:51:44};)
- ''名無しさん'' : _アンダーバーできない (&new{2012/06/25 (月) 15:55:40};)
- ''名無しさん'' : ファイルエディタっていうか、ファイルマネージャとかファイルエクスプローラっていうんじゃないか? (&new{2012/06/25 (月) 23:32:05};)
- ''名無しさん'' : あと、FolderがForderになってるところがあるw (&new{2012/06/25 (月) 23:44:39};)
- ''チェストォ'' : なかなか( ´ ▽ ` )ノ (&new{2012/06/27 (水) 17:44:54};)
- ''名も無き名無し'' : QRが4〜表示されない (&new{2012/07/02 (月) 19:30:09};)
- ''hatena'' : 名前を変更する時何も入力せずにEnterキーを押すとバグ発生します。 (&new{2012/07/02 (月) 20:09:38};)
- ''いったん(投稿者)'' : hatenaさんありがとうございます。次の更新で修正したいと思います。 (&new{2012/07/02 (月) 21:46:33};)
- ''hatena'' : プログラムリスト書きましたよ〜。[[この>http://www.geocities.jp/hatena71869/prglists/FILEEDT_prglist.html]]ページにあります。載せるまではいかなくてもリンクしておけばどうでしょうか? (&new{2012/07/05 (木) 20:24:51};)
- ''いったん(投稿者)'' : hatenaさんありがとうございます。リンク貼っときました。 (&new{2012/07/07 (土) 17:00:00};)
- ''hatena'' : プログラムリストに行数を付け加えました。 (&new{2012/07/07 (土) 20:05:34};)
- ''名も無き名無し'' : なんでかな?プログラムリスト開くと文字化けすごいwちなみにOSはWin7です (&new{2012/07/07 (土) 23:24:18};)
- ''わぁぃ@'' : ↑フォントが反映されてないのかな?ファイヤフォックス(スペルが分からないorz)かな?初代プチコンの公式サイトからDLしよう。 (&new{2012/07/08 (日) 09:21:47};)
- ''名無しさん'' : メニューバーの 表示>エンコード>EUC でどうですか? (&new{2012/07/08 (日) 09:30:06};)
- ''名無しさん'' : 多分半角カナが文字化けしているだけだと思う。 (&new{2012/07/08 (日) 09:56:36};)
// - ''名無しさん'' : ���������������������������������������������������あ (&new{2012/07/08 (日) 12:00:13};)
- ''名無しさん'' : 今見たら全部全角になってたからエンコードをeucにしないと文字化けがひどい。 (&new{2012/07/08 (日) 13:25:13};)
- ''hatena'' : プログラムリストはEUC-JPです。 (&new{2012/07/08 (日) 16:52:28};)
- ''あいうえお'' : ファイルをロードするとエラーがでるのですが (&new{2012/07/22 (日) 18:01:04};)
// - ''あいうえお'' : ファイルをロードするとエラーがでるのですが (&new{2012/07/22 (日) 18:01:04};)
- ''hatena'' : プログラムリストをShift_JISにしてmetaタグを入れ、プチコンフォントにしました。 (&new{2012/09/04 (火) 19:26:21};)
// - ''qttlemxdrr'' : LXrGQcDWaJ (&new{2012/09/17 (月) 14:54:45};)
// - ''名無しさん'' : ↑??? (&new{2012/09/24 (月) 21:08:36};)
- ''hatena'' : 俺の書いたプログラムリストのリンクを削除してください。俺は編集できないです。 (&new{2012/10/15 (月) 22:41:37};)
- ''いったん(投稿者)'' : hatenaさん。対応しました。 (&new{2012/10/15 (月) 23:32:13};)
- ''が'' : 英語をカタカナに…。 (&new{2012/11/21 (水) 16:07:12};)
-- ''いったん(投稿者)'' : ↑しました。(&new{2012/11/22 (木) 17:45:00};)
- ''バグ発生'' : フォルダの名前変更で何も入力せずに改行すると発生する。 (&new{2012/12/01 (土) 19:35:03};)
- ''バグ発生2'' : ショートカットが削除できない (&new{2012/12/01 (土) 21:49:56};)
- ''いったん'' : ↑わかりました。近いうちに対策します。 (&new{2012/12/01 (土) 22:55:34};)
- ''nao112641433'' : osに組み込んでいいですか? (&new{2013/02/10 (日) 10:56:00};)
- ''いったん'' : いいですけど・・・変数とかラベルとかたくさん使ってますし、そもそもメインルーチンがあってないようなものなのでランチャ的な使い方しかできないと思いますが、それでもよければどうぞ。 (&new{2013/04/01 (月) 20:44:49};)
- ''道産子(dosankosoft)'' : @Rでラベル名を入力するとUndefined labelになります。 (&new{2013/08/25 (日) 20:07:35};)
- ''道産子(dosankosoft)'' : すみません。自己解決しました。 (&new{2013/08/25 (日) 20:10:45};)
- ''Tachesci'' : 懐かしい起動音。Windows95か98だったっけ。 (&new{2014/11/15 (土) 20:33:01};)

#comment

表示モード : [ スマホ・3DS対応表示 | クラシック表示 ]
PukiWiki 1.4.7 Copyright © 2001-2006 PukiWiki Developers Team. License is GPL. Based on "PukiWiki" 1.3 by yu-ji
ページの処理時間 : 0.026 秒 | ログイン
Copyright(C) 2011-2014 プチコンまとめWiki ◆1sxkymI8ji30