プチコンまとめWiki (初代/mkII)

投稿プログラム : マージャンソリティア

2012年05月14日投稿 / 投稿者 : 名無しさん / タグ : 投稿プログラム ゲーム QRコード mkII専用

概要

麻雀牌を使うあのパズルゲームです。
権利関係でサン電子さんから怒られたら消してください>管理人さん
さすがに、もう大丈夫だとは思いますが。

更新履歴

2012-05-25 20:30 下記バグ修正しました。PRGのQRとリストを更新しました。ついでに面選択時キーリピートつけました。
2012-05-21 22:13 バグ報告。14, 20, 33, 52, 64, 81面が開始できません。後日修正します。すみません。
2012-05-19 22:43 初期配置ルーチンを変更。どの面も100%解けるようになりました(汗。PRGのQRとリストを更新
2012-05-15 01:53 QR、リスト更新
2012-05-14 23:00 投稿

プログラムについて

各面の配置は乱数で決めています。
ただ、同じ配置を再現できるように乱数ルーチンは自前で用意しました。
しかし、乱数で配置を決めるとほとんど解けないような面ばかりできてしまったので、
少しだけハマリが少ないように微調整しています。
それでも結構難しいです・・・(汗
一応6面までは解けることを確認しましたが、初見だと負けると思います。
私が下手なだけかもしれませんが(笑)
配置を決めるルーチンを変更しました。どの面も100%解けます。
(2chのプチコンスレで素晴らしい方法を教えて下さった>>28さんthx!)

描画は全部GRPです。
GCOPYが予想以上に速かったので選択/消去する度に下から全部再描画してます。
7frameで完了するので良しとしました。

スクリーンショット

MJSOL_SCR.JPG

QR コード

プチコンmkII 向けの QR コードです。

PRG:MJSOL 2012-05-25 20:27 更新
1/52/53/5
MJSOL_PRG_4_QR0.pngMJSOL_PRG_4_QR1.pngMJSOL_PRG_4_QR2.png
4/55/5 
MJSOL_PRG_4_QR3.pngMJSOL_PRG_4_QR4.png 
GRP:MJSOL 最初の物と同じです
1/62/63/6
MJSOL_GRP_1_QR0.pngMJSOL_GRP_1_QR1.pngMJSOL_GRP_1_QR2.png
4/65/66/6
MJSOL_GRP_1_QR3.pngMJSOL_GRP_1_QR4.pngMJSOL_GRP_1_QR5.png

プログラムリスト

  1. CLEAR:ACLS
  2. SYSBEEP=FALSE
  3. VISIBLE 1,1,1,1,1,1
  4. PNLTYPE ”OFF”
  5. CHRINIT ”BGU0”
  6. BGPAGE 1:BGCLR 0
  7. BGFILL 1,0,0,31,23,10,0,0,0
  8. GPAGE 0,3,3:GCLS 0:GPRIO 2
  9. GRPDRAW=1
  10. GPAGE 1,GRPDRAW,GRPDRAW XOR 1:GCLS 0:GPRIO 2
  11. LOAD ”GRP2:MJSOL”,FALSE
  12. GOSUB @PAL_SET
  13. DIM MEN0(5,17*10)
  14. DIM MEN1(5,17*10)
  15. DIM MEN2(5,17*10)
  16. DIM U(37)
  17. GOSUB @MEN_INIT
  18. STAGE=1
  19. @FROM_TITLE
  20. GOSUB @TITLE
  21. S=STAGE
  22. IF S==14 OR S==20 OR S==33 THEN S=S+100
  23. IF S==52 OR S==64 OR S==81 THEN S=S+100
  24. A=S:GOSUB @RANDOMIZE
  25. GOSUB @MEN_INIT3
  26. GPAGE 1,GRPDRAW,GRPDRAW XOR 1
  27. GOSUB @REDRAW
  28. LOCATE 10,13:PRINT ”  Б GIVE UP”
  29. ’−−−−−−−−−−−−−−−−−−−−−−
  30. MODE=0
  31. DEL_COUNT=0
  32. TIMER=0
  33. TIME0$=TIME$
  34. SELN0=0
  35. @MAIN_LOOP
  36.  GOSUB @TCH_CHECK
  37.  IF !RET THEN @MAIN_LOOP_0
  38.   IF !(MODE==0) THEN @MAIN_LOOP_1
  39.    IF SELZ==9 THEN @MAIN_LOOP_0
  40.     SELZ0=SELZ
  41.     SELY0=SELY
  42.     SELX0=SELX
  43.     SELN0=MEN1(SELZ,SELY*17+SELX)
  44.     MODE=1
  45.     BEEP 9 ’ センタク
  46.     GOTO @MAIN_LOOP_2
  47.    @MAIN_LOOP_1
  48.    ’ MODE==1
  49.    IF !(SELZ==9) THEN @MAIN_LOOP_3
  50.     MODE=0
  51.     SELZ0=9
  52.     BEEP 48 ’キャンセル
  53.     GOTO @MAIN_LOOP_2
  54.    @MAIN_LOOP_3
  55.    ’ SELZ!=9
  56.    SELN1=MEN1(SELZ,SELY*17+SELX)
  57.    IF SELN0!=SELN1 THEN @MAIN_LOOP_4
  58.    IF SELZ0==SELZ AND SELY0==SELY AND SELX0==SELX THEN @MAIN_LOOP_4
  59.     ’ イッチ
  60.     MEN1(SELZ0,SELY0*17+SELX0)=0
  61.     MEN1(SELZ,SELY*17+SELX)=0
  62.     MODE=0
  63.     SELZ0=9
  64.     BEEP 60 ’ケス
  65.     DEL_COUNT=DEL_COUNT+1
  66.     GOTO @MAIN_LOOP_2
  67.    @MAIN_LOOP_4
  68.    BEEP 48 ’キャンセル
  69.    MODE=0
  70.    SELZ0=9
  71.   @MAIN_LOOP_2
  72.   GOSUB @REDRAW
  73.   PALANIM_C=0:PALANIM_W=0
  74.  @MAIN_LOOP_0
  75.  GOSUB @PALANIM
  76.  LOCATE 12,20
  77.  PRINT RIGHT$(”  ”+STR$(FLOOR(TIMER/60)),3);”:”;RIGHT$(”0”+STR$(TIMER%60),2)
  78.  IF TIME0$!=TIME$ THEN TIME0$=TIME$:TIMER=TIMER+1
  79.  VSYNC 1
  80.  IF DEL_COUNT==72 THEN @FANFARE
  81.  IF BUTTON(2) AND 32 THEN BEEP 13:GOTO @FROM_TITLE
  82.  GOTO @MAIN_LOOP
  83. ’−−−−−−−−−−−−−−−−−−−−−−
  84. @FANFARE
  85.  BGMPLAY 5
  86.  @FANFARE_0
  87.  VSYNC 1
  88.  IF BGMCHK() GOTO @FANFARE_0
  89.  STAGE=STAGE+1
  90.  GOTO @FROM_TITLE
  91. ’−−−−−−−−−−−−−−−−−−−−−−
  92. @TCH_CHECK
  93.  RET=FALSE
  94.  IF !(TCHST AND TCHTIME==1) THEN RETURN
  95.  XX=TCHX:YY=TCHY
  96.  RET=TRUE
  97.  F=FALSE
  98.  SELZ=9
  99.  ’−−− Z=4 −−−
  100.   X=FLOOR((XX+10+12−10)/16)
  101.   Y=FLOOR((YY+4+12−10)/20)
  102.   IF MEN1(4,Y*17+X)==0 THEN @TCH_CHK_4
  103.   SELZ=4:SELY=Y:SELX=X
  104.   RETURN
  105.   @TCH_CHK_4
  106.  ’−−− Z=3 −−−
  107.   X=FLOOR((XX+10+12)/16)
  108.   Y=FLOOR((YY+4+12)/20)
  109.   IF Y>8 THEN @TCH_CHK_3
  110.   IF MEN1(3,Y*17+X)==0 THEN @TCH_CHK_3
  111.   IF MEN1(4,4*17+7)==0 THEN F=TRUE
  112.   IF F THEN SELZ=3:SELY=Y:SELX=X
  113.   RETURN
  114.   @TCH_CHK_3
  115.  ’−−− Z=2 −−−
  116.   X=FLOOR((XX+10+8)/16)
  117.   Y=FLOOR((YY+4+8)/20)
  118.   IF MEN1(2,Y*17+X)==0 THEN @TCH_CHK_2
  119.   IF MEN1(2,Y*17+X+1)==0 THEN F=TRUE
  120.   IF MEN1(2,Y*17+X−1)==0 THEN F=TRUE
  121.   IF F THEN SELZ=2:SELY=Y:SELX=X
  122.   RETURN
  123.   @TCH_CHK_2
  124.  ’−−− Z=1 −−−
  125.   X=FLOOR((XX+10+4)/16)
  126.   Y=FLOOR((YY+4+4)/20)
  127.   IF MEN1(1,Y*17+X)==0 THEN @TCH_CHK_1
  128.   IF MEN1(1,Y*17+X+1)==0 THEN F=TRUE
  129.   IF MEN1(1,Y*17+X−1)==0 THEN F=TRUE
  130.   IF F THEN SELZ=1:SELY=Y:SELX=X
  131.   RETURN
  132.   @TCH_CHK_1
  133.  ’−−− Z=0 −−−
  134.   X=FLOOR((XX+10)/16)
  135.   IF X==1 THEN YY=YY−10
  136.   IF X>=14 THEN YY=YY+10
  137.   Y=FLOOR((YY+4)/20)
  138.   IF Y>8 OR Y<0 THEN @TCH_CHK_0
  139.   IF MEN1(0,Y*17+X)==0 THEN @TCH_CHK_0
  140.   IF X==2 AND (Y==4 OR Y==5) THEN @TCH_CHK_01
  141.   IF X==14 THEN @TCH_CHK_02
  142.   IF X==13 AND (Y==4 OR Y==5) THEN @TCH_CHK_03
  143.   IF MEN1(0,Y*17+X+1)==0 THEN F=TRUE
  144.   IF MEN1(0,Y*17+X−1)==0 THEN F=TRUE
  145.   GOTO @TCH_CHK_04
  146.   @TCH_CHK_01
  147.   IF MEN1(0,Y*17+X+1)==0 THEN F=TRUE
  148.   IF MEN1(0,4*17+1)==0 THEN F=TRUE
  149.   GOTO @TCH_CHK_04
  150.   @TCH_CHK_02
  151.   IF MEN1(0,Y*17+X+1)==0 THEN F=TRUE
  152.   IF (MEN1(0,4*17+13)==0 AND MEN1(0,5*17+13)==0) THEN F=TRUE
  153.   GOTO @TCH_CHK_04
  154.   @TCH_CHK_03
  155.   IF MEN1(0,5*17+X+1)==0 THEN F=TRUE
  156.   IF MEN1(0,Y*17+X−1)==0 THEN F=TRUE
  157.   @TCH_CHK_04
  158.   IF F THEN SELZ=0:SELY=Y:SELX=X
  159.   @TCH_CHK_0
  160.  RETURN
  161. ’−−−−−−−−−−−−−−−−−−−−−−
  162. @PALANIM
  163.  PALANIM_W=PALANIM_W+1
  164.  IF PALANIM_W>5 THEN PALANIM_W=0
  165.  IF PALANIM_W!=1 THEN RETURN
  166.  P=16+PALANIM_C
  167.  PALANIM_C=PALANIM_C+1
  168.  IF PALANIM_C>5 THEN PALANIM_C=0
  169.  COLREAD(”GRP”,P),R,G,B
  170.  C$=HEX$(R,2)+HEX$(G,2)+HEX$(B,2)
  171.  COLSET ”GRP”,15,C$
  172.  RETURN
  173. ’−−−−−−−−−−−−−−−−−−−−−−
  174. @PUT_PAI
  175.  C0=C0−1
  176.  Y3=(C0/9 AND &HFF)*24+C1
  177.  X3=(C0%9)*20
  178.  Y4=Y1
  179.  IF X0<2 THEN Y4=Y4+10
  180.  IF X0>13 THEN Y4=Y4−10
  181.  GCOPY 2,X3,Y3,X3+19,Y3+23,X1,Y4,FALSE
  182.  RETURN
  183. ’−−−−−−−−−−−−−−−−−−−−−−
  184. @MEN_INIT
  185.  GPAGE 1,2,1
  186.  FOR Z=0 TO 4
  187.   FOR Y=0 TO 9
  188.    FOR X=0 TO 16
  189.     Y0=10*Z+Y
  190.     X0=X+192
  191.     C=GSPOIT(X0,Y0)
  192.     IF C!=1 THEN @ME_IN_0
  193.      MEN0(Z,Y*17+X)=1
  194.     @ME_IN_0
  195.    NEXT
  196.   NEXT
  197.  NEXT
  198.  MEN_NUM=1
  199.  RETURN
  200. ’−−−−−−−−−−−−−−−−−−−−−−
  201. @MEN_INIT2
  202.  FOR I=1 TO 36
  203.   U(I)=0
  204.  NEXT
  205.  A=36
  206.  FOR Z=0 TO 4
  207.   FOR Y=0 TO 9
  208.    FOR X=0 TO 16
  209.     IF MEN0(Z,Y*17+X)==0 THEN @ME_IN2_0
  210.      @ME_IN2_1
  211.      GOSUB @RAND
  212.      R=R+1
  213.      IF U(R)==4 GOTO @ME_IN2_1
  214.      IF Z>2 THEN @ME_IN2_3
  215.      ’ オナシ゛ ハイ ハ トナリ キンシ
  216.      IF MEN1(Z,Y*17+X−1)==R THEN @ME_IN2_1
  217.      @ME_IN2_3
  218.      IF Z==0 OR Z>=3 THEN @ME_IN2_2
  219.      ’ オナシ゛ ハイ ノ カサナリ キンシ
  220.      FOR ZZ=0 TO Z−1
  221.       IF MEN1(ZZ,Y*17+X)==R THEN @ME_IN2_1
  222.      NEXT
  223.      @ME_IN2_2
  224.      MEN1(Z,Y*17+X)=R
  225.      U(R)=U(R)+1
  226.     @ME_IN2_0
  227.    NEXT
  228.   NEXT
  229.  NEXT
  230.  RETURN
  231. ’−−−−−−−−−−−−−−−−−−−−−−
  232. @MEN_INIT3
  233.  ’−−−−−
  234.  FOR I=1 TO 36
  235.   U(I)=0
  236.  NEXT
  237.  ’−−−−−
  238.  FOR Z=0 TO 3
  239.   FOR Y=1 TO 8
  240.    FOR X=2 TO 13
  241.     N=0
  242.     IF MEN0(Z,Y*17+X)==1 THEN N=99
  243.     MEN2(Z,Y*17+X)=N
  244.    NEXT
  245.   NEXT
  246.  NEXT
  247.  MEN2(0,4*17+1)=99
  248.  MEN2(0,5*17+14)=99
  249.  MEN2(0,5*17+15)=99
  250.  MEN2(4,4*17+7)=99
  251.  ’−−−−−
  252.  FOR Z=0 TO 2
  253.   FOR Y=1 TO 8
  254.    FOR X=2 TO 13
  255.     IF MEN2(Z,Y*17+X)==0 THEN @ME_IN3_01
  256.     N=99
  257.     IF MEN2(Z,Y*17+X−1)==0 THEN N=98
  258.     IF MEN2(Z,Y*17+X+1)==0 THEN N=98
  259.     MEN2(Z,Y*17+X)=N
  260.     @ME_IN3_01
  261.    NEXT
  262.   NEXT
  263.  NEXT
  264.  MEN2(0,4*17+1)=98
  265.   MEN2(0,5*17+2)=99
  266.  MEN2(0,5*17+14)=99
  267.   MEN2(0,4*17+13)=99
  268.  MEN2(0,5*17+15)=98
  269.  MEN2(4,4*17+7)=98
  270.  ’−−−−−
  271.  COUNT=0
  272.  @ME_IN3_00
  273.  A=36:GOSUB @RAND:R=R+1
  274.  IF U(R)==4 THEN @ME_IN3_00
  275.  U(R)=U(R)+2
  276.  RR=R
  277.  ’−−−−
  278.  @ME_IN3_10
  279.  A=8:GOSUB @RAND:Y0=R+1
  280.  A=15:GOSUB @RAND:X0=R+1
  281.  Z0=4
  282.  @ME_IN3_12
  283.  N=MEN2(Z0,Y0*17+X0)
  284.  IF N==98 THEN @ME_IN3_11
  285.  IF Z0>0 THEN Z0=Z0−1:GOTO @ME_IN3_12
  286.  GOTO @ME_IN3_10
  287.  @ME_IN3_11
  288.  MEN1(Z0,Y0*17+X0)=RR
  289.  ’−−
  290.  @ME_IN3_20
  291.  A=8:GOSUB @RAND:Y1=R+1
  292.  A=15:GOSUB @RAND:X1=R+1
  293.  IF Y0==Y1 AND X0==X1 THEN @ME_IN3_20
  294.  Z1=4
  295.  @ME_IN3_22
  296.  N=MEN2(Z1,Y1*17+X1)
  297.  IF N==98 THEN @ME_IN3_21
  298.  IF Z1>0 THEN Z1=Z1−1:GOTO @ME_IN3_22
  299.  GOTO @ME_IN3_20
  300.  @ME_IN3_21
  301.  MEN1(Z1,Y1*17+X1)=RR
  302.  ’−−
  303.  FOR I=0 TO 1
  304.   ZZ=Z0:YY=Y0:XX=X0
  305.   IF I==1 THEN ZZ=Z1:YY=Y1:XX=X1
  306.   MEN2(ZZ,YY*17+XX)=0
  307.   IF ZZ==0 THEN @ME_IN3_30
  308.   IF ZZ!=4 THEN @ME_IN3_31
  309.   ’ Z==4
  310.   MEN2(3,4*17+7)=98
  311.   MEN2(3,4*17+8)=98
  312.   MEN2(3,5*17+7)=98
  313.   MEN2(3,5*17+8)=98
  314.   GOTO @ME_IN3_40
  315.   @ME_IN3_31
  316.   ’ Z==1,2,3
  317.   N=99
  318.   IF MEN2(ZZ−1,YY*17+XX−1)==0 THEN N=98
  319.   IF MEN2(ZZ−1,YY*17+XX+1)==0 THEN N=98
  320.   MEN2(ZZ−1,YY*17+XX)=N
  321.   @ME_IN3_30
  322.   IF MEN2(ZZ,YY*17+XX−1)==99 AND MEN2(ZZ+1,YY*17+XX−1)==0 THEN MEN2(ZZ,YY*17+XX−1)=98
  323.   IF MEN2(ZZ,YY*17+XX+1)==99 AND MEN2(ZZ+1,YY*17+XX+1)==0 THEN MEN2(ZZ,YY*17+XX+1)=98
  324.   IF XX==1 THEN MEN2(0,5*17+2)=98
  325.   IF XX==14 THEN MEN2(0,4*17+13)=98
  326.   ’−
  327.   IF XX!=13 THEN @ME_IN3_40
  328.   IF MEN2(0,5*17+14)!=99 THEN @ME_IN3_40
  329.   IF YY!=4 AND YY!=5 THEN @ME_IN3_40
  330.   IF MEN2(0,4*17+13)==0 AND MEN2(0,5*17+13)==0 THEN MEN2(0,5*17+14)=98
  331.   @ME_IN3_40
  332.  NEXT
  333.  COUNT=COUNT+2
  334.  IF COUNT<36*4 THEN @ME_IN3_00
  335.  RETURN
  336. ’−−−−−−−−−−−−−−−−−−−−−−
  337. @REDRAW
  338.  GCLS
  339.  FOR Z0=0 TO 3
  340.   IF Z0==0 THEN SX=1:SY=1:EX=15:EY=8
  341.   IF Z0==1 THEN SX=5:SY=2:EX=10:EY=7
  342.   IF Z0==2 THEN SX=6:SY=3:EX=9:EY=6
  343.   IF Z0==3 THEN SX=7:SY=4:EX=8:EY=5
  344.   Y1=−4−Z0*4+SY*20
  345.   FOR Y0=SY TO EY
  346.    X1=−10−Z0*4+SX*16
  347.    FOR X0=SX TO EX
  348.     C1=0
  349.     IF Z0==SELZ0 AND Y0==SELY0 AND X0==SELX0 THEN C1=96
  350.     C0=MEN1(Z0,Y0*17+X0)
  351.     IF C0!=0 THEN GOSUB @PUT_PAI
  352.     X1=X1+16
  353.    NEXT X0
  354.    Y1=Y1+20
  355.   NEXT Y0
  356.  NEXT Z0
  357.  Z0=4:Y0=4:X0=7
  358.  C1=0
  359.  IF Z0==SELZ0 AND Y0==SELY0 AND X0==SELX0 THEN C1=96
  360.  C0=MEN1(Z0,Y0*17+X0)
  361.  IF C0==0 THEN @REDRAW_0
  362.  X1=−10−Z0*4+X0*16+10
  363.  Y1=−4−Z0*4+Y0*20+10
  364.  GOSUB @PUT_PAI
  365.  @REDRAW_0
  366.  GRPDRAW=GRPDRAW XOR 1
  367.  GPAGE 1,GRPDRAW,GRPDRAW XOR 1
  368.  RETURN
  369. ’−−−−−−−−−−−−−−−−−−−−−−
  370. @TIME_COUNT
  371.  IF X0==1 THEN @TI_CO_0
  372.   TIME_COUNTER=MAINCNTL
  373.   RETURN
  374.  @TI_CO_0
  375.  X0=MAINCNTL−TIME_COUNTER
  376.  RETURN
  377. ’−−−−−−−−−−−−−−−−−−−−−−
  378. @RANDOMIZE
  379.  RAND_X=A
  380.  RETURN
  381. ’−−−−−−−−−−−−−−−−−−−−−−
  382. @RAND
  383.  RAND_X=(RAND_X*31+1235) AND 16383
  384.  R=FLOOR((RAND_X/16384)*A)
  385.  RETURN
  386. ’−−−−−−−−−−−−−−−−−−−−−−
  387. @PAL_SET
  388.  RESTORE @PAL_DATA
  389.  FOR I=0 TO 23
  390.   READ C$
  391.   COLSET ”GRP”,I,C$
  392.  NEXT
  393.  RETURN
  394.  @PAL_DATA
  395.  DATA ”000000”,”DEA673”,”E7B67B”,”BDC7CE”
  396.  DATA ”CED7DE”,”FFFFFF”,”000000”,”FF0000”
  397.  DATA ”00AA00”,”3982C6”,”000000”,”000000”
  398.  DATA ”000000”,”000000”,”000000”,”74BCFF”
  399.  DATA ”74BCFF”,”A2D2FF”,”D0E8FF”,”FFFFFF”
  400.  DATA ”D1E9FF”,”A3D3FF”,”74BCFF”,”000000”
  401. ’−−−−−−−−−−−−−−−−−−−−−−
  402. @TITLE
  403.  CLS
  404.  X=10
  405.  @TITLE_0
  406.  S$=RIGHT$(” ”+STR$(STAGE),2)
  407.  LOCATE X, 8:PRINT ”           ↑”
  408.  LOCATE X, 9:PRINT ”  STAGE= ← ”;S$;” →”
  409.  LOCATE X,10:PRINT ”           ↓”
  410.  LOCATE X,11:PRINT ””
  411.  LOCATE X,12:PRINT ”  А START”
  412.  VSYNC 1
  413.  GOSUB @KEYREPEAT
  414.  IF KEYREP AND 1 THEN STAGE=STAGE+10
  415.  IF KEYREP AND 2 THEN STAGE=STAGE−10
  416.  IF KEYREP AND 4 THEN STAGE=STAGE−1
  417.  IF KEYREP AND 8 THEN STAGE=STAGE+1
  418.  IF STAGE<0 THEN STAGE=100+STAGE
  419.  IF STAGE>99 THEN STAGE=STAGE−100
  420.  IF BUTTON(2) AND 16 THEN BEEP 7:GOTO @TITLE_1
  421.  GOTO @TITLE_0
  422.  @TITLE_1
  423.  CLS
  424.  LOCATE X, 9:PRINT ”  STAGE=   ”;S$;”  ”
  425.  RETURN
  426. ’−−−−−−−−−−−−−−−−−−−−−−
  427. @KEYREPEAT
  428.  KEYREP=0
  429.  K=BUTTON() AND 15
  430.  IF K!=KEYREP_P THEN @KEYREP_1 ELSE @KEYREP_2
  431.   @KEYREP_1
  432.    KEYREP_P=K
  433.    KEYREP_C=0
  434.    KEYREP_F=TRUE
  435.    KEYREP=BTRIG()
  436.    RETURN
  437.   @KEYREP_2
  438.    IF K==0 THEN RETURN
  439.    KEYREP_C=KEYREP_C+1
  440.    C=6
  441.    IF KEYREP_F THEN C=20
  442.    IF KEYREP_C<C THEN RETURN
  443.    KEYREP=K
  444.    KEYREP_C=0
  445.    KEYREP_F=FALSE
  446.  RETURN
  447. ’−−−−−−−−−−−−−−−−−−−−−−
  448. @LOOP
  449.  VSYNC 1
  450.  GOTO @LOOP
  451. ’−−−−−−−−−−−−−−−−−−−−−−
  452. ’−−−−−−−−−−−−−−−−−−−−−−
  453. ’−−−−−−−−−−−−−−−−−−−−−−

CHECKER FLAG (ひとことコメント)

この作品に対するコメントがあれば一言どうぞ。

  • 名無しさん : これはすごい。99面もパターンがありますが、必ずしも解けるとは限らないのですか? (2012/05/14 (月) 23:36:39)
  • 投稿者 : 解けない面はあると思います。ハマリパターンを完璧にはチェックしてないので(汗w (2012/05/15 (火) 00:49:35)
  • 名無しさん : プレイ中に画面の一番下あたり(緑の部分)をタッチすると、プログラムが終了してしまうようです。普通に遊ぶ分には全く問題ないのですが念のためご報告しました。 (2012/05/15 (火) 00:50:59)
  • 投稿者 : あ、そのバグ、有りそうだな、って思ってたのにチェックしてませんでした。タッチ座標を変換して配列にアクセスするときに配列の範囲外になっちゃうんですよね。後ほど修正しておきます。 (2012/05/15 (火) 01:09:01)
  • 投稿者 : ↑↑QRとリスト更新しました。気になるようでしたらPRGのQR再読み込み、もしくはリストに120、149行を追加してください。 (2012/05/15 (火) 01:57:43)
  • 名無しさん : プチコンスレでいい案が出てましたね。クリアできないんじゃ、やる気が出ないので・・・ (2012/05/15 (火) 12:04:31)
  • 名無しさん : ↑↑対応ありがとうございます。 (2012/05/15 (火) 18:40:03)
  • 名無しさん : 上海は好きなゲームなので作ってもらえてすげー嬉しいのですが (2012/05/15 (火) 23:40:49)
  • 名無しさん : ↑途中でエンター押してしまった QRの画像が大きくて自分の環境じゃ表示出来なくて残念皆さんの評価は良さそうなのでこれからもプログラム頑張ってください (2012/05/15 (火) 23:47:25)
  • 投稿者 : ↑QR小さくしてみました。 (2012/05/19 (土) 22:53:57)
  • 名無しさん : 修正お疲れ様です! これで安心して遊べます。ありがとう。 (2012/05/19 (土) 23:21:17)
  • ど素人 : これでもう「解けない配置だったかも……」と自分に言い訳できなくなりました(爆)グラフィックもボリュームも凄いの一言です。 (2012/05/20 (日) 00:42:48)
  • 名無しさん : 2ちゃんのほうにも書きましたが、クリアタイムを記録しておく機能があると、一度クリアしても、タイムアタックで長く楽しめる気が。 (2012/05/21 (月) 13:56:52)
  • 名無しさん : 14, 20, 33, 52, 64, 81面が開始できないバグはもう修正された? (2012/05/22 (火) 15:32:28)
  • 投稿者 : バグ修正しました。遅くなってすみません。 (2012/05/25 (金) 20:33:16)
  • 名無しさん : 0面ではじめられちゃいますね。で、固まる。 (2012/05/25 (金) 21:18:32)
  • Lv100 : >>28(説明文の)さんは何処のスレの人ですか? (2012/05/25 (金) 23:54:21)
  • 名無しさん : たぶんこのスレだろう http://toro.2ch.net/test/read.cgi/handygame/1336902883/ (2012/05/26 (土) 00:33:42)
  • 権兵衛さん : 「これ以上取れませんよ」判定、お願いします。 (2012/05/26 (土) 02:41:32)
  • 権兵衛さん : 0面で・・の対応策。 (2012/05/26 (土) 03:18:46)
  • 権兵衛さん : 427 IF STAGE <=1 THEN STAGE=1 を挿入・・・で、直った (2012/05/26 (土) 03:21:57)
  • 名無しさん : ↑だと1→99ができなくなるけど、できるようにするのはちょっと面倒くさそう。 (2012/05/26 (土) 09:38:08)
  • 権兵衛さん : ↑あれ?、本当ですかぁ〜?、おっかしい〜な〜。 (2012/05/26 (土) 14:31:17)
  • 名無しさん : ↑ん? 1→2・・・98→99→1 はできるけど、1→99はできなくなりませんか? (2012/05/26 (土) 15:58:36)
  • 権兵衛さん : あっ、本当だ・・・、でも、上十字キーを押せばいいと、思うのですが? (2012/05/26 (土) 18:56:16)
  • 名無しさん : それでよければ。投稿者さんの考え方次第ですね。とりあえず0面が選べなければOKだし。 (2012/05/26 (土) 19:32:28)
  • 権兵衛さん : そうですね。余計なことをしちゃったかな?投稿者さん、ごめんなさい。 (2012/05/26 (土) 20:46:15)
  • 名無しさん : 428行をSTAGE<1、STAGE=99+STAGEに変えて429行をSATGE=STAGE-99に変えれば0面は選べなくなる (2012/05/26 (土) 21:46:09)
  • 権兵衛さん : もう一つの方法:@RANDOMIZEのすぐ下に、IF A==0 THEN A=100を挿入。ステージ0が復活します、でも実際はステージ100。お試しあれ (2012/05/26 (土) 22:28:02)
  • 名無しさん : 上に別の牌が重なっている牌が取れてしまう(上の牌が浮いた状態になる)仕様は、ゲーム性を損なう気が・・・。 (2012/06/04 (月) 15:38:25)
  • 名無しさん : ゲームが始まらないのですが… (2012/08/28 (火) 18:03:47)
  • ねじ : 私はmkIIでちゃんと動いてます。 (2013/11/03 (日) 17:18:38)
  • かつみ : 他の面も欲しいな〜と感じます。 (2014/01/12 (日) 00:58:06)
  • ijezqfzuq : yQYRmeABMdn (2014/06/04 (水) 09:10:30)

表示モード : [ スマホ・3DS対応表示 | クラシック表示 ]
PukiWiki 1.4.7 Copyright © 2001-2006 PukiWiki Developers Team. License is GPL. Based on "PukiWiki" 1.3 by yu-ji
ページの処理時間 : 0.052 秒 | このページの最終更新 : 2014/06/04 (水) 09:10:30 (1964d) | ログイン
Copyright(C) 2011-2014 プチコンまとめWiki ◆1sxkymI8ji30